2

我正在尝试以下在 SMT-LIB 中对扩展自然进行编码的方法（我定义了一个类似于 的数据类型Maybe Integer）：

; extended integers -- if first field is true, then the value is infinity
(declare-datatypes () ((IntX (mk-int-x (is-infty Bool) (not-infty Int)))))

; addition
(define-fun plus ((x IntX) (y IntX)) IntX
  (ite (or (is-infty x) (is-infty y))
           (mk-int-x true 0)
           (mk-int-x false (+ (not-infty x) (not-infty y)))))

(declare-fun x () IntX)
(assert (= x (plus x (mk-int-x false 1))))
; x = x+1 when x |-> infty
(get-model)
(exit)

我将如何在 SBV 中对此进行编码？我尝试了以下方法，但这只是使 SBV 崩溃。我也不知何故怀疑这会做我想要的，但我对 SBV 的工作原理还不够熟悉。

!/usr/bin/env stack
{- stack script
  --resolver nightly-2018-11-23
  --package sbv
  --package syb
-}

{-# LANGUAGE DeriveAnyClass #-}
{-# LANGUAGE DeriveDataTypeable #-}
{-# LANGUAGE LambdaCase #-}
{-# LANGUAGE ScopedTypeVariables #-}

import Data.Generics
import Data.SBV

data IntX = IntX (Maybe Integer) deriving (Eq, Ord, Data, Read, Show, SymWord, HasKind)

pretty :: IntX -> String
pretty = \case
  IntX Nothing -> "∞"
  IntX n -> show n

instance Num IntX where
  (+) (IntX x) (IntX y) = IntX $ (+) <$> x <*> y
  (*) (IntX x) (IntX y) = IntX $ (*) <$> x <*> y
  fromInteger = IntX . Just

ex1 = sat $ do
  x :: SBV IntX <- free "x"
  return $ x .== x + 1

main :: IO ()
main = print =<< ex1

~/temp ✘ ./sbv.hs
sbv.hs: SBV.SMT.SMTLib2.cvtExp.sh: impossible happened; can't translate: s0 + s1
CallStack (from HasCallStack):

  error, called at ./Data/SBV/SMT/SMTLib2.hs:681:13 in sbv-7.12-9AiNAYtrUhB8YA6mr6BTn4:Data.SBV.SMT.SMTLib2
4

1 回答 1

4

这里的基本问题是您的代码混合了 Haskell 的具体Maybe类型并试图将其视为符号对象。但是您在 SMT-Lib2 中的实现方式是正确的：您基本上需要在 SBV 中编写相应的代码。

我会开始：

{-# LANGUAGE DeriveAnyClass  #-}
{-# LANGUAGE DeriveGeneric   #-}
{-# LANGUAGE NamedFieldPuns  #-}

import Data.SBV
import Data.SBV.Control
import GHC.Generics (Generic)

这只是样板；除非您想使用查询模式，否则您不需要Data.SBV.Control导入，但正如我们将看到的那样，它确实派上用场。

首先要做的是对你的IntX类型进行符号编码；就像您在 SMTLib 中所做的那样：

data SIntX = SIntX { isInf :: SBool
                   , xVal  :: SInteger
                   }
                   deriving (Generic, Mergeable)

instance Show SIntX where
  show (SIntX inf val) = case (unliteral inf, unliteral val) of
                           (Just True,  _)      -> "oo"
                           (Just False, Just n) -> show n
                           _                    -> "<symbolic>"

上面没有什么令人惊讶的，除了Generic和的推导Mergeable。它只是使 SBV 能够ite在您的扩展自然色上​​使用。还要注意Show实例在使用 . 区分具体值和符号值时是如何小心的unliteral。

接下来，我们添加一些便利功能，这也不足为奇：

inf :: SIntX
inf = SIntX { isInf = true, xVal = 0 }

nat :: SInteger -> SIntX
nat v = SIntX { isInf = false, xVal = v }

liftU :: (SInteger -> SInteger) -> SIntX -> SIntX
liftU op a = ite (isInf a) inf (nat (op (xVal a)))

liftB :: (SInteger -> SInteger -> SInteger) -> SIntX -> SIntX -> SIntX
liftB op a b = ite (isInf a ||| isInf b) inf (nat (xVal a `op` xVal b))

现在我们可以做IntX一个数字：

instance Num SIntX where
  (+)         = liftB (+)
  (*)         = liftB (*)
  negate      = liftU negate
  abs         = liftU abs
  signum      = liftU signum
  fromInteger = nat . literal

（请注意，这意味着 的语义，这oo - oo = oo充其量是有问题的。但这不是重点。您可能必须根据需要明确定义-和处理它。类似的评论适用于signum。）

由于您想测试相等性，我们还必须定义它的符号版本：

instance EqSymbolic SIntX where
  a .== b = ite (isInf a &&& isInf b) true
          $ ite (isInf a ||| isInf b) false
          $ xVal a .== xVal b

同样，如果要比较，则必须定义一个OrdSymbolic实例；但想法保持不变。

我们需要一种方法来创建象征性的扩展自然。以下函数很好地完成了它：

freeSIntX :: String -> Symbolic SIntX
freeSIntX nm = do i <- sBool    $ nm ++ "_isInf"
                  v <- sInteger $ nm ++ "_xVal"
                  return $ SIntX { isInf = i, xVal = v }

严格来说，您不需要命名变量。（即，nm不需要该参数。）但我发现出于显而易见的原因始终命名我的变量很有帮助。

现在，我们可以编写您的示例：

ex1 :: IO SatResult
ex1 = sat $ do x <- freeSIntX "x"
               return $ x .== x+1

当我运行它时，我得到：

*Main> ex1
Satisfiable. Model:
  x_isInf = True :: Bool
  x_xVal  =    0 :: Integer

我相信这就是你要找的东西。

当您处理较大的程序时，能够IntX更直接地提取值并进一步使用它们进行编程是有益的。这时候查询模式就派上用场了。首先，一个助手：

data IntX = IntX (Maybe Integer) deriving Show

queryX :: SIntX -> Query IntX
queryX (SIntX {isInf, xVal}) = do
          b <- getValue isInf
          v <- getValue xVal
          return $ IntX $ if b then Nothing
                               else Just v

现在我们可以编码：

ex2 :: IO ()
ex2 = runSMT $ do x <- freeSIntX "x"
                  constrain $ x .== x+1

                  query $ do cs <- checkSat
                             case cs of
                               Unk   -> error "Solver said Unknown!"
                               Unsat -> error "Solver said Unsatisfiable!"
                               Sat   -> do v <- queryX x
                                           io $ print v

我们得到：

*Main> ex2
IntX Nothing

我希望这有帮助。我已将所有这些代码放在一个要点中：https ://gist.github.com/LeventErkok/facfd067b813028390c89803b3a0e887

于 2018-11-23T16:01:52.710 回答