0

这是我的问题（对我来说实际上是一个大问题）。

我有一个 1.130.395 行的 txt 文件，如下例所示：

10812
10954
10963
11070
11099
10963
11070
11099
betti.bt
betti12
betti1419432307
19442407
19451970
19461949

我有 2000 个 .gz 日志文件。

我需要为 .txt 文件的每一行对所有 .gz 文件执行 grep。

这是 gz 文件内容的示例，示例行：

time=2019-02-28 00:03:32,299|requestid=30ed0f2b-9c44-47d0-abdf-b3a04dbb560e|severity=INFO |severitynumber=0|url=/user/profile/oauth/{token}|params=username:juvexamore,token:b73ad88b-b201-33ce-a924-6f4eb498e01f,userIp:10.94.66.74,dtt:No|result=SUCCESS
time=2019-02-28 00:03:37,096|requestid=8ebca6cd-04ee-4818-817d-30f78ee95731|severity=INFO |severitynumber=0|url=/user/profile/oauth/{token}|params=username:10963,token:1d99be3e-325f-3982-a668-30494cab9a96,userIp:10.94.66.74,dtt:No|result=SUCCESS

txt 文件包含用户名。如果带有“profile”参数和“result=SUCCESS”的url存在用户名，我需要在gz文件中搜索。

如果找到某些内容，则仅写入日志文件： username found; name of the log file in which it was found

有可能做某事吗？我知道我需要使用 zgrep 命令，但是有人可以帮助我....可以自动化该过程以使其消失吗？

谢谢大家

4

2 回答 2

0

使用getline. 它读取file.txt用户名并对其进行哈希处理，然后将 gzip 作为参数给定的 gzip 压缩，split直到获取带有 的字段username:，提取实际的用户名并从哈希中搜索它。未正确测试等标准免责声明。让我知道它是否有效：

$ cat script.awk
BEGIN{
    while (( getline line < ARGV[1]) > 0 ) {       # read the username file
        a[line]                                    # and hash to a
    }
    close(ARGV[1])
    for(i=2;i<ARGC;i++) {                          # read all the other files
        cmd = "gunzip --to-stdout " ARGV[i]        # form uncompress command
        while (( cmd | getline line ) > 0 ) {      # read line by line
            m=split(line,t,"|")                    # split at pipe
            if(t[m]!="result=SUCCESS")             # check only SUCCESS records
                continue
            n=split(t[6],b,/[=,]/)                 # username in 6th field
            for(j=1;j<=n;j++)                      # split to find it, set to u var:
                if(match(b[j],/^username:/)&&((u=substr(b[j],RSTART+RLENGTH)) in a)) {
                    print u,"found in",ARGV[i]     # output if found in a hash
                        break                      # exit for loop once found
                }
        }
        close(cmd)
    }
}

运行它（使用相同数据的 2 个副本）：

$ awk -f script.awk file.txt log-0001.gz log-0001.gz
10963 found in log-0001.gz
10963 found in log-0001.gz
于 2019-02-28T17:46:49.990 回答
0

我会做（未经测试）：

zgrep -H 'url=/user/profile/oauth/{token}|params=username:.*result=SUCCESS' *.gz |
awk -F'[=:,]' -v OFS=';' 'NR==FNR{names[$0];next} $12 in names{print $12, $1}' names.txt - |
sort -u

或者可能更有效，因为它删除了NR==FNRzgrep 输出的每一行的测试：

zgrep -H 'url=/user/profile/oauth/{token}|params=username:.*result=SUCCESS' *.gz |
awk -F'[=:,]' -v OFS=';' '
    BEGIN {
        while ( (getline line < "names.txt") > 0 ) {
            names[line]
        }
        close("names.txt")
    }
    $12 in names{print $12, $1}' |
sort -u

如果给定的用户名在给定的日志文件中只能出现一次，或者您实际上希望多次出现以产生多个输出行，那么您不需要最终的| sort -u.

于 2019-03-01T00:56:12.563 回答