-1

我有一个Conrec的噩梦。我正在尝试使用 Conrec 在 ActionScript 中实现等高线。我已经查看了 java 和 javascript 实现，但仍然卡住了。这些可以在这里找到：http: //paulbourke.net/papers/conrec/

Conrec 将获取网格数据并组装连续的等高线。问题是它不一定以连续的方式绘制这些线。例如，它将绘制 A->B，然后是 C->B，然后是 C->D，而不是 A、B、C、D 等。

javascript 实现似乎正在考虑这一点，并将指令序列化为一组绘图点。这也是我最终想要完成的。也就是说，它从核心 Conrec 逻辑中获取指令（例如：A->B、C->B、C->D 等）并将其组织成 A、B、C、D 系列。我认为它还会将系列作为多维数组返回以容纳虚线（例如：[[A，B，C，D]，[E，F，G]]）。最后一个功能是我在 Actionscript 中需要做的。

最后一部分是我卡住的地方。现在忽略Conrec（我已经放弃寻找Actionscript实现），我怎样才能将这些指令组织成一个串行点的集合？当 Conrec 给我“从 X-> Y 绘制点”时，我如何首先检查 X 或 Y 是否已经在一个系列中，然后将 X 或 Y（以不在系列中的那个）附加到系列中？如果两个都不在系列中，则以 X、Y 作为起始集开始一个新系列。然后检查所有现有系列的后续说明并连接系列，如果它们现在在同一点开始和停止？另外，我需要能够允许一个系列自行关闭（例如：A、B、C、A）——一个循环（这甚至可能吗？！）。

我希望这是有道理的。我不确定除了“连接”之外是否还有一个技术术语来表示我想做的事情。我也希望有人用 Conrec 做到了这一点，并可以给我一些指示。

与此同时，我将继续努力，看看我是否能想出一些东西，但我对自己的能力没有信心。我真的很感谢一些资深或专业的建议。

PS：如果您知道从网格数据中绘制等高线的另一种方法，我愿意接受其他选择。但我必须能够在 Actionscript 中实现它。

4

3 回答 3

0

我刚刚将 ConRec 移植到 Actionscript3 并且似乎工作正常，我还没有彻底测试它，但它以我期望的方式绘制了我的轮廓。如果愿意，请尝试一下，我很好奇它是否是正确的端口。它在这里：

http://www.jvanderspek.com/DEV/ConRec/ConRec.as

于 2011-04-05T23:59:32.047 回答
0

好的，这是我第一次尝试完成我需要做的事情。我对结果不是很满意，但它似乎奏效了。

package {
  import flash.display.Sprite;

  public class lineSeriesPointConcat extends Sprite {
    public function lineSeriesPointConcat() {
      init();
    }
    //directions [X -> Y]
    //case 1: both counterclockwise, result is counterclockwise
    private var case1:Array = [
      ["G1", "F1"], 
      ["F1", "E1"], 

      ["D1", "C1"],
      ["C1", "B1"],
      ["B1", "A1"], 

      ["E1", "D1"], //link
      ["G1", "A1"] //loop
    ];

    //case 2: clockwise, counterclockwise, result is clockwise
    private var case2:Array = [
      ["E2", "F2"], 
      ["F2", "G2"], 

      ["D2", "C2"], 
      ["C2", "B2"], 
      ["B2", "A2"], 

      ["E2", "D2"], //link
      ["G2", "A2"] //loop
    ];

    //case 3: both clockwise, result is clockwise
    private var case3:Array = [
      ["E3", "F3"], 
      ["F3", "G3"], 

      ["A3", "B3"], 
      ["B3", "C3"], 
      ["C3", "D3"], 

      ["E3", "D3"], //link
      ["G3", "A3"] //loop
    ];

    //case 4: counterclockwise, clockwise, result is clockwise
    private var case4:Array = [
      ["G4", "F4"], 
      ["F4", "E4"], 

      ["A4", "B4"], 
      ["B4", "C4"], 
      ["C4", "D4"], 

      ["E4", "D4"], //link
      ["G4", "A4"] //loop
    ];


    private var collectedSeries:Array = [];

    private function init():void {
      var directions:Array = case1.concat(case2.concat(case3.concat(case4)));
      for each (var direction:Array in directions) {
        connect(direction[0], direction[1]);
      }
      trace ("final series:\n\t" + collectedSeries.join("\n\t"));
    }

    private function connect(from:String, to:String):void {
      var series:Array;
      var seriesStart:String;
      var seriesEnd:String;
      var seriesIndex:int;
      var n:int = collectedSeries.length;
      var i:int;
      for (i = 0; i < n; i++) {
        series = collectedSeries[i];
        seriesStart = series[0];
        seriesEnd = series[series.length - 1];

        if (seriesStart == to) {
          seriesStart = from;
          series.unshift(from);
          break;
        } else if (seriesStart == from) {
          seriesStart = to;
          series.unshift(to);
          break;
        } else if (seriesEnd == to) {
          seriesEnd = from;
          series.push(from);
          break;
        } else if (seriesEnd == from) {
          seriesEnd = to;
          series.push(to);
          break;
        }
      }

      if (i == n) {
        //this is a new series segment
        series = [from, to];
        seriesStart = from;
        seriesEnd = to;
        collectedSeries.push(series);
      }

      for (var j:int = 0; j < n; j++) {
        var compareSeries:Array = collectedSeries[j];
        if (compareSeries == series) {
          //don't compare the series to itself.
          continue;
        }
        var compSeriesStart:String = compareSeries[0];
        var compSeriesEnd:String = compareSeries[compareSeries.length - 1];
        if (compSeriesStart == compSeriesEnd) { 
          //this series loops on itself, it will not concatenate further
          continue;
        }
        if (compSeriesStart == seriesEnd) {
          trace ("case 1");
          series = series.concat(compareSeries.slice(1));
        } else if (compSeriesStart == seriesStart) {
          trace ("case 2");
          series = compareSeries.reverse().concat(series.slice(1));
        } else if (compSeriesEnd == seriesStart) {
          trace ("case 3");
          series = compareSeries.concat(series.slice(1));
        } else if (compSeriesEnd == seriesEnd) {
          trace ("case 4");
          series = compareSeries.concat(series.reverse().slice(1));
        } else {
          //no linkage between these two series
          continue;
        }
        collectedSeries[i] = series; //replace one of the two segements
        collectedSeries.splice(j, 1); //splice out the other
        break;
      }
      trace ("series: " + series + (i == n ? " new" : ""));
    }
  }
}

这将给出以下结果：

A1,G1,F1,E1,D1,C1,B1,A1

G2,A2,B2,C2,D2,E2,F2,G2

G3,A3,B3,C3,D3,E3,F3,G3

G4,A4,B4,C4,D4,E4,F4,G4

我仍然非常感谢我能得到的任何建议/反馈。没人用Conrec吗？！

编辑：哎呀！我原来的 splice() 有一个错误！对不起！现在修复

于 2011-04-01T01:05:29.910 回答
-1

好的，所以 Flash 可能有更好的选择。我刚刚找到了这个链接，它看起来令人印象深刻。如果这有效，它消除了原来的问题......

ActionScript 3 的隔离包

于 2011-05-10T01:55:29.463 回答