4

我有一对大小相等的数组，我将它们称为键和值。

例如：

K: V
1: 99
1: 100
1: 100
1: 100
1: 103
2: 103
2: 105
3: 45
3: 67

对键进行排序，并对与每个键关联的值进行排序。如何删除与每个键及其对应键关联的重复值？

也就是说，我想将以上内容压缩为：

1: 99
1: 100
1: 103
2: 103 <-- This should remain, since key is different
2: 105
3: 45
3: 67

我查看了Thrust中可用的流压缩功能，但找不到任何这样做的东西。推力可以做到这一点吗？还是我需要编写自己的内核来标记模板中的重复项，然后删除它们？

4

2 回答 2

3

对键进行排序，并且对与每个键关联的值也进行排序。因此，我们可以认为键值对是排序的。thrust::unique如果它可以将这 2 个向量视为单个向量，它将直接在此工作。这可以通过使用 . 将每个位置的 2 个项目（键值）压缩到单个元组中来实现zip_iterator。

以下是如何就地实现这一点，并将键值向量修剪为仅唯一元素：

typedef thrust::device_vector< int >                IntVector;
typedef IntVector::iterator                         IntIterator;
typedef thrust::tuple< IntIterator, IntIterator >   IntIteratorTuple;
typedef thrust::zip_iterator< IntIteratorTuple >    ZipIterator;

IntVector keyVector;
IntVector valVector;

ZipIterator newEnd = thrust::unique( thrust::make_zip_iterator( thrust::make_tuple( keyVector.begin(), valVector.begin() ) ),
                                     thrust::make_zip_iterator( thrust::make_tuple( keyVector.end(), valVector.end() ) ) );

IntIteratorTuple endTuple = newEnd.get_iterator_tuple();

keyVector.erase( thrust::get<0>( endTuple ), keyVector.end() );
valVector.erase( thrust::get<1>( endTuple ), valVector.end() );

如果要压缩并生成单独的结果流，则需要为您的类型编写自己的二进制谓词，该谓词会查看元组的两个元素。可thrust::zip_iterator用于从单独的数组形成虚拟元组迭代器。

一个完整的工作示例，您可以这样做如下所示：

#include <iostream>
#include <thrust/tuple.h>
#include <thrust/functional.h>
#include <thrust/device_vector.h>
#include <thrust/iterator/zip_iterator.h>
#include <thrust/unique.h>

// Binary predicate for a tuple pair
typedef thrust::tuple<int, int> tuple_t;
struct tupleEqual
{
  __host__ __device__
    bool operator()(tuple_t x, tuple_t y)
    {
      return ( (x.get<0>()== y.get<0>()) && (x.get<1>() == y.get<1>()) );
    }
};

typedef thrust::device_vector<int>::iterator  intIterator;
typedef thrust::tuple<intIterator, intIterator> intIteratorTuple;
typedef thrust::zip_iterator<intIteratorTuple> zipIterator;
typedef thrust::device_vector<tuple_t>::iterator tupleIterator;

int main(void)
{
  thrust::device_vector<int> k(9), v(9);
  thrust::device_vector<tuple_t> kvcopy(9);

  k[0] = 1; k[1] = 1; k[2] = 1; 
  k[3] = 1; k[4] = 1; k[5] = 2;
  k[6] = 2; k[7] = 3; k[8] = 3;

  v[0] = 99;  v[1] = 100; v[2] = 100;
  v[3] = 100; v[4] = 103; v[5] = 103;
  v[6] = 105; v[7] = 45;  v[8] = 67;

  zipIterator kvBegin(thrust::make_tuple(k.begin(),v.begin()));
  zipIterator kvEnd(thrust::make_tuple(k.end(),v.end()));
  thrust::copy(kvBegin, kvEnd, kvcopy.begin());

  tupleIterator kvend = 
        thrust::unique(kvcopy.begin(), kvcopy.end(), tupleEqual());

  for(tupleIterator kvi = kvcopy.begin(); kvi != kvend; kvi++) {
    tuple_t r = *kvi;
    std::cout << r.get<0>() << "," << r.get<1>() << std::endl;
  }

  return 0;
}
于 2011-04-02T08:30:57.827 回答
1

稍加准备的流压缩就可以了。您基本上可以为每个键值对启动一个线程，检查前一个键值对是否相等，如果不相等：在与这些对相同大小的单独数组中设置一个标志（int = 1）。所有其他标志保持未设置（int = 0）。然后根据标志数组对键值对进行流压缩。

于 2011-04-02T07:17:39.150 回答