3

我当前的项目使用具有 40 种不同类型（可区分联合）的 AST，并且该 AST 中的几种类型具有循环依赖性。类型不是那么大，因此我将它们放在一个文件中并type ... and ...为相互依赖的类型应用构造。

现在，我正在添加函数以在 AST 中的每个元素下进行一些计算。由于有很多函数，其中包含几行代码，为了使源代码更清晰易读，我将这些函数分隔在不同的文件中。

在没有循环依赖的情况下没关系，当依赖函数在同一个文件中时也可以 - 在这种情况下我可以使用let rec function1 ... and function2 ...构造。

但在我的情况下它不起作用。

另外，我错误地认为签名文件可以帮助我解决这个问题，但它们的行为与 C++ 不同

  • 它们用于定义函数/类型访问模式（内部/公共），也可以在此处添加函数/类型注释头。

我看到的唯一可能的解决方案是将所有功能移动到一个文件并使用let rec ... and ... and ... and ... and ...构造。

可能有人有不同的想法？

4

1 回答 1

6

正如评论中提到的，没有办法在多个文件之间拆分具有循环依赖关系的函数（或类型）。签名文件主要用于文档目的，因此它们无济于事。

如果不知道依赖项到底是什么，就很难给出一些建议。但是，可以使用函数或接口重构实现的某些部分。例如，如果您有：

let rec process1 (a:T1) = 
  match a with
  | Leaf -> 0
  | T2Thing(b) -> process2 b

and process2 (b:T2) = 
  match b with 
  | T1Thing(a) -> process1 a

您可以修改函数process1以将第二个函数作为参数。这使得可以在两个文件之间拆分实现，因为它们不再相互递归：

// File1.fs
let process1 (a:T1) process2 = 
  match a with
  | Leaf -> 0
  | T2Thing(b) -> process2 b

// File2.fs
let rec process2 (b:T2) = 
  match b with 
  | T1Thing(a) -> process1 a process2

如果你能找到一些更清晰的结构——例如两个函数块包含逻辑相关的函数并且需要相互访问，那么你也可以定义一个接口。这对于只有两个函数的示例没有多大意义，但它看起来像这样：

type IProcess2 = 
  abstract Process : T2 -> int

let process1 (a:T1) (process2:IProcess2) = 
  match a with
  | Leaf -> 0
  | T2Thing(b) -> process2.Process b

let rec process2 (b:T2) = 
  let process2i = 
    { new IProcess2 with 
        member x.Process(a) = process2 a }
  match b with 
  | T1Thing(a) -> 
    process1 a process2i

无论如何，这些只是一些通用技术。如果不了解您正在使用的类型的更多信息，很难给出更精确的建议。如果您可以分享更多细节，也许我们可以找到一种方法来避免一些递归引用。

于 2011-03-23T14:08:47.023 回答