0

我创建了一个函数来刷新带有参数的查询，然后找到一个特定字段。

function RefreshQuery(AQuery : TADOQuery; AField : string; AValue : integer; AParam : string; AParamValue : Variant) : boolean; overload;

当 AValue 为整数时，它可以工作，当我将其更改为 Variant

我收到 List Index Out of Bounds 1699364 错误。

函数本身看起来像这样：

function RefreshQuery(AQuery : TADOQuery; AField : string; AValue : integer; AParam : string; AParamValue : Variant) : boolean; overload;
var AfterOpen,AfterScroll,BeforeOpen : TDataSetNotifyEvent;
    AList : TStringList;
    i : integer;
begin
  result:=false;

  AfterOpen := AQuery.AfterOpen;
  AfterScroll := AQuery.AfterScroll;
  BeforeOpen := AQuery.BeforeOpen;

  AQuery.AfterOpen:=nil;
  AQuery.AfterScroll:=nil;
  AQuery.BeforeOpen:=nil;

  AList := TStringList.Create;
  AList.Delimiter:=';';
  AList.DelimitedText:=AParam;

  if AQuery.Active then AQuery.Close;

  if AList.Count = 1 then
    AQuery.Parameters.ParamByName(AList[i]).Value:=AParamValue // the error happens here
  else
    for i := 0 to AList.Count-1 do
      AQuery.Parameters.ParamByName(AList[i]).Value:=AParamValue[i];

  AQuery.Open;

  if not AQuery.Locate(AField, AValue, []) then
    result:=false
  else
    result:=true;

  AQuery.AfterOpen:=AfterOpen;
  AQuery.AfterScroll:=AfterScroll;
  AQuery.BeforeOpen:=BeforeOpen;

  if Assigned(AQuery.AfterScroll) then
    AQuery.AfterScroll(AQuery);

  AList.Free;
end;

我这样使用它：

  if   RefreshQuery(CityQuery,'id',CityQueryID.Value,'Active',not(CheckBox1.Checked).ToInteger+2) = false then
  begin
    MessageDlg('blabla!',mtWarning, [mbOK], 0);
    Exit;
  end;

在上面的例子中 CityQueryID.Value 是 Integer Type 。但有时我想使用 String 。所以我想更改函数以使用变体。

4

1 回答 1

5

发生错误是因为在语句

  if AList.Count = 1 then
    AQuery.Parameters.ParamByName(AList[i]).Value:=AParamValue // the error happens here

你还没有给它赋值i，因为它是一个局部变量，它将有一个随机值，这取决于调用之前堆栈中RefreshQuery的内容。

将语句更改为

  if AList.Count = 1 then
    AQuery.Parameters.ParamByName(AList[0]).Value:=AParamValue

应该解决问题。

完成此操作后，您应该会发现可以毫无问题地将参数类型AValue更改为 。variant

于 2019-02-20T08:25:03.007 回答