2

我正在用数学编写一个生命游戏程序但是有一个警告，我需要能够将复制规则应用于一定百分比的单元格，我想尝试使用 MapAt 的新方法，但 liveNeighbors 不起作用elementwise，如果不完全按照我之前所做的（很多混乱的索引），我想不出一种修复它的方法，有人有什么建议吗？（我假设这会比下面列出的旧方法更有效，如果不是请告诉我，我只是一个初学者！）。

我正在尝试做的事情：

 Map[ArrayPlot,FixedPointList[MapAt[update[#,liveNeighbors[#]]&,#,coords]&,Board, 1]]

我已经做了什么：

LifeGame[ n_Integer?Positive, steps_] := Module [{Board, liveNeighbors, update},
  Board = Table [Random [Integer], {n}, {n}];
  liveNeighbors[ mat_] := 
   Apply[Plus,Map[RotateRight[mat,#]&,{{-1,-1},{-1, 0},{-1,1}, {0, -1}, {0, 1}, {1, -1}, {1, 0}, {1, 1}}]];
  update[1, 2] := 1;
  update[_, 3] := 1;
  update[ _, _] := 0;
  SetAttributes[update, Listable];
 Seed = RandomVariate[ProbabilityDistribution[0.7 UnitStep[x] + 0.3 UnitStep[x - 1], {x, 0, 1, 1}], {n, n}];
 FixedPointList[Table[If[Seed[[i, j]] == 1,update[#[[i, j]], liveNeighbors[#][[i, j]]],#[[i, j]]], {i, n}, {j, n}]&, Board, steps]]]

谢谢！

4

3 回答 3

5 
In[156]:= 
LifeGame2[n_Integer?Positive, steps_] := 
 Module[{Board, liveNeighbors, update},
  Board = RandomInteger[1, {n, n}];
  liveNeighbors[mat_] := 
   ListConvolve[{{1, 1, 1}, {1, 0, 1}, {1, 1, 1}}, 
    ArrayPad[mat, 1, "Periodic"]];
  SetAttributes[update, Listable];
  Seed = RandomVariate[BernoulliDistribution[0.3], {n, n}];
  update[0, el_, nei_] := el;
  update[1, 1, 2] := 1;
  update[1, _, 3] := 1;
  update[1, _, _] := 0;
  FixedPointList[MapThread[update, {Seed, #, liveNeighbors[#]}, 2] &, 
   Board, steps]
  ]

这个实现和你的一样，除了快得多：

In[162]:= AbsoluteTiming[
 res1 = BlockRandom[SeedRandom[11]; LifeGame[20, 100]];]

Out[162]= {6.3476347, Null}

In[163]:= Timing[BlockRandom[Seed[11]; LifeGame2[20, 100]] == res1]

Out[163]= {0.047, True}
于 2011-03-22T21:12:24.337 回答
4

假设您不必为家庭作业问题编写自己的代码，您是否考虑过仅使用内置CellularAutomaton函数？

直接来自文档，2D CA 规则：

GameOfLife = {224, {2, {{2, 2, 2}, {2, 1, 2}, {2, 2, 2}}}, {1, 1}};

并在 100x100 网格上迭代 100 步：

ArrayPlot[CellularAutomaton[GameOfLife, RandomInteger[1, {100, 100}], {{{100}}}]]

元胞自动机的输出

它至少会给你一个速度比较的基线。

而不是MapAt，您可以使用PartwithSpan语法一次替换整个子数组：

a = ConstantArray[0, {5, 5}];
a[[2 ;; 4, 2 ;; 4]] = {{1, 2, 3}, {4, 5, 6}, {7, 8, 9}}

MatrixForm 中的一个

！

于 2011-03-22T21:03:50.307 回答
0

在这里，您有我的高尔夫版本。

于 2011-03-22T22:32:40.163 回答