0

我可以使用一些帮助。

这是我的 XML 的说明性示例：

<items>
 <item>  
  <name>Thing 1</name>
  <colors>
    <color>white</color>
    <color>green</color>
  </colors>  
  </item>
 <item>  
  <name>Thing 2</name>
  <colors>
    <color>purple</color>
    <color>white</color>
    <color>black</color>  
  </colors>
 </item>
 <item>  
  <name>Thing 3</name>
   <colors/>
 </item>
</items>

我的 xslt 的精简示例版本如下：

<xsl:key name="myGrouping" use="colors/color" match="item"/>  
<xsl:template match="/">
 <xsl:apply-templates select="items" mode="groupingTemplate"/>
</xsl:template>  

<xsl:template mode="groupingTemplate" match="items">  
 <xsl:for-each select="item[count(.|key('myGrouping',colors/color)[1])=1]">  
 <xsl:sort select="colors/color"/>  
 <xsl:if test="count(colors/color)&gt;0">
   <p><xsl:value-of select="colors/color"/></p>
   <xsl:for-each select="key('myGrouping',colors/color)">
   <xsl:sort select="name"/>
    <li><xsl:value-of select="name"/></li>
   </xsl:for-each>
  </xsl:if>
 </xsl:for-each>
</xsl:template>

我想做的是在 XSLT 1.0 中（使用 Muenchian 方法）在颜色节点上进行分组，所以我的 html 输出将是：

<p>black</p>  
<li>Thing 2</li>  

<p>green</p>  
<li>Thing 1</li>  

<p>purple</p>  
<li>Thing 2</li>  

<p>white<p>  
<li>Thing 1</li>  
<li>Thing 2</li>

到目前为止，我的代码可以做到这一点，但只能选择第一个条目。换句话说，在上面的例子中，我当前的输出是：

<p>white</p>
<li>Thing 1</li>
<li>Thing 2</li>

非常感谢您提供解决方案的帮助和解释为什么会发生这种情况。

谢谢！杰夫

4

1 回答 1

2

在拉了很多头发后想通了......下面的xsl可以解决问题 

<xsl:key name="byColor" use="." match="item/colors/color"/>  
<xsl:template match="/">
  <xsl:apply-templates select="items" mode="groupingTemplate"/>
</xsl:template>  

<xsl:template mode="groupingTemplate" match="items">  
  <xsl:for-each select="item/colors/color[count(.|key('byColor',.)[1])=1]">  
  <xsl:sort select="."/>  
  <xsl:if test="count(.)&gt;0">
    <p><xsl:value-of select="."/></p>
    <xsl:for-each select="key('byColor',.)">
     <xsl:sort select="../../name"/>
        <li><xsl:value-of select="../../name"/></li>
    </xsl:for-each>
   </xsl:if>
   </xsl:for-each>
 </xsl:template>
于 2011-03-26T03:31:38.140 回答