1

我已经使用 vim 多年了，但我刚刚开始集成 eslint（通过ALE）。我发现有时我希望能够快速添加一个/* eslint-ignore-next-line */. 例如：

 ...
❌    if (m = /^-l(\d+)$/.exec(args[i])) t.len = m[1];
 ...
~/some/dir/file.js [+]          
cond-assign: Expected a conditional expression and instead saw an assignment.

ALE 在窗口底部为您提供代码真的很方便，但是因为懒惰，我想自动添加注释/提示：

/* eslint-ignore-next-line cond-assign */

有没有办法在 vim 脚本/函数中访问屏幕底部的信息？

4

2 回答 2

3

虽然没有记录，但 ALE 将 lint 信息存储在b:ale_highlight_items变量中。

David784 的解决方案对我不起作用，因为我使用 ALE 的g:ale_echo_msg_format配置选项自定义了位置列表文本。所以我修改它直接从位置列表中获取信息，b:ale_highlight_items而不是从位置列表中解析出来。

这里是：

command! ALEIgnoreEslint call AleIgnoreEslint()
function! AleIgnoreEslint()
  " https://stackoverflow.com/questions/54961318/vim-ale-shortcut-to-add-eslint-ignore-hint
  let l:codes = []
  if (!exists('b:ale_highlight_items'))
    echo 'cannot ignore eslint rule without b:ale_highlight_items'
    return
  endif
  for l:item in b:ale_highlight_items
    if (l:item['lnum']==line('.') && l:item['linter_name']=='eslint')
      let l:code = l:item['code']
      call add(l:codes, l:code)
    endif
  endfor
  if len(l:codes)
    exec 'normal O/* eslint-disable-next-line ' . join(l:codes, ', ') . ' */'
  endif
endfunction
于 2020-11-11T17:12:22.043 回答
2

幸运的是，ALE 使用内置location-list来存储它的 lint 消息，这可以通过 访问，寄存器getloclist({nr})在哪里。{nr}当前寄存器始终为0.

因此，这是一种获取当前行的所有 lint 消息并将它们全部添加到 eslint 提示注释的方法：

function AleIgnore()
  let codes = []
  for d in getloclist(0)
    if (d.lnum==line('.'))
      let code = split(d.text,':')[0]
      call add(codes, code)
    endif
  endfor
  if len(codes)
    exe 'normal O/* eslint-disable-next-line ' . join(codes, ', ') . ' */'
  endif
endfunction

此版本只会eslint-disable-next-line在当前行之前添加提示。扩展它以在文件顶部添加全局提示也很容易eslint-disable......困难的部分是弄清楚getloclist().

*编辑：我正在添加一个接受new-line参数的更新版本。如果是0，它将在文件顶部添加一个全局提示，如果是，它将在当前行上方1添加提示。-next-line但我也保留了以前的版本，因为它是一个更简单的例子，没有所有的三元组和东西。

function AleIgnore(nl)
  let codes = []
  for d in getloclist(0)
    if (d.lnum==line('.'))
      let code = split(d.text,':')[0]
      call add(codes, code)
    endif
  endfor
  if len(codes)
    exe 'normal mq' . (a:nl?'':'1G') . 'O'
          \ . '/* eslint-disable' . (a:nl?'-next-line ':' ')
          \ . join(codes, ', ') . ' */' . "\<esc>`q"
  endif
endfunction
于 2019-03-02T17:50:02.223 回答