3

我试图或多或少地let通过重新创建一个构造，syntax-rules但它似乎在使用两个椭圆时绊倒了。

我试着这样写出来：

(define-syntax if-let
  (syntax-rules ()
    [(_ (([binding        value]  ...)
         ([binding2 funct value2])
         ([binding3       value3] ...)) then else) (let ([binding  value]  ...
                                                         [binding2 value2]
                                                         [binding3 value3] ...)
                                                     (if (funct binding2) then else))]))

我认为中间的不同模式[binding2 funct value2]将能够提供一个清晰的划分，就模式而言，第一个模式何时结束以及第二个模式何时开始，但我不断收到标题中的错误。

预期的结果是能够做类似的事情

(if-let ([var1                  1]
         [diff null? '(1 2 3 4 5)]
         [var2                  2])
    var1
  var2)

并返回2，但能够在远程需要var之前和之后拥有尽可能多的 s，diff因此最终使用的变量的顺序无关紧要。

我错过了一些明显的东西吗？这种模式是否可以用卫生宏来完成？谢谢你的帮助！

4

1 回答 1

1

这可以通过辅助宏来实现，以执行查找funct中间事物所需的递归。

(if-let-helper processed-bindings processed-conditions input-binding-conditions then else)

当它重复出现时，它将信息传输input-binding-conditions到 processed-bindingsand中，当它为空processed-conditions时停止 。input-binding-conditions

(define-syntax if-let-helper
  (syntax-rules ()
    [(_ ([bnd val] ...) (cnd ...) () then else)
     (let ([bnd val] ...)
       (if (and cnd ...) then else))]
    [(_ ([bnd val] ...) (cnd ...) ([binding value] . rest) then else)
     (if-let-helper ([bnd val] ... [binding value]) (cnd ...) rest then else)]
    [(_ ([bnd val] ...) (cnd ...) ([binding funct value] . rest) then else)
     (if-let-helper ([bnd val] ... [binding value]) (cnd ... (funct binding))
                    rest then else)]))

(define-syntax if-let
  (syntax-rules ()
    [(_ (binding-funct-value ...) then else)
     (if-let-helper () () (binding-funct-value ...) then else)]))

使用它：

> (if-let ([var1                  1]
           [diff null? '(1 2 3 4 5)]
           [var2                  2])
    var1
    var2)
2

为了解释这一点，我将逐步介绍此示例如何处理每个子句。它最初变成了这个if-let-helper调用：

(if-let-helper
  ()
  ()
  ([var1                  1]
   [diff null? '(1 2 3 4 5)]
   [var2                  2])
  var1
  var2)

前两个列表开始为空，因为它尚未处理任何内容。

(if-let-helper
  ([var1                  1])
  ()
  ([diff null? '(1 2 3 4 5)]
   [var2                  2])
  var1
  var2)

此时它已经处理了第一个子句并将绑定值对添加到第一个“已处理绑定”列表中。但是，funct第一个子句中没有，因此它没有在第二个“已处理条件”列表中添加条件。

(if-let-helper
  ([var1                  1]
   [diff       '(1 2 3 4 5)])
  ((null? diff))
  ([var2                  2])
  var1
  var2)

此时它已经处理了前两个子句，并(null? diff)在第二个列表中添加了一个条件，因为它funct在第二个子句中看到了 there。

(if-let-helper
  ([var1                  1]
   [diff       '(1 2 3 4 5)]
   [var2                  2])
  ((null? diff))
  ()
  var1
  var2)

至此它已经处理了所有三个子句，因此它达到了基本情况并转换为最终的letand if：

(let ([var1                  1]
      [diff       '(1 2 3 4 5)]
      [var2                  2])
  (if (and (null? diff))
      var1
      var2))
于 2019-04-18T05:12:16.740 回答