stata - 在 coefplot 中仅绘制交互项

Question

在Stata回归后，我试图只绘制交互项的系数。

我无法使用community-contributed command做到这一点coefplot。

这是一个可重现的示例和我尝试的解决方案：

sysuse auto, clear
reg price foreign i.turn foreign#i.turn

*this plots all coefficients:
coefplot,

*this drops _cons and foreign but not i.turn
coefplot, drop(i.turn _cons foreign )

*variations with keep also do not work
coefplot, keep(foreign#i.turn )

还有其他方法吗？

我已经在Statalist上交叉发布了这个问题。

Answer 1

您只需要指定交互：

sysuse auto, clear

reg price foreign i.turn foreign#i.turn, coeflegend noheader

local coefinter 1.foreign#33.turn 1.foreign#34.turn 1.foreign#35.turn ///
                1.foreign#36.turn 1.foreign#37.turn

coefplot, keep(`coefinter')

编辑：

您还可以获得所有非零系数，如下所示：

sysuse auto, clear
reg price foreign i.turn i.foreign#i.turn, coeflegend noheader

matrix A = e(b)
local namecol "`: colnames A'"

tokenize `namecol'

forvalues i = 1 / `=colsof(matrix(A))' {
    local mv = A[1,`i']
    if `mv' != 0 & strmatch("``i''" , "*#*") {
        local coefinter `coefinter' ``i''
    }
}

coefplot, keep(`coefinter')

Answer 2

比已经提出的解决方案更简单一点的解决方案是使用通配符（“*”或“？”）。

sysuse auto, clear
reg price foreign i.turn foreign#i.turn
coefplot, keep(*.foreign#*.turn)