0

我有一个关于使用 Microsoft Access 按与用户输入的邮政编码的距离对我的客户进行排序（见下表）的问题。我正在使用大圆距离公式（见下面的代码）来计算邮政编码之间的距离。我有一张美国当前邮政编码的表格及其纬度和经度坐标（见下面的第二张表格）。该函数获取每个客户的邮政编码，并从第一张和第二张表格中获取纬度和经度并使用它来计算每个之间的距离。这是我正在运行的调用GreatCircleDistance公式的 SQL 查询：

PARAMETERS [Zip Code] IEEEDouble;
SELECT Clinics.Clinic, [US Zip Codes].ZIP, 
      [US Zip Codes].LAT, [US Zip Codes].LNG, 
      GreatCircleDistance([Zip Code],[LAT],[LNG],True,True) AS Distance
FROM [US Zip Codes] INNER JOIN Clinics ON [US Zip Codes].ZIP = Clinics.[Clinic ZIP];

用于此查询的大圆距离公式如下所示：

Private Const C_RADIUS_EARTH_KM As Double = 6370.97327862
Private Const C_RADIUS_EARTH_MI As Double = 3958.73926185
Private Const C_PI As Double = 3.14159265358979

Function GreatCircleDistance(ZipCode As Double, _
        Latitude2 As Double, Longitude2 As Double, _
        ValuesAsDecimalDegrees As Boolean, _
        ResultAsMiles As Boolean) As Double

Dim lat1 As Double
Dim lat2 As Double
Dim long1 As Double
Dim long2 As Double
Dim X As Long
Dim Delta As Double

If ValuesAsDecimalDegrees = True Then
    X = 1
Else
    X = 24
End If

' convert to decimal degrees
'POTENTIAL PROBLEM
lat1 = DLookup("[US Zip Codes].LAT", "[US Zip Codes]", "[US Zip Codes].ZIP = '" & ZipCode & "'") * X
long1 = DLookup("[US Zip Codes].LNG", "[US Zip Codes]", "[US Zip Codes].ZIP = '" & ZipCode & "'") * X
'POTENTIAL PROBLEM

lat2 = Latitude2 * X
long2 = Longitude2 * X

' convert to radians: radians = (degrees/180) * PI
lat1 = (lat1 / 180) * C_PI
lat2 = (lat2 / 180) * C_PI
long1 = (long1 / 180) * C_PI
long2 = (long2 / 180) * C_PI

' get the central spherical angle
Delta = ((2 * ArcSin(Sqr((Sin((lat1 - lat2) / 2) ^ 2) + _
Cos(lat1) * Cos(lat2) * (Sin((long1 - long2) / 2) ^ 2)))))

If ResultAsMiles = True Then
    GreatCircleDistance = Delta * C_RADIUS_EARTH_MI
Else
    GreatCircleDistance = Delta * C_RADIUS_EARTH_KM
End If

End Function



Function ArcSin(X As Double) As Double
    ' VBA doesn't have an ArcSin function. Improvise.
    ArcSin = Atn(X / Sqr(-X * X + 1))
End Function

这是包含我所有客户的第一张桌子。为了简单起见，我只添加了三个，但文件中大约有 2000 条记录：

Clinic            City        State     Clinic ZIP
Clinic #1       Lakeland        FL         33809
Clinic #2        Smyrna         TN         37167
Clinic #3       Kissimmee       FL         34747
...

这是包含每个美国邮政编码的第二个表。有记录的邮政编码超过 41,000 个：

ID       ZIP         LAT           LNG
1       00501      40.8133      -73.0476      
2       00601       18.18       -66.7522
3       00602      18.3607      -67.1752
4       00603      18.4544       -67.122
...

现在这种方法有效，但计算输入邮政编码和每个 2000ish 客户端邮政编码的邮政编码之间的距离需要很长时间。当我使用DLookUp函数获取用户输入的邮政编码的纬度和经度时，我认为问题出在大圆距离公式中。有谁知道我可以如何减少计算时间？谢谢

4

2 回答 2

2

由于您需要比较两对不相关的坐标，请考虑在 MS Access 中使用逗号分隔的源FROM子句中的交叉连接查询。然后将两对LAT和LNG传入距离公式。

但是，请务必包含WHERE子句以过滤作为参数传入的特定邮政编码（否则您将运行两组的笛卡尔积）。这应该返回一个单行结果集，以对所有内连接行重复：

PARAMETERS [ZipCodeParam] TEXT(255);
SELECT c.Clinic, us.ZIP, us.LAT, us.LNG, 
       p.ZIP, p.LAT, p.LNG,
       GreatCircleDistance(p.[LAT], p.[LNG], us.[LAT], us.[LNG], True, True) AS Distance
FROM [US Zip Codes] p, 
     ([US Zip Codes] us
      INNER JOIN Clinics c
          ON us.ZIP = c.[Clinic ZIP])
WHERE p.ZIP = ZipCodeParam;

当然调整函数参数并删除不需要的DLookUp调用：

Function GreatCircleDistance(Latitude1 As Double, Longitude1 As Double, _
        Latitude2 As Double, Longitude2 As Double, _
        ValuesAsDecimalDegrees As Boolean, _
        ResultAsMiles As Boolean) As Double

...

lat1 = Latitude1 * X
lng1 = Longitude1 * X

lat2 = Latitude2 * X
lng2 = Longitude2 * X

...

End Function
于 2019-01-05T17:36:44.490 回答
0

Dlookup 代码可能是问题所在。您的 DLookup 代码看起来不正确，并且无法在我的系统上运行。此代码有效：

lat1 = DLookup("LAT", "[美国邮政编码]", "ZIP = " & ZipCode) * X

lat1 = DLookup("LNG", "[US Zip Codes]", "ZIP = " & ZipCode) * X

https://www.techonthenet.com/access/functions/domain/dlookup.php

于 2019-01-05T11:02:59.837 回答