0

我正在尝试编写一个 bat 脚本以更好地组织我客户的文件。我创建了两个文件夹。第一个名为“文件夹”，其中包含每个客户端及其文件的文件夹。每个客户端的文件夹名称都具有结构 name_surname_uniqueclientid。第二个名为“Raw”，包含原始客户端文件和文件夹，但每个文件夹或文件在其名称中都包含唯一的客户端 ID。我的目标是从每个“文件夹”文件夹中提取每个 ID，并检查“原始”文件夹中是否有包含此 ID 的文件或文件夹。如果有，应该将它们复制到相应的“文件夹”中
我的问题是我无法检查包含 id 的文件夹并将它们移动到相应的“文件夹”文件夹。

我已经设法从文件夹的名称中提取 id，检查包含此 id 的“Raw”文件夹中的文件并将它们复制到相应的“folders”文件夹中。据我所知，脚本没有输入最后一个 if。它应该找到包含 id 的文件夹，如果有的话，将它们复制到相应的“文件夹”文件夹中。

    @echo off

    setlocal enabledelayedexpansion
    for /d %%a in ("folders\*") do (
        for /f "tokens=3 delims=_" %%t in ("%%~nxa") do ( 
        if exist "Raw\*%%t*" (
            xcopy "Raw\*%%t*" "%%a"
            )

下面这部分不起作用：

        if exist Raw\*%%t*\ (
            xcopy "Raw\*%%t*\*" "%%a" /s /i
            echo ok
            )
        )
    )
    pause   
    goto :eof

初始文件夹树

C:\DATA
├───folders
│   ├───FirstName_Lastname_10123
│   │   |
│   │   │   kjhda10123.rtf
│   │   │   dadsada10123lhlhfds.txt
│   │   │
│   │   └───kjhfdsfs10123f
│   ├───FirstName_Lastname_10124
│   │   │   jgkjgjfs10124kjlda.rtf
│   │   │   klhlidkas10124klhdas.txt
│   │   │
│   │   └───lkhjlkhdsakda10124
│   └───FirstName_Lastname_10125
│       │   kjhkdsa10125.rtf
│       │   10125dakjh.txt
│       │
│       └───10125
|           |   kjhkjda.txt
|           |   hkda.pdf  
└───Raw
    |   dsakhkhda10123.txt
    |   kgjddjasg10125.pdf
    |   kkkkdajh10123khda.docx
    |   10124dsadas
    |   
    └───vcb10125

后

C:\DATA
├───folders
│   ├───FirstName_Lastname_10123
│   │   |   kkkkdajh10123khda.docx
│   │   │   kjhda10123.rtf
│   │   │   dadsada10123lhlhfds.txt
|   |   |   dsakhkhda10123.txt
│   │   │
│   │   └───kjhfdsfs10123f
│   ├───FirstName_Lastname_10124
│   │   │   jgkjgjfs10124kjlda.rtf
│   │   │   klhlidkas10124klhdas.txt
│   │   │   10124dsadas
│   │   └───lkhjlkhdsakda10124
│   └───FirstName_Lastname_10125
│       │   kjhkdsa10125.rtf
│       │   10125dakjh.txt
│       │   kgjddjasg10125.pdf
|       |   vcb10125
│       └───10125
|           |   kjhkjda.txt
|           |   hkda.pdf  
└───Raw
    |   
    |   
    |   
    |   
    |   
    └───

如果文件夹已存在合并

4

2 回答 2

1

IMO 您的方法并没有那么糟糕，
但是if您需要另一个for方法来迭代/解析在 RAW 中找到的文件/文件夹。

我还要move文件，而不是复制：

:: Q:\Test\2019\01\10\SO_54120642.cmd
@echo off
Set "Base=C:\Data\folders"
Set "Src=C:\Data\Raw"

for /d %%A in ("%Base%\*") do (
    for /f "tokens=3 delims=_" %%T in ("%%~nxA") do (
        for /f "delims=" %%F in ('dir /B /A "%Src%\*%%T*" 2^>Nul') Do ( 
            Move "%Src%\%%F" "%%A\"
        )
    )
)
pause   
goto :eof

在我的 ramdrive 上模拟了你的树，结果如下：

> tree /F
└───DATA
    ├───folders
    │   ├───FirstName_Lastname_10123
    │   │   │   dadsada10123lhlhfds.txt
    │   │   │   dsakhkhda10123.txt
    │   │   │   kjhda10123.rtf
    │   │   │   kkkkdajh10123khda.docx
    │   │   │
    │   │   └───kjhfdsfs10123f
    │   ├───FirstName_Lastname_10124
    │   │   │   10124dsadas
    │   │   │   jgkjgjfs10124kjlda.rtf
    │   │   │   klhlidkas10124klhdas.txt
    │   │   │
    │   │   └───lkhjlkhdsakda10124
    │   └───FirstName_Lastname_10125
    │       │   10125dakjh.txt
    │       │   hkda.pdf
    │       │   kgjddjasg10125.pdf
    │       │   kjhkdsa10125.rtf
    │       │   kjhkjda.txt
    │       │
    │       ├───10125
    │       └───vcb10125
    └───Raw
