0

背景：

我正在编写一个 Flash 游戏，但遇到了问题。我一直在使用 Polygonal 的 AS3 数据结构 ( http://code.google.com/p/polygonal/wiki/DataStructures ) 没有任何问题。

我最近在游戏中添加了 SmartFoxServer 2X 支持 ( http://www.smartfoxserver.com/ )。导入 SmartFox SWC 文件后，我会在“new LinkedQueue()”调用上收到运行时错误，指示不兼容的覆盖。

无论如何，我向 Polygonal 提交了一个错误，结果证明 SmartFox 正在使用他的数据结构的旧版本，并将其包含在他们的 SWC 文件中。

我的问题：

考虑到我只有两个 SWC 文件，有什么方法可以强制它们进入不同的命名空间吗？这将允许我与 smartfox 的旧版本一起使用新版本。

4

1 回答 1

1

是的，如果真的很重要，而且你想花时间，可以通过改变里面的swf和目录来修改swc中的包。

这是一个使用SWFWire Decompiler的示例 AIR 项目：

public class SWFWireCompiler extends Sprite
{
    public function SWCEditor()
    {
        stage.nativeWindow.activate();

        var bytes:ByteArray = getBytes('library.swf');

        var swfReader:SWFReader = new SWF10Reader();
        var readResult:SWFReadResult = swfReader.read(new SWFByteArray(bytes));
        readResult.swf.header.signature = SWFHeader.UNCOMPRESSED_SIGNATURE;

        for each(var tag:SWFTag in readResult.swf.tags)
        {
            var abcTag:DoABCTag = tag as DoABCTag;
            if(abcTag)
            {
                for each(var string:StringToken in abcTag.abcFile.cpool.strings)
                {
                    if(string.utf8 == 'de.polygonal.ds')
                    {
                        string.utf8 = 'de.polygonal.ds.old';
                    }
                }
            }
        }

        var swfWriter:SWFWriter = new SWF10Writer();
        var writeResult:SWFWriteResult = swfWriter.write(readResult.swf);

        writeBytes('C:\\output.swf', writeResult.bytes);
    }

    private function getBytes(file:String):ByteArray
    {
        var bytes:ByteArray = new ByteArray();
        var stream:FileStream = new FileStream();
        stream.open(File.applicationDirectory.resolvePath(file), FileMode.READ);
        stream.readBytes(bytes);
        stream.close();
        return bytes;
    }

    private function writeBytes(filename:String, bytes:ByteArray):void
    {
        var file:File = new File(filename);
        var fs:FileStream = new FileStream();
        fs.open(file, FileMode.WRITE);
        fs.writeBytes(bytes);
        fs.close();
    }
}

然后，您必须在 catalog.xml 中进行查找/替换，然后重新打包它。

于 2011-03-04T06:42:13.290 回答