9

下面的客户端程序从 WebSocket 服务器接收消息。
它不发送任何消息。

客户

use v6;
use Cro::WebSocket::Client;

constant WS-URL = 'ws://localhost:20000/status';
constant TIMEOUT-TO-CONNECT = 5; # seconds

my $timeout;
my $connection-attempt;

await Promise.anyof(
  $connection-attempt = Cro::WebSocket::Client.connect(WS-URL),
  $timeout = Promise.in(TIMEOUT-TO-CONNECT));

if $timeout.status == Kept
{
  say "* could not connect to server in ', TIMEOUT-TO-CONNECT, ' seconds";
  exit 1;
}

if $connection-attempt.status != Kept
{
  my $cause = $connection-attempt.cause;
  say '"* error when trying to connect to server';
  say '"* --------------------------------------';
  # $cause is a long string, how do we get a simple numeric code ?
  say $cause;
  say '"* ======================================';
  exit 1;
}

my $connection = $connection-attempt.result;
my $peer = 'localhost:20000';
say '* connected with ', $peer;

react
{
  whenever $connection.messages -> $message
  {
    my $body = await $message.body;
    say '* received message=[' ~ $body ~ '] from server';
    LAST { say '* LAST'; done; }
    QUIT { default { say '* QUIT'; done; }}
  }
  CLOSE { say '* CLOSE: leaving react block';}
} # react

服务器

use Cro::HTTP::Router;
use Cro::HTTP::Server;
use Cro::HTTP::Router::WebSocket;

my $application =
route
{
  get -> 'status'
  {
    web-socket -> $incoming
    {
      my $counter = 0;
      my $timer = Supply.interval(1);

      supply
      {
        whenever $incoming -> $thing
        {
          LAST { note '* LAST: client connection was closed'; done; }
          QUIT { default { note '* QUIT: error in client connection'; done;  } }
        }
        whenever $timer
        {
          $counter++;
          say '* sending message ', $counter;
          emit $counter.Str;
        }
        CLOSE { say '* CLOSE: leaving supply block'; }
      } # supply
    } #incoming
  } # get -> status
}

my $server = Cro::HTTP::Server.new: :port(20000), :$application;

$server.start;

say '* serving on port 20000';

react whenever signal(SIGINT)
{
  $server.stop;
  exit;
}

现在，当服务器关闭时（例如，按 Ctrl+C），客户端什么也看不到。

在客户端中设置 CRO_TRACE=1 会给出： 

TRACE(anon 2)] Cro::WebSocket::MessageParser EMIT WebSocket Message - Text

* received message=[4] from server
[TRACE(anon 1)] Cro::TCP::Connector DONE
[TRACE(anon 2)] Cro::WebSocket::FrameParser DONE
[TRACE(anon 2)] Cro::WebSocket::MessageParser DONE
[TRACE(anon 1)] Cro::HTTP::ResponseParser DONE
^C

客户什么也没显示（然后我取消了它）。

所以，问题是：客户应该如何处理这种情况？

更新

编辑了问题，现在显示服务器代码
另外，我在 Fedora 28 中。当我第一次取消服务器时，netstat 显示 

$ netstat -ant | grep 20000
tcp6       0      0 ::1:20000               ::1:56652               TIME_WAIT  
$

Tcpdump 显示 

IP6 ::1.20000 > ::1.56652: Flags [F.], seq 145, ack 194, win 350, options [nop,nop,TS val 1476681452 ecr 1476680552], length 0
IP6 ::1.56652 > ::1.20000: Flags [F.], seq 194, ack 146, win 350, options [nop,nop,TS val 1476681453 ecr 1476681452], length 0
IP6 ::1.20000 > ::1.56652: Flags [.], ack 195, win 350, options [nop,nop,TS val 1476681453 ecr 1476681453], length 0

从客户端到服务器的最后一个 ACK​​ 似乎丢失了，我猜客户端没有关闭连接。

另外，我很好奇为什么 Cro 默认选择使用 IPv6。

4

1 回答 1

4

这是自发布此问题以来已修复的错误，但我留下答案是因为这部分问题可能会使人们在 Raku 中处理网络时感到困惑：

另外，我很好奇为什么 Cro 默认选择使用 IPv6。

localhostlocalhost如果这是您hosts文件中的第一个地址，将首先解析为 IPv6 地址。在撰写本文时，IO::Socket::Async（Cro 在内部使用）仅允许PF_UNSPEC指定为一个系列，并且从主机名解析结果中使用的唯一地址是收到的地址列表中的第一个地址。这将在将来的某个时候更改，作为我的IP6NS 授权工作的一部分，以及改进 DNS 处理方式的问题解决问题，但目前，如果您只想使用 IPv4/IPv6，您应该指定127.0.0.1/::1代替的使用localhost（或您的机器将其解析到的任何地址，如果它们不同）。

于 2020-02-23T08:58:22.853 回答