0

我想用 0 音译 1 - 8 的数字，但在编译时不知道数字。由于音译不插入变量我这样做：

@trs = (sub{die},sub{${$_[0]} =~ tr/[0,1]/[1,0]/},sub{${$_[0]} =~ tr/[0,2]/[2,0]/},sub{${$_[0]} =~ tr/[0,3]/[3,0]/},sub{${$_[0]} =~ tr/[0,4]/[4,0]/},sub{${$_[0]} =~ tr/[0,5]/[5,0]/},sub{${$_[0]} =~ tr/[0,6]/[6,0]/},sub{${$_[0]} =~ tr/[0,7]/[7,0]/},sub{${$_[0]} =~ tr/[0,8]/[8,0]/});

然后像这样索引它：

$trs[$character_to_transliterate](\$var_to_change);

如果有人能指出我最好的解决方案，我将不胜感激。

4

3 回答 3

2

任何时候你在重复自己，你应该看看你正在做的事情是否可以循环完成。由于tr在编译时创建它的表，您可以使用eval它在运行时访问编译器：

my @trs = (sub {die}, map {eval "sub {\$_[0] =~ tr/${_}0/0$_/}"} 1 .. 8);

my $x = 123;

$trs[2]($x);

print "$x\n"; # 103

这里也不需要使用引用，子程序参数已经通过引用传递。

如果不想使用字符串 eval，则需要使用支持运行时修改的构造。为此，您可以使用s///运算符：

sub subst {$_[0] =~ s/($_[1]|0)/$1 ? 0 : $_[1]/ge}

my $z = 1230;

subst $z => 2;

print "$z\n"; # 1032

该tr///构造比s///后者支持正则表达式更快。

于 2011-03-10T16:07:21.543 回答
1

我建议简单地放弃tr一些实际上允许一点元编程的东西，比如s///. 例如：

# Replace $to_swap with 0 and 0 with $to_swap, and leave
# everything else alone.
sub swap_with_0 {
    my ($digit, $to_swap) = @_;
    if ($digit == $to_swap) {
        return 0;
    } elsif ($digit == 0) {
        return $to_swap;
    } else {
        return $digit;
    }
}

# Swap 0 and $to_swap throughout $string
sub swap_digits {
    my ($string, $to_swap) = @_;
    $string =~ s/([0$to_swap])/swap_with_0($1, $to_swap)/eg;
    return $string;
}

这非常简单。:)

于 2011-03-10T17:24:53.113 回答
0

这是一个使用替换而不是音译的简短子例程：

sub swap_digits {
    my ($str, $digit) = @_;
    $str =~ s{ (0) | $digit }{ defined $1 ? $digit : 0 }gex;
    return $str;
}
于 2011-03-10T17:19:01.230 回答