0

在包规范中，函数名只出现一次，因此它没有重载。在包体中，相同的函数名称使用不同的参数集出现两次。其中之一具有与包规范中的参数相同的参数。我的问题是，包主体中的“第一个函数”是否实际被调用，如果是，它到底在做什么？它试图返回自己。

    --package specification
    CREATE OR REPLACE 
    PACKAGE jtestpkg
      IS
    FUNCTION testfunc(p_num IN NUMBER, p_out1 IN out varchar2, p_out2 IN out varchar2)
      RETURN NUMBER;
    END jtestpkg;

    --package body
    CREATE OR REPLACE 
    PACKAGE BODY jtestpkg
      IS
      --first func
      function testfunc
            (p_num IN NUMBER,
             p_out1 IN OUT varchar2) 
            return number is
                v_out2 varchar2(50);
      BEGIN
      dbms_output.put_line('invoking first func');
          RETURN testfunc(
              p_num,
              p_out1,
              v_out2);
      END;
      --second func
      FUNCTION testfunc(
                p_num IN NUMBER,
                p_out1 IN OUT varchar2,
                p_out2 IN OUT varchar2)
        RETURN NUMBER
        IS
        v_num number;
      BEGIN
        IF 1=p_num THEN
          p_out1:='FirstOUT_1';
          p_out2:='SecondOUT_1';
          dbms_output.put_line(v_num||p_out1||p_out2);
          RETURN 1;
        elsif 2=p_num THEN
          p_out1:='FirstOUT_2';
          p_out2:='SecondOUT_2';
          dbms_output.put_line(v_num||p_out1||p_out2);
          RETURN 2;
        ELSE
          p_out1:='FirstOUT_3';
          p_out2:='SecondOUT_3';
          dbms_output.put_line(v_num||p_out1||p_out2);
          return 3;
        END IF;
        ------
      p_out1:='FirstOUT_0';
      p_out2:='SecondOUT_0';
      dbms_output.put_line(v_num||p_out1||p_out2);
      RETURN 0;
      END testfunc;
    END jtestpkg;
4

1 回答 1

4

规范中声明的函数是公共的，可以从包外部调用。在主体中定义但未在规范中声明的函数是私有的，只能从该包中调用。

在您的示例中，您在包主体中标记为“第二个函数”的函数的第二个重载版本与规范中的声明相匹配，因此这是您从其他地方调用函数时所涉及的：

declare
  rc number;
  in_out_1 varchar2(20) := 'A';
  in_out_2 varchar2(20) := 'B';
begin
  rc := jtestpkg.testfunc(42, in_out_1, in_out_2);
end;
/

FirstOUT_3SecondOUT_3


PL/SQL procedure successfully completed.

正文中的第一个重载函数，您标记为“first func”，在规范中没有匹配的声明，因此您不能在外部调用它：

declare
  rc number;
  in_out_1 varchar2(20) := 'A';
begin
  rc := jtestpkg.testfunc(42, in_out_1);
end;
/

ORA-06550: line 5, column 9:
PLS-00306: wrong number or types of arguments in call to 'TESTFUNC'
ORA-06550: line 5, column 3:
PL/SQL: Statement ignored

我的问题是，包体中的“第一个函数”是否实际被调用

不。在您的代码中，从未调用过“第一个函数”。

它试图返回自己。

不，不是。如果它本身是从包内的其他地方调用的，那么您的“第一个 func”将调用“第二个 func”，但您目前没有这样做。

那里的调试说“调用第一个函数”，但这不是真的，它正在调用第二个函数，因为它发出的调用有三个参数 - 匹配“第二个函数”参数列表。（这恰好是公开的，但如果不是公开也没关系，因为无论如何它都是包内部的）。

举个例子，你可以调用私有函数作为包实例化和初始化的一部分：

...
  END testfunc;

-- initialization, called on instantiation (for each session)
BEGIN
  dbms_output.put_line('Initialization start');
  declare
    rc number;
    in_out_1 varchar2(20) := 'A';
  begin
    dbms_output.put_line('Initialization: calling first func');
    rc := testfunc(1, in_out_1);
  end;
  dbms_output.put_line('Initialization end');
END jtestpkg;
/

然后在会话中第一次调用包中的任何公共内容将实例化它，初始化它，然后运行该包级块。所以使用相同的匿名块：

declare
  rc number;
  in_out_1 varchar2(20) := 'A';
  in_out_2 varchar2(20) := 'B';
begin
  rc := jtestpkg.testfunc(42, in_out_1, in_out_2);
end;
/

您会看到（仅在会话中第一次）：

Initialization start
Initialization: calling first func
invoking first func
FirstOUT_1SecondOUT_1
Initialization end
FirstOUT_3SecondOUT_3


PL/SQL procedure successfully completed.

FirstOUT_3SecondOUT_3从该调用中传递的值 42来看，您仍然可以看到与以前相同的输出；但在此之前，作为初始化过程的一部分，您会看到FirstOUT_1SecondOUT_1“第一个函数”调用“第二个函数”的输出，值为 1。

允许函数调用自身，即递归调用，但每次都需要更改调用，否则会陷入无限循环，最终被杀死。不过，您在这里也没有这样做。

于 2019-04-04T15:20:07.283 回答