0

I'm trying to select the main menu ID of this page http://greyhoundstats.co.uk/index.php labeled ("menu_wholesome") in order to get their hyperlinks later on. In the HTML document, there are two tags with this ID, a <div> and its child element <ul>, but when i search for them with the code below, i get the object variable not set" error.

Option Explicit

Public Const MenuPage As String = "http://greyhoundstats.co.uk/index.php"

Sub BrowseMenus()

Dim XMLHTTPReq As New MSXML2.XMLHTTP60
Dim HTMLDoc As New MSHTML.HTMLDocument

Dim MainMenuList As MSHTML.IHTMLElement
Dim aElement As MSHTML.IHTMLElementCollection
Dim ulElement As MSHTML.IHTMLUListElement
Dim liElement As MSHTML.IHTMLLIElement

XMLHTTPReq.Open "GET", MenuPage, False
XMLHTTPReq.send

HTMLDoc.body.innerText = XMLHTTPReq.responseText

    Set MainMenuList = HTMLDoc.getElementById("menu_wholesome")(0) '<-- error happens here

End Sub

Anyone knows why getElementsById can't find the refered ID, although it is part of the HTML document set? I know that this method is supposed to return a unique ID, but when we have the same one refered by other tags i also know that i will return the first ID found which should be the <div id="menu_wholesome"> part of the HTML page being requested.

4

2 回答 2

1

目前尚不清楚您要达到什么目的。我刚刚解决了您目前遇到的问题。.getElementById()处理单个元素，因此当您将其视为元素的集合时，它将引发该错误。如果您注意到这部分getElementBy和getElementsBy，您可以看到哪个是元素集合的变化（不要忽略s）。(0)当您使用getElementsBy时，您只能使用或类似的东西。

您应该以正确的方式缩进您的代码，以便其他人可以毫无困难地阅读它：

Sub BrowseMenus()
    Const MenuPage$ = "http://greyhoundstats.co.uk/index.php"
    Dim HTTPReq As New XMLHTTP60, HTMLDoc As New HTMLDocument
    Dim MainMenuList As Object

    With HTTPReq
        .Open "GET", MenuPage, False
        .send
        HTMLDoc.body.innerHTML = .responseText
    End With

    Set MainMenuList = HTMLDoc.getElementById("menu_wholesome")
End Sub
于 2018-09-28T05:43:04.940 回答
1

首先：您想要像遍历 DOM 文档一样工作并设置 innerHTML。

第二：这条线

Set MainMenuList = HTMLDoc.getElementById("menu_wholesome")(0)

这是不正确的。getElementById返回您无法索引的单个元素。你索引到一个集合中。

请注意： div 和 ul 都指向相同的内容。

如果要单独选择它们，请使用querySelector

HTMLDoc.querySelector("div#menu_wholesome")
HTMLDoc.querySelector("ul#menu_wholesome")

上面的目标首先是标签名称，然后是 id 属性。

如果您想要一个 id 集合，则使用querySelectorAll它返回匹配项的 nodeList。ID 应该是页面唯一的，但有时它们不是！

HTMLDoc.querySelectorAll("#menu_wholesome")

然后您可以索引到 nodeList 例如 

HTMLDoc.querySelectorAll("#menu_wholesome").item(0)

VBA：

Option Explicit

Public Const MenuPage As String = "http://greyhoundstats.co.uk/index.php"
Sub BrowseMenus()
    Dim sResponse As String, HTMLDoc As New MSHTML.HTMLDocument
    Dim MainMenuList As Object, div As Object, ul As Object

    With CreateObject("MSXML2.XMLHTTP")
        .Open "GET", MenuPage, False
        .setRequestHeader "If-Modified-Since", "Sat, 1 Jan 2000 00:00:00 GMT"
        .send
        sResponse = StrConv(.responseBody, vbUnicode)
    End With

    sResponse = Mid$(sResponse, InStr(1, sResponse, "<!DOCTYPE "))
    HTMLDoc.body.innerHTML = sResponse

    Set MainMenuList = HTMLDoc.querySelectorAll("#menu_wholesome")

    Debug.Print MainMenuList.Length

    Set div = HTMLDoc.querySelector("div#menu_wholesome")
    Set ul = HTMLDoc.querySelector("ul#menu_wholesome")

    Debug.Print div.outerHTML
    Debug.Print ul.outerHTML

End Sub
于 2018-09-28T05:49:08.013 回答