3

为了加快速度，我在这里忘记做什么了吗？我正在尝试实现名为 Tuning Timbre Spectrum Scale 的书中描述的算法。另外——如果一切都失败了，有没有办法让我用 C 语言编写这部分代码，然后可以从 python 调用它？

import numpy as np
cimport numpy as np

# DTYPE = np.float
ctypedef np.float_t DTYPE_t

np.seterr(divide='raise', over='raise', under='ignore', invalid='raise')

"""
I define a timbre as the following 2d numpy array:
[[f0, a0], [f1, a1], [f2, a2]...] where f describes the frequency
of the given partial and a is its amplitude from 0 to 1. Phase is ignored.
"""

#Test Timbre
# cdef np.ndarray[DTYPE_t,ndim=2] t1 = np.array( [[440,1],[880,.5],[(440*3),.333]])

# Calculates the inherent dissonance of one timbres of the above form
# using the diss2Partials function
cdef DTYPE_t diss1Timbre(np.ndarray[DTYPE_t,ndim=2] t):
    cdef DTYPE_t runningDiss1
    runningDiss1 = 0.0
    cdef unsigned int len = np.shape(t)[0]
    cdef unsigned int i
    cdef unsigned int j
    for i from 0 <= i < len:
        for j from i+1 <= j < len:
            runningDiss1 += diss2Partials(t[i], t[j])
    return runningDiss1

# Calculates the dissonance between two timbres of the above form 
cdef DTYPE_t diss2Timbres(np.ndarray[DTYPE_t,ndim=2] t1, np.ndarray[DTYPE_t,ndim=2] t2):
    cdef DTYPE_t runningDiss2
    runningDiss2 = 0.0
    cdef unsigned int len1 = np.shape(t1)[0]
    cdef unsigned int len2 = np.shape(t2)[0]
    runningDiss2 += diss1Timbre(t1)
    runningDiss2 += diss1Timbre(t2)
    cdef unsigned int i1
    cdef unsigned int i2
    for i1 from 0 <= i1 < len1:
        for i2 from 0 <= i2 < len2:
            runningDiss2 += diss2Partials(t1[i1], t2[i2])
    return runningDiss2

cdef inline DTYPE_t float_min(DTYPE_t a, DTYPE_t b): return a if a <= b else b

# Calculates the dissonance of two partials of the form [f,a]
cdef DTYPE_t diss2Partials(np.ndarray[DTYPE_t,ndim=1] p1, np.ndarray[DTYPE_t,ndim=1] p2):
    cdef DTYPE_t f1 = p1[0]
    cdef DTYPE_t f2 = p2[0]
    cdef DTYPE_t a1 = abs(p1[1])
    cdef DTYPE_t a2 = abs(p2[1])

    # In order to insure that f2 > f1:
    if (f2 < f1):
        (f1,f2,a1,a2) = (f2,f1,a2,a1)

    # Constants of the dissonance curves
    cdef DTYPE_t _xStar
    _xStar = 0.24
    cdef DTYPE_t _s1
    _s1 = 0.021
    cdef DTYPE_t _s2
    _s2 = 19
    cdef DTYPE_t _b1
    _b1 = 3.5
    cdef DTYPE_t _b2
    _b2 = 5.75

    cdef DTYPE_t a = float_min(a1,a2)
    cdef DTYPE_t s = _xStar/(_s1*f1 + _s2)
    return (a * (np.exp(-_b1*s*(f2-f1)) - np.exp(-_b2*s*(f2-f1)) ) )

cpdef dissTimbreScale(np.ndarray[DTYPE_t,ndim=2] t,np.ndarray[DTYPE_t,ndim=1] s):
    cdef DTYPE_t currDiss
    currDiss = 0.0;
    cdef unsigned int i
    for i from 0 <= i < s.size:
        currDiss += diss2Timbres(t, transpose(t,s[i]))
    return currDiss

cdef np.ndarray[DTYPE_t,ndim=2] transpose(np.ndarray[DTYPE_t,ndim=2] t, DTYPE_t ratio):
    return np.dot(t, np.array([[ratio,0],[0,1]]))

代码链接：Cython 代码

4

3 回答 3

9

以下是我注意到的一些事情：

  1. 在其他地方使用t1.shape[0]代替等。np.shape(t1)[0]
  2. 不要len用作变量，因为它是 Python 中的内置函数（不是为了速度，而是为了良好的实践）。使用 L 或类似的东西。
  3. 除非确实需要，否则不要将二元素数组传递给函数。每次传递数组时，Cython 都会检查缓冲区。因此，当使用diss2Partials(t[i], t[j])dodiss2Partials(t[i,0], t[i,1], t[j,0], t[j,1])并diss2Partials适当地重新定义时。
  4. 不要使用abs，或者至少不要使用 Python 。它必须将您的 C double 转换为 Python float，调用 abs 函数，然后再转换回 C double。像使用float_min.
  5. 调用np.exp与 using 做类似的事情abs。在顶部更改并添加np.exp到您的导入。expfrom libc.math cimport exp
  6. 彻底摆脱这个transpose功能。这np.dot确实减慢了速度，但无论如何这里确实不需要矩阵乘法。重写你的dissTimbreScale函数来创建一个空矩阵，比如说t2。在当前循环之前，将第二列设置t2为等于第二列t（最好使用循环，但您可能会在此处使用 Numpy 操作）。然后，在当前循环内部，放入一个循环，将第一列设置为t2等于第一列ttimes s[i]。这就是你的矩阵乘法真正在做的事情。然后只是t2作为第二个参数传递给diss2Timbres而不是函数返回的那个transpose。

先做1-5，因为它们很容易。6 号可能需要更多的时间、精力和实验，但我怀疑它也可以显着提高速度。

于 2011-03-24T18:38:41.597 回答
0

在您的代码中：

for i from 0 <= i < len:
    for j from i+1 <= j < len:
        runningDiss1 += diss2Partials(t[i], t[j])
return runningDiss1

为每个数组查找执行边界检查，@cython.boundscheck(False)在函数之前使用装饰器，然后在使用 i 和 j 作为索引之前转换为无符号 int 类型。查找Numpy 教程的 cython 以获取更多信息。

于 2011-03-17T12:50:16.960 回答
0

我会分析您的代码，以查看哪个函数花费的时间最多。如果是，diss2Timbres您可能会从“numexpr”包中受益。

我比较了我的一个函数的 Python/Cython 和 Numexpr（链接到 SO）。根据数组的大小，numexpr 的性能优于 Cython 和 Fortran。

注意：刚刚发现这篇文章真的很旧......

于 2015-02-13T12:56:31.450 回答