0

我是批处理新手，目前正在练习创建自动化脚本。我现在被困住了。我希望 zip 文件仅包含 tm_user.data，但我的代码会将其存档为 Fame\tm_user.data。如果你们中的任何人能帮助我，我将不胜感激。

变量

set default_folder_name=Main Folder
set tm_folder_name=TM Folder
set local_dir=C:\%default_folder_name%
set tm_dir=%local_dir%\%tm_folder_name%

主体

set /p id="Enter ID: "
set d = "tm_user.data"

if exist "%tm_dir%\%id%\Fame\%d%" (
    "C:\Program Files\7-Zip\7z.exe" a -tzip "%tm_dir%\%id%\Fame\%id%_fame.zip" "%tm_dir%\%id%\Fame\%d%"
    echo Process completed...
    timeout 2
    start "launch folder" "%tm_dir%\%id%\Fame"
    exit
) else (
        echo Error: %d% not found, please try again later!!
        timeout 5
        exit
    )
)
4

1 回答 1

1

批处理文件的一些最佳实践。

  1. 不要在SET命令中的等号两侧放置空格。等号之前的空格成为变量名的一部分，等号之后的空格被分配给变量。
  2. 不要为变量分配引号，但要使用它们来包围分配以保护特殊字符并避免将尾随空格分配给变量的末尾。

我选择使用PUSHDandPOPD命令。该PUSHD命令设置工作目录并将前一个目录存储在堆栈中。该POPD命令返回到先前存储的目录。使用这种技术，您不必在 7zip 命令中指定路径。

@echo off
set "default_folder_name=Main Folder"
set "tm_folder_name=TM Folder"
set "local_dir=C:\%default_folder_name%"
set "tm_dir=%local_dir%\%tm_folder_name%"

set /p "id=Enter ID: "
set "d=tm_user.data"

if exist "%tm_dir%\%id%\Fame\%d%" (
    pushd "%tm_dir%\%id%\Fame"
    "C:\Program Files\7-Zip\7z.exe" a -tzip "%id%_fame.zip" "%d%"
    echo Process completed...
    timeout 2
    start .
    popd
    exit
) else (
    echo Error: %d% not found, please try again later!!
    timeout 5
    exit
)
于 2019-02-27T04:57:19.950 回答