86

我找到的关于 Perl 构建过程、单元测试和代码覆盖率的大多数 Stackoverflow 答案只是将我指向 CPAN 以获取那里的文档。指向 CPAN 模块绝对没有错,因为这是完整文档所在的位置。不过,在许多情况下,我很难找到完整的工作代码示例。

我一直在互联网上搜索可以下载或粘贴到我的 IDE 中的实际工作代码示例,例如您的典型教程“Hello World”示例源代码,但是一个示例通过单元测试和代码演示构建过程覆盖分析。有没有人有一个完整的工作项目的小例子来展示这些技术和流程?

(我确实有一个小的工作示例,我会用它来回答我自己的问题,但可能还有其他 SO 用户的示例比我想出的示例更好。)

4

5 回答 5

108

我花了一段时间,也花了我从许多不同的来源获取小片段并将它们融合在一起,但我认为我有一个小的工作示例,足以向 Perl 新手演示 Perl 构建过程,包括单元测试和代码覆盖分析和报告。(我在 Windows XP Pro PC 上使用ActiveState ActivePerl v5.10.0,Module::BuildTest::MoreDevel::Cover

从 Perl 项目的目录开始,然后在项目目录下创建一个“lib”目录和一个“t”目录:

HelloPerlBuildWorld
        |
        |----------> lib
        |
        |----------> t

在“lib”目录中,创建一个名为“HelloPerlBuildWorld.pm”的文本文件。该文件是您将要构建和测试的 Perl 模块。将以下内容粘贴到此文件中:

use strict;
use warnings;
package HelloPerlBuildWorld;

$HelloPerlBuildWorld::VERSION = '0.1';

sub hello {
   return "Hello, Perl Build World!";
}

sub bye {
   return "Goodbye, cruel world!";
}

sub repeat {
   return 1;
}

sub argumentTest {
    my ($booleanArg) = @_;

    if (!defined($booleanArg)) {
        return "null";
    }
    elsif ($booleanArg eq "false") {
        return "false";
    }
    elsif ($booleanArg eq "true") {
        return "true";
    }
    else {
        return "unknown";
    }

   return "Unreachable code: cannot be covered";
}

1;

在“t”目录中,创建一个名为“HelloPerlBuildWorld.t”的文本文件。该文件是您的单元测试脚本,它将尝试全面测试您上面的 Perl 模块。将以下内容粘贴到此文件中:

use strict;
use warnings;
use Test::More qw(no_plan);

# Verify module can be included via "use" pragma
BEGIN { use_ok('HelloPerlBuildWorld') };

# Verify module can be included via "require" pragma
require_ok( 'HelloPerlBuildWorld' );

# Test hello() routine using a regular expression
my $helloCall = HelloPerlBuildWorld::hello();
like($helloCall, qr/Hello, .*World/, "hello() RE test");

# Test hello_message() routine using a got/expected routine
is($helloCall, "Hello, Perl Build World!", "hello() IS test");

# Do not test bye() routine

# Test repeat() routine using a got/expected routine
for (my $ctr=1; $ctr<=10; $ctr++) {
    my $repeatCall = HelloPerlBuildWorld::repeat();
    is($repeatCall, 1, "repeat() IS test");
}

# Test argumentTest() 
my $argumentTestCall1 = HelloPerlBuildWorld::argumentTest();
is($argumentTestCall1, "null", "argumentTest() IS null test");

# Test argumentTest("true") 
my $argumentTestCall2 = HelloPerlBuildWorld::argumentTest("true");
is($argumentTestCall2, "true", "argumentTest() IS true test");

# Test argumentTest("false") 
my $argumentTestCall3 = HelloPerlBuildWorld::argumentTest("false");
is($argumentTestCall3, "false", "argumentTest() IS false test");

# Test argumentTest(123) 
my $argumentTestCall4 = HelloPerlBuildWorld::argumentTest(123);
is($argumentTestCall4, "unknown", "argumentTest() IS unknown test");

现在备份到您的顶级项目目录,创建一个名为“Build.PL”的文本文件。该文件将创建您稍后将使用的构建脚本。将以下内容粘贴到此文件中:

use strict;
use warnings;
use Module::Build;

my $builder = Module::Build->new(
    module_name         => 'HelloPerlBuildWorld',
    license             => 'perl',
    dist_abstract       => 'HelloPerlBuildWorld short description',
    dist_author         => 'Author Name <email_addy@goes.here>',
    build_requires => {
        'Test::More' => '0.10',
    },
);

$builder->create_build_script();

这就是您需要的所有文件。现在从顶级项目目录的命令行中,键入以下命令:

perl Build.PL

您将看到类似于以下内容的内容:

Checking prerequisites...
Looks good

Creating new 'Build' script for 'HelloPerlBuildWorld' version '0.1'

现在您应该能够使用以下命令运行单元测试:

Build test

并看到与此类似的内容:

Copying lib\HelloPerlBuildWorld.pm -> blib\lib\HelloPerlBuildWorld.pm
t\HelloPerlBuildWorld....ok
All tests successful.
Files=1, Tests=18,  0 wallclock secs ( 0.00 cusr +  0.00 csys =  0.00 CPU)

要使用代码覆盖率分析运行单元测试,请尝试以下操作:

Build testcover

你会看到一些关于这个顺序的东西:

t\HelloPerlBuildWorld....ok
All tests successful.
Files=1, Tests=18, 12 wallclock secs ( 0.00 cusr +  0.00 csys =  0.00 CPU)
cover
Reading database from D:/Documents and Settings/LeuchKW/workspace/HelloPerlBuildWorld/cover_db


----------------------------------- ------ ------ ------ ------ ------ ------
File                                  stmt   bran   cond    sub   time  total
----------------------------------- ------ ------ ------ ------ ------ ------
D:/Perl/lib/ActivePerl/Config.pm       0.0    0.0    0.0    0.0    n/a    0.0
D:/Perl/lib/ActiveState/Path.pm        0.0    0.0    0.0    0.0    n/a    0.0
D:/Perl/lib/AutoLoader.pm              0.0    0.0    0.0    0.0    n/a    0.0
D:/Perl/lib/B.pm                      18.6   16.7   13.3   19.2   96.4   17.6
 ...
[SNIP]
 ...
D:/Perl/lib/re.pm                      0.0    0.0    0.0    0.0    n/a    0.0
D:/Perl/lib/strict.pm                 84.6   50.0   50.0  100.0    0.0   73.1
D:/Perl/lib/vars.pm                   44.4   36.4    0.0  100.0    0.0   36.2
D:/Perl/lib/warnings.pm               15.3   12.1    0.0   11.1    0.0   12.0
D:/Perl/lib/warnings/register.pm       0.0    0.0    n/a    0.0    n/a    0.0
blib/lib/HelloPerlBuildWorld.pm       87.5  100.0    n/a   83.3    0.0   89.3
Total                                  9.9    4.6    2.8   11.3  100.0    7.6
----------------------------------- ------ ------ ------ ------ ------ ------


Writing HTML output to D:/Documents and Settings/LeuchKW/workspace/HelloPerlBuildWorld/cover_db/coverage.html ...
done.

(有人请告诉我如何配置 Cover 以忽略所有 Perl 库,但只报告我编写的单个文件。根据 CPAN 文档,我无法让 Cover 过滤工作!)

现在,如果您刷新顶级目录,您可以看到一个名为“cover_db”的新子目录。进入该目录并双击“coverage.html”文件以在您喜欢的 Web 浏览器中打开代码覆盖率报告。它为您提供了一个漂亮的彩色编码超文本报告,您可以单击文件名并在实际源代码旁边的报告中查看 Perl 模块的详细语句、分支、条件、子程序覆盖率统计信息。您可以在此报告中看到,我们根本没有涵盖“bye()”例程,而且还有一行无法访问的代码没有像我们预期的那样被涵盖。

代码覆盖率报告快照
(来源:leucht.com

您可以做的另一件事是帮助您在 IDE 中自动执行此过程,即创建更多“Build.PL”类型的文件,这些文件显式执行我们在上面从命令行手动执行的一些构建目标。例如,我使用具有以下内容的“BuildTest.PL”文件:

use strict;
use warnings;
use Module::Build;

my $build = Module::Build->resume (
  properties => {
    config_dir => '_build',
  },
);

$build->dispatch('build');
$build->dispatch('test');

然后我设置我的 IDE 以通过单击鼠标执行此文件(通过“perl BuiltTest.PL”),它会自动从 IDE 运行我的单元测试代码,而不是我从命令行手动执行。将“dispatch('test')”替换为“dispatch('testcover')”以自动执行代码覆盖率。键入“构建帮助”以获取可从 Module::Build 获得的构建目标的完整列表。

于 2009-02-10T18:38:10.620 回答
14

作为对 Kurt 的回应,我建议用这个替代他的 BuiltTest.PL 脚本。

use strict;
use warnings;
use Module::Build;

my $build = Module::Build->resume (
  properties => {
    config_dir => '_build',
  },
);

$build->dispatch('build');
$build->dispatch('test');

它重用由 Build.PL 构建的数据库(因此假设已经运行)。

于 2009-02-10T18:54:48.847 回答
12

我在Intermediate PerlMastering Perl中对此进行了介绍。然而,Kurt 给出了一个很好的总结。

不过,我使用Module::Release将所有这些组合到一个发布脚本中。我输入一个命令,一切都会发生。

于 2009-02-11T07:58:40.587 回答
12

非常有用module-starter的生成了一个易于使用的骨架项目,它处理模块安装、文档创建和模块文件的良好布局,以及——我认为——代码覆盖支持。对于任何与 Perl 模块相关的工作来说,这都是 IMO 一个很好的开始。

另外:使用与 CPAN 相关的工具Module::Build——即使对于可能永远不会公开发布的模块——也是一个非常好的主意

于 2009-02-11T09:38:37.460 回答
7

(披露:我是作者)

一旦您按照上述方式对所有内容进行了排序,您就可以进行下一步并使用Devel::CoverX::Covered来例如

  • 给定一个源文件,列出为该源文件提供覆盖的测试文件。这可以在文件、子例程和行级别上完成。
  • 给定一个测试文件,列出该测试文件涵盖的源文件和子文件。
  • 给定一个源文件,有效地报告每行或子的覆盖率细节。

有关具体的命令行示例,请参见概要

Devel::PerlySense中,Emacs 支持在源代码缓冲区(屏幕截图)中显示覆盖信息,以及导航到/从覆盖测试文件。

于 2009-08-16T00:24:06.913 回答