awk - 如何合并两个文件中的行？

Question

我有文件1：

1
5
4

和文件 2：

44
65
56

我想归档：

1
44
5
65
4
56

谢谢

Answer 1

paste与自定义分隔符一起使用，\n即换行：

paste -d '\n' file1 file2 > file.out

或 GNU sed：

sed 'R file2' file1

或 awk：

awk 'NR==FNR{a[NR]=$0;next} {print a[FNR]} 1' file1 file2

Answer 2

paste是更好的方法，但是使用 awk 您可以getline在读取某个文件时使用它来读取另一个文件：

awk -v f2="file2" '{print; getline < f2; print;}' file1

Answer 3

您能否尝试以下解决方案，如果您也有，它将适用于超过 2 个 Input_file(s)。

awk 'FNR==NR{a[FNR]=$0;next} {a[FNR]=(a[FNR]?a[FNR] ORS:"")$0} END{for(i=1;i<=FNR;i++){print a[i]}}'  Input_file1  Input_file2

---

---

编辑：添加 1 个更通用的解决方案，我们可以将 N 个文件传递给它而且它不假设所有 Input_file(s) 中的行数相同，它从所有文件中获取最大行数并将打印匹配行（在所有文件中都有行号）并将打印行（最后在任何文件中的数量也更多），以防 OP 的文件有这种情况。

假设我们有 3 个名为 file1、file2 和 file3 的文件，如下所示。

cat Input_file1
1
5
4

cat Input_file2
44
65
56

cat Input_file3
1
2
3
4
5
6

下面是代码。

awk '
prev!=FILENAME{
   count=count>prev_count?count:prev_count
}
{
   prev_count=FNR
}
FNR==1{
   prev=FILENAME
}
FNR==NR{
   a[FNR]=$0
   next
}
{
   a[FNR]=(a[FNR]?a[FNR] ORS:"")$0
}
END{
   count=count>prev_count?count:prev_count
   for(i=1;i<=count;i++){
      print a[i]
   }
}'   Input_file1  Input_file2   Input_file3

输出如下。

1
44
1
5
65
2
4
56
3
4
5
6