2

假设我有这个简单的组件

type evt =
  | NoOp;

type t('a) = 'a;

let component = ReasonReact.reducerComponent("TestComponent");

let make = _children => {
  ...component,
  initialState: () => "hello",
  reducer: (evt, state: t('a)) =>
    switch (evt) {
    | NoOp => ReasonReact.NoUpdate
    },
  render: self => <div> {str("hello")} </div>,
};

（在这里试试）

为什么我越来越

The type of this module contains type variables that cannot be generalized

? （类型变量在这里没用，但想象一下它在 initialState 中是需要的。试图使示例尽可能简单。）

4

1 回答 1

3

技术原因是 ReasonReact 组件是记录类型，看起来像这样：

type fauxComponent = {
  reducer: (evt, t('a)) => t('a),
  render: t('a) => ReasonReact.reactElement
};

如果您尝试编译它，您将收到有关“未绑定类型参数”的错误。错误的不同是因为它被推断为ReasonReact.component具有一堆类型变量的类型，其中一个被推断为具有多态类型。问题本质上是相同的，但在没有所有间接性的情况下更容易说明。

我认为你不能这样做的技术原因被称为价值限制。但也有实际原因。'a如果您明确指定为多态，您实际上可以编译此类型：

type fauxComponent = {
  reducer: 'a. (evt, t('a)) => t('a),
  render: 'a. t('a) => ReasonReact.reactElement
};

这说这'a可以是任何东西，但这也是问题所在。因为它可以是任何东西，所以你无法知道它是什么，因此除了让它通过并返回之外，你真的无法对它做任何事情。您也不知道 and'a中的情况相同，这通常不是记录的问题，因为它们不是有状态的对象。问题的出现是因为 ReasonReact 像他们一样“滥用”它们。reducerrender

那么你将如何完成你想要做的事情呢？简单，使用函子！;) 在 Reason 中，您可以参数化模块，然后将其称为函子，并使用它来指定要在整个模块中使用的类型。这是您的示例功能化：

module type Config = {
  type t;
  let initialState : t;
};

module FunctorComponent(T : Config) {
  type evt =
  | NoOp;

  type t = T.t;

  let component = ReasonReact.reducerComponent("TestComponent");

  let make = _children => {
    ...component,
    initialState: () => T.initialState,
    reducer: (evt, state: t) =>
      switch (evt) {
      | NoOp => ReasonReact.NoUpdate
      },
    render: self => <div> {ReasonReact.string("hello")} </div>,
  };
};

module MyComponent = FunctorComponent({
  type t = string;
  let initialState = "hello";
});

ReactDOMRe.renderToElementWithId(<MyComponent />, "preview");

函子所接受的参数实际上需要是模块，所以我们首先定义一个模块类型Config，将其指定为参数类型，然后当我们MyComponent使用函子创建模块时，我们创建并传递一个实现Config模块类型的匿名模块。

现在你知道为什么很多人认为 OCaml 和 Reason 的模块系统如此棒了 :) （实际上还有很多，但这是一个好的开始）

于 2018-11-09T10:50:21.647 回答