如何使用 shift 来选择命令行的一部分(就像在许多文本编辑器中一样)?
4 回答
扩展了将近 3 年前 Stephane 的出色回答,我添加了更多绑定以使行为(几乎)与所有 Windows 的标准键盘行为完全一致:
- 使用导航键(箭头、home、end)时,选择被清除,没有 shift
Backspace
并Del
删除活动选择Ctrl+Shift+Left
使用/时选择扩展到下一个/上一个单词Ctrl+Shift+Right
Shift+Home
并将Shift+End
选择范围分别扩展到行的开头和结尾。Ctrl+Shift+Home
并Ctrl+Shift+End
做同样的事情。
不完全相同的两件事:
- 与窗口不同,将选择扩展到下一个单词包括尾随空格。这可以修复,但它不会打扰我。
- 在有活动选择时键入不会将其删除并用您键入的字符替换它。这似乎需要更多的工作来重新映射整个键盘。不值得给我麻烦。
请注意,默认的 mintty 行为是绑定Shift+End
和Shift+Home
访问回滚缓冲区。这取代了 zsh 配置;钥匙永远不会通过。为了使这些功能起作用,您需要在 或 中配置不同的键(或禁用回滚/etc/minttyrc
)~/.minttyrc
。请参阅此处的“滚动修改器” - 最简单的解决方案只是将ScrollMod=2
其绑定到Alt
而不是Shift
.
所以一切:
~/.minttyrc
ScrollMod=2
~/.zshrc
r-delregion() {
if ((REGION_ACTIVE)) then
zle kill-region
else
local widget_name=$1
shift
zle $widget_name -- $@
fi
}
r-deselect() {
((REGION_ACTIVE = 0))
local widget_name=$1
shift
zle $widget_name -- $@
}
r-select() {
((REGION_ACTIVE)) || zle set-mark-command
local widget_name=$1
shift
zle $widget_name -- $@
}
for key kcap seq mode widget (
sleft kLFT $'\e[1;2D' select backward-char
sright kRIT $'\e[1;2C' select forward-char
sup kri $'\e[1;2A' select up-line-or-history
sdown kind $'\e[1;2B' select down-line-or-history
send kEND $'\E[1;2F' select end-of-line
send2 x $'\E[4;2~' select end-of-line
shome kHOM $'\E[1;2H' select beginning-of-line
shome2 x $'\E[1;2~' select beginning-of-line
left kcub1 $'\EOD' deselect backward-char
right kcuf1 $'\EOC' deselect forward-char
end kend $'\EOF' deselect end-of-line
end2 x $'\E4~' deselect end-of-line
home khome $'\EOH' deselect beginning-of-line
home2 x $'\E1~' deselect beginning-of-line
csleft x $'\E[1;6D' select backward-word
csright x $'\E[1;6C' select forward-word
csend x $'\E[1;6F' select end-of-line
cshome x $'\E[1;6H' select beginning-of-line
cleft x $'\E[1;5D' deselect backward-word
cright x $'\E[1;5C' deselect forward-word
del kdch1 $'\E[3~' delregion delete-char
bs x $'^?' delregion backward-delete-char
) {
eval "key-$key() {
r-$mode $widget \$@
}"
zle -N key-$key
bindkey ${terminfo[$kcap]-$seq} key-$key
}
这涵盖了我使用过的几种不同键盘配置的键码。
注意: “key”列中的值没有任何意义,它们只是用来为 zle 构建一个命名引用。他们可以是任何东西。重要的是seq
,mode
和widget
列。
注意 2:您可以绑定几乎任何您想要的键,您只需要在控制台模拟器中使用的键码。打开常规控制台(不运行 zsh)并键入Ctrl+V,然后键入所需的键。它应该发出代码。^[
意味着\E
。
shift-arrow() {
((REGION_ACTIVE)) || zle set-mark-command
zle $1
}
shift-left() shift-arrow backward-char
shift-right() shift-arrow forward-char
shift-up() shift-arrow up-line-or-history
shift-down() shift-arrow down-line-or-history
zle -N shift-left
zle -N shift-right
zle -N shift-up
zle -N shift-down
bindkey $terminfo[kLFT] shift-left
bindkey $terminfo[kRIT] shift-right
bindkey $terminfo[kri] shift-up
bindkey $terminfo[kind] shift-down
这假设您的终端发送的转义序列与发送的转义序列不同Shift-Arrows,Arrow并且您的 terminfo 数据库正确填充了相应的 kLFT 和 kRIT 功能,并且您使用的是 emacs 样式的键绑定。
或者,将代码分解一下:
shift-arrow() {
((REGION_ACTIVE)) || zle set-mark-command
zle $1
}
for key kcap seq widget (
left LFT $'\e[1;2D' backward-char
right RIT $'\e[1;2C' forward-char
up ri $'\e[1;2A' up-line-or-history
down ind $'\e[1;2B' down-line-or-history
) {
functions[shift-$key]="shift-arrow $widget"
zle -N shift-$key
bindkey ${terminfo[k$kcap]-$seq} shift-$key
}
上面是 terminfo 数据库没有信息的情况下的硬编码序列(使用xterm
序列)。
扩展了 Jamie Treworgy 的回答。
包括以下功能:
cmd+a
: 选择整个命令行提示文本cmd+x
:剪切(复制和删除)当前命令行选择到剪贴板cmd+c
: 将当前命令行选择复制到剪贴板cmd+v
: 粘贴剪贴板选择ctrl+u
: 向后删除直到行首cmd+z
: 撤消cmd+shift+z
: 重做- 班次选择:
shift-left
: 选择左边的字符shift-right
: 选择右边的字符shift-up
: 向上选择行shift-down
:选择向下直播cmd-shift-left
: 选择直到行首cmd-shift-right
: 选择直到行尾alt-shift-left
: 选择左边的单词alt-shift-right
: 选择右边的单词ctrl-shift-left
: 选择直到行首ctrl-shift-right
: 选择直到行尾ctrl-shift-a
: 选择直到行首ctrl-shift-e
: 选择直到行尾
- 取消选择:按预期工作,在
left/right
,alt-left/right
,cmd/ctrl-left/right
,esc+esc
. - 删除选择
Delete
:在,ctrl+d
,上按预期工作backspace
- 删除选择和插入字符:对所有可见的 ASCII 字符和空格按预期工作
- 删除选择并插入剪贴板:按预期工作
.zshrc
# for my own convenience I explicitly set the signals
# that my terminal sends to the shell as variables.
# you might have different signals. you can see what
# signal each of your keys sends by running `$> cat`
# and pressing keys (you'll be able to see most keys)
# also some of the signals sent might be set in your
# terminal emulator application/program
# configurations/preferences. finally some terminals
# have a feature that shows you what signals are sent
# per key press.
#
# for context, at the time of writing these variables are
# set for the kitty terminal program, i.e these signals
# are mostly ones sent by default by this terminal.
export KEY_ALT_F='ƒ'
export KEY_ALT_B='∫'
export KEY_ALT_D='∂'
export KEY_CTRL_U=$'\x15' # ^U
export KEY_CMD_BACKSPACE=$'^[b' # arbitrary; added via kitty config (send_text)
export KEY_CMD_Z=^[[122;9u
export KEY_SHIFT_CMD_Z=^[[122;10u
export KEY_CTRL_R=$'\x12' # ^R
export KEY_CMD_C=^[[99;9u
export KEY_CMD_X=^[[120;9u
export KEY_CMD_V=^[[118;9u
export KEY_CMD_A=^[[97;9u
export KEY_CTRL_L=$'\x0c' # ^L
export KEY_LEFT=${terminfo[kcub1]:-$'^[[D'}
export KEY_RIGHT=${terminfo[kcuf1]:-$'^[[C'}
export KEY_SHIFT_UP=${terminfo[kri]:-$'^[[1;2A'}
export KEY_SHIFT_DOWN=${terminfo[kind]:-$'^[[1;2B'}
export KEY_SHIFT_RIGHT=${terminfo[kRIT]:-$'^[[1;2C'}
export KEY_SHIFT_LEFT=${terminfo[kLFT]:-$'^[[1;2D'}
export KEY_ALT_LEFT=$'^[[1;3D'
export KEY_ALT_RIGHT=$'^[[1;3C'
export KEY_SHIFT_ALT_LEFT=$'^[[1;4D'
export KEY_SHIFT_ALT_RIGHT=$'^[[1;4C'
export KEY_CMD_LEFT=$'^[[1;9D'
export KEY_CMD_RIGHT=$'^[[1;9C'
export KEY_SHIFT_CMD_LEFT=$'^[[1;10D'
export KEY_SHIFT_CMD_RIGHT=$'^[[1;10C'
export KEY_CTRL_A=$'\x01' # ^A
export KEY_CTRL_E=$'\x05' # ^E
export KEY_SHIFT_CTRL_A=$'^[[97;6u'
export KEY_SHIFT_CTRL_E=$'^[[101;6u'
export KEY_SHIFT_CTRL_LEFT=$'^[[1;6D'
export KEY_SHIFT_CTRL_RIGHT=$'^[[1;6C'
export KEY_CTRL_D=$'\x04' # ^D
# -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- --
# copy selected terminal text to clipboard
zle -N widget::copy-selection
function widget::copy-selection {
if ((REGION_ACTIVE)); then
zle copy-region-as-kill
printf "%s" $CUTBUFFER | pbcopy
fi
}
# cut selected terminal text to clipboard
zle -N widget::cut-selection
function widget::cut-selection() {
if ((REGION_ACTIVE)) then
zle kill-region
printf "%s" $CUTBUFFER | pbcopy
fi
}
# paste clipboard contents
zle -N widget::paste
function widget::paste() {
((REGION_ACTIVE)) && zle kill-region
RBUFFER="$(pbpaste)${RBUFFER}"
CURSOR=$(( CURSOR + $(echo -n "$(pbpaste)" | wc -m | bc) ))
}
# select entire prompt
zle -N widget::select-all
function widget::select-all() {
local buflen=$(echo -n "$BUFFER" | wc -m | bc)
CURSOR=$buflen # if this is messing up try: CURSOR=9999999
zle set-mark-command
while [[ $CURSOR > 0 ]]; do
zle beginning-of-line
done
}
# scrolls the screen up, in effect clearing it
zle -N widget::scroll-and-clear-screen
function widget::scroll-and-clear-screen() {
printf "\n%.0s" {1..$LINES}
zle clear-screen
}
function widget::util-select() {
((REGION_ACTIVE)) || zle set-mark-command
local widget_name=$1
shift
zle $widget_name -- $@
}
function widget::util-unselect() {
REGION_ACTIVE=0
local widget_name=$1
shift
zle $widget_name -- $@
}
function widget::util-delselect() {
if ((REGION_ACTIVE)) then
zle kill-region
else
local widget_name=$1
shift
zle $widget_name -- $@
fi
}
function widget::util-insertchar() {
((REGION_ACTIVE)) && zle kill-region
RBUFFER="${1}${RBUFFER}"
zle forward-char
}
# | key sequence | command
# --------------------- | ------------------------------- | -------------
bindkey $KEY_ALT_F forward-word
bindkey $KEY_ALT_B backward-word
bindkey $KEY_ALT_D kill-word
bindkey $KEY_CTRL_U backward-kill-line
bindkey $KEY_CMD_BACKSPACE backward-kill-line
bindkey $KEY_CMD_Z undo
bindkey $KEY_SHIFT_CMD_Z redo
bindkey $KEY_CTRL_R history-incremental-search-backward
bindkey $KEY_CMD_C widget::copy-selection
bindkey $KEY_CMD_X widget::cut-selection
bindkey $KEY_CMD_V widget::paste
bindkey $KEY_CMD_A widget::select-all
bindkey $KEY_CTRL_L widget::scroll-and-clear-screen
for keyname kcap seq mode widget (
left kcub1 $KEY_LEFT unselect backward-char
right kcuf1 $KEY_RIGHT unselect forward-char
shift-up kri $KEY_SHIFT_UP select up-line-or-history
shift-down kind $KEY_SHIFT_DOWN select down-line-or-history
shift-right kRIT $KEY_SHIFT_RIGHT select forward-char
shift-left kLFT $KEY_SHIFT_LEFT select backward-char
alt-right x $KEY_ALT_RIGHT unselect forward-word
alt-left x $KEY_ALT_LEFT unselect backward-word
shift-alt-right x $KEY_SHIFT_ALT_RIGHT select forward-word
shift-alt-left x $KEY_SHIFT_ALT_LEFT select backward-word
cmd-right x $KEY_CMD_RIGHT unselect end-of-line
cmd-left x $KEY_CMD_LEFT unselect beginning-of-line
shift-cmd-right x $KEY_SHIFT_CMD_RIGHT select end-of-line
shift-cmd-left x $KEY_SHIFT_CMD_LEFT select beginning-of-line
ctrl-e x $KEY_CTRL_E unselect end-of-line
ctrl-a x $KEY_CTRL_A unselect beginning-of-line
shift-ctrl-e x $KEY_SHIFT_CTRL_E select end-of-line
shift-ctrl-a x $KEY_SHIFT_CTRL_A select beginning-of-line
shift-ctrl-right x $KEY_SHIFT_CTRL_RIGHT select end-of-line
shift-ctrl-left x $KEY_SHIFT_CTRL_LEFT select beginning-of-line
del x $KEY_CTRL_D delselect delete-char
a x 'a' insertchar 'a'
b x 'b' insertchar 'b'
c x 'c' insertchar 'c'
d x 'd' insertchar 'd'
e x 'e' insertchar 'e'
f x 'f' insertchar 'f'
g x 'g' insertchar 'g'
h x 'h' insertchar 'h'
i x 'i' insertchar 'i'
j x 'j' insertchar 'j'
k x 'k' insertchar 'k'
l x 'l' insertchar 'l'
m x 'm' insertchar 'm'
n x 'n' insertchar 'n'
o x 'o' insertchar 'o'
p x 'p' insertchar 'p'
q x 'q' insertchar 'q'
r x 'r' insertchar 'r'
s x 's' insertchar 's'
t x 't' insertchar 't'
u x 'u' insertchar 'u'
v x 'v' insertchar 'v'
w x 'w' insertchar 'w'
x x 'x' insertchar 'x'
y x 'y' insertchar 'y'
z x 'z' insertchar 'z'
A x 'A' insertchar 'A'
B x 'B' insertchar 'B'
C x 'C' insertchar 'C'
D x 'D' insertchar 'D'
E x 'E' insertchar 'E'
F x 'F' insertchar 'F'
G x 'G' insertchar 'G'
H x 'H' insertchar 'H'
I x 'I' insertchar 'I'
J x 'J' insertchar 'J'
K x 'K' insertchar 'K'
L x 'L' insertchar 'L'
M x 'M' insertchar 'M'
N x 'N' insertchar 'N'
O x 'O' insertchar 'O'
P x 'P' insertchar 'P'
Q x 'Q' insertchar 'Q'
R x 'R' insertchar 'R'
S x 'S' insertchar 'S'
T x 'T' insertchar 'T'
U x 'U' insertchar 'U'
V x 'V' insertchar 'V'
W x 'W' insertchar 'W'
X x 'X' insertchar 'X'
Y x 'Y' insertchar 'Y'
Z x 'Z' insertchar 'Z'
0 x '0' insertchar '0'
1 x '1' insertchar '1'
2 x '2' insertchar '2'
3 x '3' insertchar '3'
4 x '4' insertchar '4'
5 x '5' insertchar '5'
6 x '6' insertchar '6'
7 x '7' insertchar '7'
8 x '8' insertchar '8'
9 x '9' insertchar '9'
exclamation-mark x '!' insertchar '!'
hash-sign x '\#' insertchar '\#'
dollar-sign x '$' insertchar '$'
percent-sign x '%' insertchar '%'
ampersand-sign x '\&' insertchar '\&'
star x '\*' insertchar '\*'
plus x '+' insertchar '+'
comma x ',' insertchar ','
dot x '.' insertchar '.'
forwardslash x '\\' insertchar '\\'
backslash x '/' insertchar '/'
colon x ':' insertchar ':'
semi-colon x '\;' insertchar '\;'
left-angle-bracket x '\<' insertchar '\<'
right-angle-bracket x '\>' insertchar '\>'
equal-sign x '=' insertchar '='
question-mark x '\?' insertchar '\?'
left-square-bracket x '[' insertchar '['
right-square-bracket x ']' insertchar ']'
hat-sign x '^' insertchar '^'
underscore x '_' insertchar '_'
left-brace x '{' insertchar '{'
right-brace x '\}' insertchar '\}'
left-parenthesis x '\(' insertchar '\('
right-parenthesis x '\)' insertchar '\)'
pipe x '\|' insertchar '\|'
tilde x '\~' insertchar '\~'
at-sign x '@' insertchar '@'
dash x '\-' insertchar '\-'
double-quote x '\"' insertchar '\"'
single-quote x "\'" insertchar "\'"
backtick x '\`' insertchar '\`'
whitespace x '\ ' insertchar '\ '
) {
eval "function widget::key-$keyname() {
widget::util-$mode $widget \$@
}"
zle -N widget::key-$keyname
bindkey $seq widget::key-$keyname
}
# suggested by "e.nikolov", fixes autosuggest completion being
# overriden by keybindings: to have [zsh] autosuggest [plugin
# feature] complete visible suggestions, you can assign an array
# of shell functions to the `ZSH_AUTOSUGGEST_ACCEPT_WIDGETS`
# variable. when these functions are triggered, they will also
# complete any visible suggestion. Example:
export ZSH_AUTOSUGGEST_ACCEPT_WIDGETS=(
widget::key-right
widget::key-shift-right
widget::key-cmd-right
widget::key-shift-cmd-right
)
奖金
有些人可能也会发现这些有用,虽然我没有在上面包含它们,只需将它们添加到 for-loop 数组中:
标签
tab x $'\x09' insertchar '\ '
- 请注意,选项卡完成将失败
其他
send kEND $'\E[1;2F' select end-of-line send2 x $'\E[4;2~' select end-of-line shome kHOM $'\E[1;2H' select beginning-of-line shome2 x $'\E[1;2~' select beginning-of-line end kend $'\EOF' deselect end-of-line end2 x $'\E4~' deselect end-of-line home khome $'\EOH' deselect beginning-of-line home2 x $'\E1~' deselect beginning-of-line csend x $'\E[1;6F' select end-of-line cshome x $'\E[1;6H' select beginning-of-line cleft x $'\E[1;5D' deselect backward-word cright x $'\E[1;5C' deselect forward-word del kdch1 $'\E[3~' delregion delete-char
旧但可能对某些人仍然有用
笔记
某些键盘按键序列首先在终端应用程序(在我的情况下为 iTerm2)上配置,以发送特定于 shell 程序的信号。上面代码中使用的绑定是:
➤ iTerm2
➤ Preferences
➤ Keys
➤ Key Bindings:
键序列 | 键绑定 |
---|---|
cmd+shift+left |
发送转义序列:a |
cmd+shift+right |
发送转义序列:e |
ctrl+shift+a |
发送转义序列:a |
ctrl+shift+e |
发送转义序列:e |
cmd+left |
发送十六进制代码:\x01 |
cmd+right |
发送十六进制代码:\x05 |
cmd+a |
发送转义序列:å |
cmd+c |
发送转义序列:ç |
cmd+v |
发送转义序列:√</code> |
cmd+x |
发送转义序列:≈</code> |
cmd+z |
发送转义序列:Ω |
cmd+shift+z |
发送转义序列:¸ |
此步骤将终端键绑定到 shell 信号,即告诉终端程序/应用程序 (iTerm2)zsh
在按下某些键盘键序列时向 shell 程序 ( ) 发送什么信号。根据您的终端程序和偏好,您可以根据需要绑定密钥,或使用默认信号。
keyboard --> cmd+z --> iTerm2 --> ^[Ω --> zsh --> undo (widget)
然后上面的脚本将接收到的信号绑定到外壳函数,称为小部件。即我们告诉外壳程序,在接收到指定的信号(键序列)时运行指定的小部件。
因此,在您的命令行上,按下键盘按键序列后,终端会向外壳发送适当的信号,外壳会调用相应的小部件(函数)。在这种情况下,我们告诉 shell 绑定的函数是编辑命令行本身的函数,就好像它是一个文件一样。
上面定义的小部件使用zsh
的内置zle
(zsh 行编辑器)模块 API。更多信息可以查看官方文档:ZSH ➤ 18 Zsh Line Editor和官方指南:ZSH ➤ Chapter 4: The Z-Shell Line Editor。
查看 shell 接收到的信号的一个巧妙技巧正在运行
cat
,然后按下键:❯ cat ^[[1;2D^[[1;2C^[Ω^[≈^[ç
这是按下后的输出:
shift-left
、shift-right
、cmd+z
、cmd+x
和cmd+c
。某些键可能不会出现。在这种情况下,请检查您的终端配置,该键可能绑定到某些终端功能(例如
cmd+n
,可能会打开一个新的终端窗格,cmd+t
可能会打开一个新的终端选项卡)。另请参阅
terminfo(5)
另一种查找某些键的方法。
已知问题和问题修复
如果您在 iTerm2 上,更改
cmd+v
绑定到的内容可能会使粘贴在命令行以外的任何内容上的行为有所不同,并且需要重新映射该特定程序(例如,在搜索提示中的程序等less
)。如果您想避免这种情况,请不要更改 iTerm2 的映射cmd+v
,并注释掉/删除widget::paste
.esc
oh-my-zsh
可能会与's插件发生冲突sudo
并给出奇怪的行为。您可以注释掉/删除esc
数组中的行,或提出修复建议。right
与 冲突zsh-autosuggestion
,即它不会接受该建议。您可以从数组中注释掉/删除right
,或提出修复建议。这可能是可能的,我只是目前不知道如何,并且花了足够的时间来尝试。我尝试了很多事情,我认为最接近工作的事情可能是:
function widget::key-right() { REGION_ACTIVE=0 zle autosuggest-accept zle forward-char } zle -N widget::key-right bindkey $'\eOC' widget::key-right
但无济于事。它没有完成建议。但是,您始终可以为它创建一个新的键绑定:
bindkey $'\e\'' autosuggest-accept
我autosuggestion-accept
从 Github 存储库中获得:zsh-users/zsh-autosuggestions。要修复与 的右键冲突
zsh-autosuggestion
和/或您可能遇到的其他冲突,请将.zshrc
以下内容添加到您的 shell 初始化文件之一(例如 ):(export ZSH_AUTOSUGGEST_ACCEPT_WIDGETS=(<shell-function> ...)
由@e.nikolov建议)。见上面的例子。
感谢您的回答,我让所有人放心,并使用键盘执行我的脚本来选择和复制。
如果有人想过滤更干净的东西,我将不胜感激。
它是 ~/.zshrc 文件的一部分到主用户文件夹中。
alias pbcopy="xclip -selection clipboard"
shift-arrow() {
((REGION_ACTIVE)) || zle set-mark-command
zle $1
}
for key kcap seq widget (
left LFT $'\e[1;2D' backward-char
right RIT $'\e[1;2C' forward-char
up ri $'\e[1;2A' up-line-or-history
down ind $'\e[1;2B' down-line-or-history
super sup $'\ec' widget::copy-selection
) {
functions[shift-$key]="shift-arrow $widget"
zle -N shift-$key
bindkey ${terminfo[k$kcap]-$seq} shift-$key
}
zle -N widget::copy-selection
# copy selected terminal text to clipboard
function widget::copy-selection {
if ((REGION_ACTIVE)); then
zle copy-region-as-kill
printf "%s" $CUTBUFFER | pbcopy
fi
}
我使用 de windows+c 按钮复制选定的字符。我正在使用 ubuntu 20.04 并将键盘选项配置为使用像元这样的 win 按钮!在此之后,在终结者的偏好中,我将粘贴快捷方式更改为 windows+v,jts,因为我认为它像 control+x 和 COControl+v 一样更快