excel - 从 URL 获取图像文件尺寸

Question

我有这个链接： https ://s23527.pcdn.co/wp-content/uploads/2017/04/wine_speedlights_kit_lens.jpg.optimal.jpg

它在单元格 A2 上：

我想在单元格 B2 上获取此 JPG 的 URL 的尺寸

（我不介意如何得到它，它可以是 1920 on cellB2和 1080 on cell C2）

Answer 1

您需要调用 APIURLDownloadToFile来下载您的图像。在下面的示例中，我们将下载到临时文件夹C:\Temp\。

下载图像后，您将创建一个新的 Shell 对象，并最终使用该.ExtendedProperty()属性来获取文件尺寸

下载完文件后，您可以继续使用 删除临时文件Kill()。

下面的方法使用Early Binding。您将需要设置一个参考

Microsoft Shell Controls And Automation

通过进入Tools -> ReferencesVBE 菜单

Option Explicit

#If VBA7 Then
    Declare PtrSafe Function URLDownloadToFile Lib "urlmon" Alias "URLDownloadToFileA" _
            (ByVal pCaller As Long, ByVal szURL As String, ByVal szFileName As String, _
            ByVal dwReserved As Long, ByVal lpfnCB As Long) As Long
#Else
    Declare Function URLDownloadToFile Lib "urlmon" Alias "URLDownloadToFileA" _
            (ByVal pCaller As Long, ByVal szURL As String, ByVal szFileName As String, _
            ByVal dwReserved As Long, ByVal lpfnCB As Long) As Long
#End If

Sub test()

    Const tmpDir$ = "C:\Temp\"
    Const tmpFile$ = "tmpPicFile.jpg"
    
    Debug.Print URLDownloadToFile(0, ActiveSheet.Range("A2").Value, tmpDir & tmpFile, 0, 0)
    ActiveSheet.Range("B2").Value = getFileDimensions(tmpDir, tmpFile)
    Kill tmpDir & tmpFile

End Sub

Private Function getFileDimensions(filePath$, fileName$) As String

    With New Shell32.Shell
        With .Namespace(filePath).ParseName(fileName)
            getFileDimensions = .ExtendedProperty("Dimensions")
        End With
    End With
    
End Function