6

由于我一直在使用kotlin-reflect来调用我的默认值并声明了一个，因此我看到了第二个不同的构造函数。

我已经意识到两个不同的字段int arg3和kotlin.jvm.internal.DefaultConstructorMarker arg4添加到我的构造函数中。

data class Model(
    @SerializedName("xyz") val entity: String?,
    @SerializedName("abc") val id: Long? = null
)
val constructors = clazz.declaredConstructors // how I call the constructors

我的实际问题是为什么我有这两个字段，它背后的逻辑是什么？

提前致谢。

4

1 回答 1

14

这两个参数被添加到 Kotlin 编译器为所有具有默认参数的函数和构造函数生成的特殊合成成员中。

isSynthetic()使用 Java 反射，您可以通过检查并找到不是的来过滤掉这些合成函数和构造函数。

整数参数是位掩码。当从 Kotlin 调用这样的函数时，会生成一个位掩码并作为参数传递。这些位显示函数的哪些默认参数被传递显式参数，哪些应该使用默认值。

该DefaultConstructorMarker参数用于确保合成构造函数（接受位掩码）与不同的构造函数没有冲突，该构造函数的签名具有相同的参数，Int最后是一个。传递给标记参数的参数不以任何方式使用，并且始终为null.

实际上，为每个函数或构造函数分别生成了两个方法或构造函数，它们至少具有一个默认参数：一个与声明的签名相同且没有附加参数，另一个也接受位掩码和标记。

如果你检查这样一个函数的字节码，你会发现大致如下的函数声明：

fun foo(bar: String, baz: List<String> = emptyList(), qux: Set<String> = emptySet()) = 0

字节码中真正的方法是：

// access flags 0x19
// signature (Ljava/lang/String;Ljava/util/List<Ljava/lang/String;>;Ljava/util/Set<Ljava/lang/String;>;)I
// declaration: int foo(java.lang.String, java.util.List<java.lang.String>, java.util.Set<java.lang.String>)
public final static foo(
    Ljava/lang/String;
    Ljava/util/List;
    Ljava/util/Set;
)I
  // annotable parameter count: 3 (visible)
  // annotable parameter count: 3 (invisible)
  @Lorg/jetbrains/annotations/NotNull;() // invisible, parameter 0
  @Lorg/jetbrains/annotations/NotNull;() // invisible, parameter 1
  @Lorg/jetbrains/annotations/NotNull;() // invisible, parameter 2
L0
  ALOAD 0
  LDC "bar"
  INVOKESTATIC kotlin/jvm/internal/Intrinsics.checkParameterIsNotNull (Ljava/lang/Object;Ljava/lang/String;)V
  ALOAD 1
  LDC "baz"
  INVOKESTATIC kotlin/jvm/internal/Intrinsics.checkParameterIsNotNull (Ljava/lang/Object;Ljava/lang/String;)V
  ALOAD 2
  LDC "qux"
  INVOKESTATIC kotlin/jvm/internal/Intrinsics.checkParameterIsNotNull (Ljava/lang/Object;Ljava/lang/String;)V
L1
  LINENUMBER 16 L1
  ICONST_0
  IRETURN
L2
  LOCALVARIABLE bar Ljava/lang/String; L0 L2 0
  LOCALVARIABLE baz Ljava/util/List; L0 L2 1
  LOCALVARIABLE qux Ljava/util/Set; L0 L2 2
  MAXSTACK = 2
  MAXLOCALS = 3

处理位掩码并在必要时计算默认值的生成包装器是一个单独的方法：

// access flags 0x1009
public static synthetic foo$default(
    Ljava/lang/String;
    Ljava/util/List;
    Ljava/util/Set;
    I
    Ljava/lang/Object;
)I
  ILOAD 3
  ICONST_2
  IAND
  IFEQ L0
L1
  LINENUMBER 16 L1
  INVOKESTATIC kotlin/collections/CollectionsKt.emptyList ()Ljava/util/List;
  ASTORE 1
L0
  ILOAD 3
  ICONST_4
  IAND
  IFEQ L2
  INVOKESTATIC kotlin/collections/SetsKt.emptySet ()Ljava/util/Set;
  ASTORE 2
L2
  ALOAD 0
  ALOAD 1
  ALOAD 2
  INVOKESTATIC FooKt.foo (Ljava/lang/String;Ljava/util/List;Ljava/util/Set;)I
  IRETURN
  MAXSTACK = 3
  MAXLOCALS = 5

请注意后者如何检查位掩码（使用ILOAD 3, ICONST_x, IAND）然后有条件地（当IFEQ Lx不跳过它时）评估默认参数。

构造函数与普通函数的不同之处在于它们的名称中不能有后缀$default，因此标记是必要的，以避免可能的签名冲突。

于 2018-12-24T11:40:36.553 回答