2

我试图在不“破坏”列表的情况下找到最后一项（所有数字）。

我目前拥有的是这样的：

max([_|Xs]-Xs,R):-
Xs \= [],
max2(Xs,R),!.
max([X|Xs]-Xs,R):-
    R = X.
max([]-[],99999).

Max2 是一个在普通列表中查找最后一项的函数：

max2([X],X):-
    number(X),!.
max2([_|Xs],R):-
    max2(Xs,R),!.

当我尝试使用一个项目的列表时，它可以工作 - 否则会失败：

max([22|X]-X,R)
R = 22

max([22,27|X]-X,R)
Stack limit (0.2Gb) exceeded
  Stack sizes: local: 0.2Gb, global: 21Kb, trail: 3Kb
  Stack depth: 1,560,328, last-call: 0%, Choice points: 1,560,312
  Probable infinite recursion (cycle):
    [1,560,328] max2([cyclic list], _1452)
    [1,560,327] max2([cyclic list], _1484)

我尝试了其他方法，但是当我给它一个包含一个项目的列表时，它转换了它：

max([22|X]-X,R)
X = []
R = 22

所以我不能继续使用 X 作为自由变量。

我希望我写得很清楚。提前谢谢了。

4

1 回答 1

3

在 Logtalk 库中，我使用以下定义：

last(List-Back, Last) :-
    List \== Back,
    List = [Head| Tail],
    last(Tail-Back, Head, Last).

last(List, Last, Last) :-
    unify_with_occurs_check(List, Back-Back).
last(List-Back, _, Last) :-
    List \== Back,
    List = [Head| Tail],
    last(Tail-Back, Head, Last).

示例调用：

?- last([22|X]-X,R).
R = 22 ;
false.

?- last([a,b,c|X]-X,R).
R = c ;
false.

?- last(DL, Last).
DL = [Last|_1648]-_1648 ;
DL = [_1652, Last|_1648]-_1648 ;
DL = [_1652, _1664, Last|_1648]-_1648 ;
DL = [_1652, _1664, _1676, Last|_1648]-_1648 ;
DL = [_1652, _1664, _1676, _1688, Last|_1648]-_1648
...

这个定义非常笼统，因为它也适用于变量列表。例如：

?- last([X,Y,Z|Tail]-Tail, Last).
Z = Last ;
false.

在您的情况下，如果您可以确保差异列表始终格式正确并且它们的元素是基础的，您可以简化定义。

于 2018-09-15T19:41:05.463 回答