command-line - 使用批处理文件打开一系列文件中的一个

Question

基于此结构，我最多有 4 个文件（注意前缀是日期）

• 0830文件名.txt
• 0907文件名.txt
• 0914文件名.txt
• 0921文件名.txt

我想打开最近的一个（0921filename.txt）。我怎样才能在批处理文件中做到这一点？

谢谢。

Answer 1

此方法使用实际的文件修改日期，以确定哪个是最新的文件：

@echo off
for /F %%i in ('dir /B /O:-D *.txt') do (
    call :open "%%i"
    exit /B 0
)
:open
    start "dummy" "%~1"
exit /B 0

但是，此方法按字母顺序选择最后一个文件（或第一个，按反向字母顺序），因此如果文件名一致 - 它会起作用：

@echo off
for /F %%i in ('dir /B *.txt^|sort /R') do (
    call :open "%%i"
    exit /B 0
)
:open
    start "dummy" "%~1"
exit /B 0

您实际上必须选择哪种方法更适合您。

Answer 2

抱歉，我向这个问题发送了垃圾邮件，但我真的很想发布The Real Answer。如果您希望您的 BATCH 脚本解析和比较文件名中的日期，那么您可以使用如下内容：

@echo off

rem Enter the ending of the filenames.
rem Basically, you must specify everything that comes after the date.
set fn_end=filename.txt

rem Do not touch anything bellow this line.
set max_month=00
set max_day=00

for /F %%i in ('dir /B *%fn_end%') do call :check "%%i"
call :open %max_month% %max_day%
exit /B 0

:check
    set name=%~1
    set date=%name:~0,4%
    set month=%date:~0,2%
    set day=%date:~2,2%
    if /I %month% GTR %max_month% (
        set max_month=%month%
        set max_day=%day%
    ) else if /I %month% EQU %max_month% (
        set max_month=%month%
        if /I %day% GTR %max_day% (
            set max_day=%day%
        )
    )
exit /B 0

:open
    set date=%~1
    set month=%~2
    set name=%date%%month%%fn_end%
    start "dummy" "%name%"
exit /B 0

Answer 3

一个班轮，使用 EXIT 技巧：

FOR /F %%I IN ('DIR *.TXT /B /O:-D') DO NOTEPAD %%I & EXIT

编辑：

@pam：你说得对，我假设文件按日期顺序排列，但你可以将命令更改为：

FOR /F %%I IN ('DIR *.TXT /B /O:-N') DO NOTEPAD %%I & EXIT

然后你有文件列表按名称以相反的顺序排序。

Answer 4

给你...（希望没有人打败我...）（您需要将文件保存为 lasttext.bat 或其他文件）这将打开/运行最旧的 .txt 文件

dir *.txt /b /od > systext.bak 
FOR /F %%i in (systext.bak) do set sysRunCommand=%%i 
call %sysRunCommand%
del systext.bak /Y

可能只有XP。看看 DOS 的强大功能。
虽然这会按日期获取最新的文件名 - 而不是按文件名..

如果要获取最新的文件名，请将 /od 更改为 /on 。
如果要对其他内容进行排序，请在第二行添加“排序”命令。

Answer 5

使用正则表达式解析出相关整数并进行比较。