4

我正在使用命名格式 report[{field-name}] 为我的 ColdFusion 应用程序构建一个表单，当使用 RoR 或 CFWheels 时，它会在后端为我提供一个名为 report 的结构，其中包含我的所有字段名称。我正在使用 FW/1，所以我的所有表单字段都放入 RC 范围内，而不是保留在 Form 范围内。我知道可以将我的表单字段转换为 ColdFusion 结构，因为正如我所说，CFWheels 可以做到这一点。我只是不知道如何让我的应用程序做到这一点。

这是我正在谈论的表格的一部分

<dl class="oneColumn">
    <dt class="first"><label for="report[name]">Name</label></dt>
    <dd><input type="text" name="report[name]" class="text" /></dd>
    <dt><label for="report[description]">Description</label></dt>
    <dd><textarea name="report[description]" class="textarea"></textarea></dd>
</dl>
4

2 回答 2

4

亚当有正确的上下文，但他的代码片段是错误的。

一个可行的功能是：

<cffunction name="$createNestedParamStruct" returntype="struct" access="public" output="false">
    <cfargument name="params" type="struct" required="true" />
    <cfscript>
        var loc = {};
        for(loc.key in arguments.params)
        {
            if (Find("[", loc.key) && Right(loc.key, 1) == "]")
            {
                // object form field
                loc.name = SpanExcluding(loc.key, "[");

                // we split the key into an array so the developer can have unlimited levels of params passed in
                loc.nested = ListToArray(ReplaceList(loc.key, loc.name & "[,]", ""), "[", true);
                if (!StructKeyExists(arguments.params, loc.name))
                arguments.params[loc.name] = {};

                loc.struct = arguments.params[loc.name]; // we need a reference to the struct so we can nest other structs if needed
                loc.iEnd = ArrayLen(loc.nested);
                for(loc.i = 1; loc.i lte loc.iEnd; loc.i++) // looping over the array allows for infinite nesting
                {
                    loc.item = loc.nested[loc.i];
                    if (!StructKeyExists(loc.struct, loc.item))
                        loc.struct[loc.item] = {};
                    if (loc.i != loc.iEnd)
                        loc.struct = loc.struct[loc.item]; // pass the new reference (structs pass a reference instead of a copy) to the next iteration
                    else
                        loc.struct[loc.item] = arguments.params[loc.key];
                }
                // delete the original key so it doesn't show up in the params
                StructDelete(arguments.params, loc.key, false);
            }
        }
    </cfscript>
    <cfreturn arguments.params />
</cffunction>

我在我的应用程序（CFWheels 之外）中对其进行了测试，它运行良好。您所做的只是传递一个包含应该是结构的结构（在我的情况下是来自 FW/1 的 Rc 结构），但显示为字符串，您将返回一个具有嵌套结构的结构。

例子：

<cfscript>
    Struct['hello[world]'] = 1;
    Struct['hello[earth]'] = 2;
    myhello = $createNestedParamStruct(Struct);
    /* Now myhello equals this:
        myhello.hello.world = 1;
        myhello.hello.eath = 2;
    */
</cfscript>
于 2011-03-02T04:53:45.317 回答
3

所以你需要做的最基本的改变是这样的：

mystruct.name = form["report[name]"];

您需要做的是编写一个循环，循环遍历表单结构并解析表单字段名称并构建这样的结构。我猜它已经写在 CFWheels 中的某个地方（作为一个函数），你可以通过找到它并为自己提取它来避免头痛和沮丧。

我想就是这样，但我不确定：

<!--- helper method to recursively map a structure to build mapping paths and retrieve its values so you can have your way with a deeply nested structure --->
<cffunction name="$mapStruct" returntype="void" access="public" output="false" mixin="dispatch">
    <cfargument name="map" type="struct" required="true" />
    <cfargument name="struct" type="struct" required="true" />
    <cfargument name="path" type="string" required="false" default="" />
    <cfscript>
        var loc = {};
        for(loc.item in arguments.struct)
        {
            if (IsStruct(arguments.struct[loc.item])) // go further down the rabit hole
            {
                $mapStruct(map=arguments.map, struct=arguments.struct[loc.item], path="#arguments.path#[#loc.item#]");
            }
            else // map our position and value
            {
                arguments.map["#arguments.path#[#loc.item#]"] = {};
                arguments.map["#arguments.path#[#loc.item#]"].value = arguments.struct[loc.item];
            }
        }
    </cfscript>
</cffunction>
于 2011-03-01T15:03:14.583 回答