0

我有一张叫电话簿的表，它有两列(firstName, LastName)。我想使用游标按 firstName 创建一个 lastName 索引表，我编写了以下代码：

CREATE OR REPLACE PROCEDURE proc1 AS
    TYPE tableNames IS TABLE OF VARCHAR2(20) INDEX BY VARCHAR(20);
    v1 tableNames;
    v_firstName PHONEBOOK.FIRSTNAME%TYPE;
    v_lastName PHONEBOOK.LASTNAME%TYPE;
    CURSOR c_name IS SELECT FIRSTNAME, LASTNAME FROM PHONEBOOK;
BEGIN
    OPEN c_name;
    LOOP
        FETCH c_name INTO v_firstName, v_lastName;
        EXIT WHEN c_name%NOTFOUND;
        v1(v_firstName) := v_lastName;
    END LOOP;

    FOR idx IN v1.FIRST..v1.LAST 
    LOOP
        DBMS_OUTPUT.PUT_LINE (v1(idx));
    END LOOP;

    CLOSE c_name;
END;
/

它已成功编译。当我运行此过程时，它应该打印存储在 tableNames 中的 lastNames 但它给了我一个错误：

ORA-06502“PL/SQL：数字或值错误”
原因： 发生算术、数字、字符串、转换或约束错误。例如，如果尝试将值 NULL 分配给声明为 NOT NULL 的变量，或者尝试将大于 99 的整数分配给声明为 NUMBER(2) 的变量，则会发生此错误。
行动： 改变数据，它是如何被操纵的，或者它是如何被声明的，这样值就不会违反约束。

请帮我解决这个问题

4

1 回答 1

1

不是FOR，但是WHILE。另外，我使用游标FOR循环作为源；更容易编写和维护。

SQL> create table phonebook (firstname varchar2(10), lastname varchar2(10));

Table created.

SQL> insert into phonebook
  2    select 'Little', 'Foot'    from dual union all
  3    select 'Mc'    , 'Donalds' from dual;

2 rows created.

SQL> create or replace procedure proc1 as
  2    type tablenames is table of varchar2(10) index by varchar2(10);
  3    v1 tablenames;
  4    idx varchar2(10);
  5  begin
  6    for cur_r in (select firstname, lastname
  7                  from phonebook
  8                 )
  9    loop
 10      v1(cur_r.firstname) := cur_r.lastname;
 11    end loop;
 12
 13    idx := v1.first;
 14    while idx is not null loop
 15      dbms_output.put_line(v1(idx));
 16      idx := v1.next(idx);
 17    end loop;
 18  end;
 19  /

Procedure created.

SQL> exec proc1;
Foot
Donalds

PL/SQL procedure successfully completed.

SQL>
于 2018-12-06T20:26:48.027 回答