sparql - 在联合查询中使用 Wikidata 标签服务

Question

我想知道是否可以在联合查询中使用 Wikidata 标签服务。例如，以下查询

# Query from a local SPARQL enpoint

select ?item ?itemLabel
where {
    SERVICE <https://query.wikidata.org/sparql> {
        ?item wdt:P31 wd:Q146.
        SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
    }

}

返回空?itemLabels。我怎样才能在我的结果集中获得?itemLabels ？

Answer 1

您也可以使用手动模式，在您的情况下它只是多行：

PREFIX       wdt:  <http://www.wikidata.org/prop/direct/>
PREFIX        wd:  <http://www.wikidata.org/entity/>
PREFIX        bd:  <http://www.bigdata.com/rdf#>
PREFIX  wikibase:  <http://wikiba.se/ontology#>
PREFIX      rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT * {
  SERVICE <https://query.wikidata.org/sparql> {
    ?item wdt:P31 wd:Q146
    SERVICE wikibase:label { bd:serviceParam wikibase:language "it". ?item rdfs:label ?label }
  }
}

试用 FactForge

Answer 2

包括一些名义上可选的东西...这是我刚刚通过URIBurner.com运行的完整查询及其结果。

PREFIX       wdt:  <http://www.wikidata.org/prop/direct/>
PREFIX        wd:  <http://www.wikidata.org/entity/>
PREFIX        bd:  <http://www.bigdata.com/rdf#>
PREFIX  wikibase:  <http://wikiba.se/ontology#>

SELECT *
WHERE
  {
    SERVICE <https://query.wikidata.org/sparql>
      {
        SELECT ?item ?itemLabel 
        WHERE 
          {
            ?item wdt:P31 wd:Q146 .
            SERVICE wikibase:label
              { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
          }
      }
  }