1

目前我正在使用 Yada 作为 web lib。现在我想在路由被命中之前执行一些功能。

我测试过的方法： - 将当前资源包装为子资源，但随后 swagger-doc 找不到资源 - 使用前置拦截器，但此时文档不完整，我遇到错误

我的代码：

(ns all-mighty.namespace
    (:require [yada.yada :refer [handler listener resource as-resource]]
              [yada.swagger :refer [swaggered]])

(defn resources []
[""
 (swaggered
     [""
      [
       (cool-route)
       ]]
     {:info     {:title       "Hello You!"
                 :version     "1.0"
                 :description "It's something"}
      :basePath ""}
     )])

(defn cool-route []
["/cool" (resource {
                   :description "Returns somethign cool"
                   :produces    "application/json"
                   :methods     {:get {:response cool-response}}}
                  )])

(defn cool-response [ctx]
(-> (:response ctx)
    (assoc :status 200)
    (assoc :body {:state :up}))

是的，我稍后会重构资源；-)

有人有想法吗？

4

1 回答 1

1

我使用的方式append-interceptor：

(ns all-mighty.namespace
  (:require
   [yada.handler :refer [append-interceptor]]
   [yada.interceptors :as i]
   [yada.swagger :refer [swaggered]]
   [yada.yada :refer [handler listener resource as-resource]]))

(defn cool-response [ctx]
  {:state :up
   :my/value (get ctx :my/value)})

(defn my-cool-interceptor [ctx]
  (assoc ctx :my/value 10))

(defn my-cool-resource
  [model]
  (-> model
   ;; you have to provide an interception chain, here we use the default one
   (assoc :interceptor-chain yada.yada/default-interceptor-chain)
   resource
   ;; here we append our interceptor after the request body has been processed
   (append-interceptor i/process-request-body my-cool-interceptor)))

(defn cool-route []
  ["/cool" (my-cool-resource {:description "Returns somethign cool"
                              :produces    "application/json"
                              :methods     {:get {:response cool-response}}})])

(defn routes []
  [""
   (swaggered
    [""
     [
      (cool-route)
      ]]
    {:info     {:title       "Hello You!"
                :version     "1.0"
                :description "It's something"}
     :basePath ""}
    )])

(comment
  (def l (listener (routes) {:port 1337}))
  ((:close l))
  )

因此对于下的每个资源，/cool您都可以使用该my-cool-resource功能自动添加所需的拦截器。

于 2018-07-27T14:11:44.347 回答