于 2019-01-10T12:36:08.070 回答
1

问题？（我知道这会被否决，但我想帮助 OP 并尝试清楚地理解这个问题）

  1. 因此，为了说明这一点，您有两个名为 folders&Raw正确的主目录？

  2. 里面包含以您的格式folders命名的每个客户文件夹 是否正确？name_surname_uniqueclientid

  3. 里面Raw有“原始客户端文件和文件夹”，但每个文件的名称格式都name_surname_uniqueclientid正确吗？

  4. 猜测文件夹的实际名称是_uniqueclientid在示例之后_10123_taxing.rtf...？

文件夹树？

C:\DATA
├───folders
│   ├───FirstName_Lastname_10123
│   ├───FirstName_Lastname_10124
│   └───FirstName_Lastname_10125
└───Raw
    │   FirstName_Lastname_10123_taxing.rtf
    │   FirstName_Lastname_10123_text.txt
    │   FirstName_Lastname_10124_data.rtf
    │   FirstName_Lastname_10124_text.txt
    │   FirstName_Lastname_10125.rtf
    │   FirstName_Lastname_10125_text.txt
    │
    ├───FirstName_Lastname_10123_taxing
    ├───FirstName_Lastname_10124_numbers
    └───FirstName_Lastname_10125_names

目标？

因此，如果文件Raw夹内的任何文件包含uniqueclientid在您想要将它们复制到name_surname_uniqueclientid包含在folders.. 内的名称中？

新树？

C:\DATA
├───folders
│   ├───FirstName_Lastname_10123
│   │   │   FirstName_Lastname_10123_taxing.rtf
│   │   │   FirstName_Lastname_10123_text.txt
│   │   │
│   │   └───FirstName_Lastname_10123_taxing
│   ├───FirstName_Lastname_10124
│   │   │   FirstName_Lastname_10124_data.rtf
│   │   │   FirstName_Lastname_10124_text.txt
│   │   │
│   │   └───FirstName_Lastname_10124_numbers
│   └───FirstName_Lastname_10125
│       │   FirstName_Lastname_10125.rtf
│       │   FirstName_Lastname_10125_text.txt
│       │
│       └───FirstName_Lastname_10125_names
└───Raw

编辑：（工作解决方案）

如果这确实是您的问题，那么这是您的问题的有效解决方案。请注意，所有功能、代码块和流程都有一个Rem |在代码中逐步解释的内容。

因此，使用您的代码的基础，我们可以获取uniqueclientid并从那里我们将其设置为一个名为的字符串FolderIDNumber。此字符串将在 a 中使用，find以仅显示dir循环内的有效文件夹。

在循环使用主folders name_surname_uniqueclientid文件夹后，我们可以自由地处理Raw要移动的文件。这很容易，因为我们现在拥有dir. 我们有两个dir循环的原因是一个只抓取文件夹，另一个只抓取文件。这样我们就可以正确地COPY将它们指定到name_surname_uniqueclientid文件夹中。

@echo off
@setlocal enabledelayedexpansion

Rem | Configure Directories
Set "FolderLocation=C:\DATA\folders"
Set "RawLocation=C:\DATA\Raw"

Rem | Get All Folders Locations In X Directory
for /d %%A in ("!FolderLocation!\*") do (

    Rem | Set Raw Location
    Set "FoldersLoc=%%A"

    Rem | Get Each ID# From %%A
    for /f "tokens=3 delims=_" %%B in ("%%A") do (

        Rem | Set Folders ID#
        Set "FolderIDNumber=%%B"

    )

    Rem | Get Each Folder W/H !FolderIDNumber!
    for /f "tokens=*" %%C in ('Dir "!RawLocation!\" /B /A:D^| find "!FolderIDNumber!"') do (

        Rem | Set Raw Location & Name
        Set "RawFolderLoc=!RawLocation!\%%C"
        Set "RawFoldersName=%%~nC"

        Rem | Move Folders
        robocopy "!RawFolderLoc!" "!FoldersLoc!\!RawFoldersName!" /E /NJH /NJS /NDL /NFL /NC /NS>NUL

    )

    Rem | Get Each File W/H !FolderIDNumber!
    for /f "tokens=*" %%D in ('Dir "!RawLocation!\*.*" /B /A-D^| find "!FolderIDNumber!"') do (

        Rem | Set Raw Location
        Set "RawFileLoc=!RawLocation!\%%D"

        Rem | Move Files
        copy "!RawFileLoc!" "!FoldersLoc!">NUL

    )

)
goto :EOF

有关任何命令的帮助，请执行以下操作：

  • call /?
  • set /?
  • for /?
  • if /?
  • find /?
  • 很快。
于 2019-01-10T04:14:18.750 回答