c++ - glsl 错误：“v_color”在尝试使用镶嵌着色器渲染时未声明为前一阶段的输出

Question

我希望我的渲染器能够使用镶嵌着色器，但是在运行时，调试器说

%s
Link info
---------
error: "v_color" not declared as an output from the previous stage

我不知道它到底是什么意思。

v_color 是 vec4 中的片段着色器，它来自顶点着色器，顶点着色器从 vbo 获取这个值，如下所示：

#version 420 core                                                 

layout (location = 1) in vec4 a_color                             
out vec4 v_color;                                                 
void main(void)                                                   
{                                                                    
    gl_Position = //something;                          
    v_color = a_color;                                            
}  

---

#version 420 core                                                  

out vec4 color;                                                    
in vec4 v_color;                                                   

void main(void)                                                    
{                                                                  
    color = v_color;                                               
}         

并且顶点着色器从顶点属性指针获取 a_color。

为什么它返回错误？

Answer 1

每个着色器阶段将输出传递到下一个阶段的输入。顶点着色器之后是细分控制着色器，然后是细分评估着色器，最后是片段着色器（如果没有几何着色器）。

如果您有一个曲面细分着色器并且您想将一个属性从顶点着色器传递到片段着色器，那么您必须将该属性传递给所有着色器阶段：

例如：

顶点着色器：

#version 420 core                                                 

layout (location = 1) in vec4 a_color                             
out vec4 v_color;                                                 

void main(void)                                                   
{                                                                    
   v_color = a_color;

   // .....                                            
}

镶嵌控制着色器：

#version 420 core    

layout(vertices=3) out; 

in  vec4 v_color[];
out vec4 tc_color[];

void main()
{
    tc_color[gl_InvocationID] = v_color[gl_InvocationID];

    // .....
}

镶嵌评估着色器：

#version 420 core 

layout(triangles) in;

in  vec4 tc_color[];
out vec4 te_color;

void main()
{
    te_color = tc_color[0] * gl_TessCoord.x +
               tc_color[1] * gl_TessCoord.y +
               tc_color[2] * gl_TessCoord.z;

    // .....
}

片段着色器：

#version 420 core                                                  

in  vec4 te_color;  
out vec4 color;                                                    

void main(void)                                                    
{                                                                  
    color = te_color;                                               
}