1

我正在尝试制作一个程序，该程序将在TWebBrowser组件内部加载网站上的各个区域的屏幕截图。

到目前为止，我只找到了“如何制作整个页面的屏幕截图”的解决方案，但我无法让它捕捉特定区域，它只是将页面拉伸到任何方向。

http://www.delphifaq.com/faq/f408.shtml

我一直在使用上面网站中提供的代码。

有没有办法修改代码，所以它会做我需要的？我试过但我失败了。

如果有人至少能给我一个解决这个问题的方向，我将不胜感激。

谢谢

4

3 回答 3

4

我建议改用IHTMLElementRenderHTML Elemwnt 的界面。您可以轻松找到光标下的元素并将其渲染为位图。

在我的 TWebBrowser descant 我这样实现它：

function TWebBrowserIBMA.ElementAsBitmap(pElement : IHTMLElement2) : TBitmap;
var
  pRender       : IHTMLElementRender;
  oBmpPart      : TBitmap;
  nClientWidth  : Integer;
  nClientHeight : Integer;
  nX            : Integer;
  nLastX        : Integer;
  bDoneX        : Boolean;
  nY            : Integer;
  nLastY        : Integer;
  bDoneY        : Boolean;
begin
  Result := TBitmap.Create;

  try
    Result.Height := pElement.scrollHeight;
    Result.Width  := pElement.scrollWidth;
  except
    exit;
  end;

  LockWindowUpdate(Handle);

  if (pElement.QueryInterface(IID_IHTMLElementRender, pRender) = S_OK) then begin
    try
      oBmpPart        := TBitmap.Create;
      oBmpPart.Width  := pElement.scrollWidth;
      oBmpPart.Height := pElement.scrollHeight;
      nClientWidth    := pElement.clientWidth;
      nClientHeight   := pElement.clientHeight;

      try
        nX      := pElement.scrollWidth; 
        nLastX  := -1;
        bDoneX  := false;

        while not bDoneX do begin
          pElement.scrollLeft := nX;
          nX := pElement.scrollLeft;
          if nLastX = -1 then begin
            nLastX := nX + nClientWidth;
          end;
          nY     := pElement.scrollHeight;
          nLastY := (-1);
          bDoneY := false;

          while not bDoneY do begin
            pElement.scrollTop := nY;
            nY := pElement.scrollTop;

            if nLastY = -1 then begin
              nLastY := nY + nClientHeight;
            end;

            if (pRender.DrawToDC(oBmpPart.Canvas.Handle) = S_OK) then begin
              BitBlt(Result.Canvas.Handle, nX, nY, nLastX-nX, nLastY-nY, oBmpPart.Canvas.Handle, 2, 2,SRCCOPY);
            end;

            bDoneY  := (nY = 0);
            nLastY  := nY;
            Dec(nY, nClientHeight-4);  
          end;

          bDoneX  := (nX = 0);
          nLastX  := nX;
          Dec(nX, (nClientWidth-4));
        end;
      finally
        FreeAndNil(oBmpPart);
      end;
    finally
      pRender := nil;
    end;
  end;

  LockWindowUpdate(0);
end;
于 2011-03-24T08:05:16.880 回答
1

您可以使用 sourceBitmap.Canvas.CopyRect

于 2011-03-23T13:05:04.290 回答
0

您是否尝试过设置sourceDrawRect一个矩形，其顶部和左侧为负，右侧和底部超出您让视图对象绘制的位图的宽度和高度，以便您想要的区域落在该位图上？

于 2011-03-23T13:00:12.930 回答