0

我正在开发带有可寻址 LED 的 Arduino 项目，并且正在使用 FastLED.h 库。

为了简化我的程序，我想创建一个名为 LedsHorloge.h 的库，我将从该库中调用该函数Jauge(int tour, int numberLeds, int brightness, CRGB* ledTable)来点亮我的 LED 灯条。

我是 C++ 的新手。

在 Arduino IDE 中，这是我得到的错误：

D:\Programmation\Arduino\libraries\libraries\JaugeLED/LedsHorloge.h:16:8: note: void LedsJauge::Jauge(int, int, int, CRGB*)

   void Jauge(int tour, int numberLeds, int brightness, CRGB* ledTable);

        ^

D:\Programmation\Arduino\libraries\libraries\JaugeLED/LedsHorloge.h:16:8: note:   no known conversion for argument 4 from 'CRGB (*)[32]' to 'CRGB*'

exit status 1
no matching function for call to 'LedsJauge::Jauge(int&, int, int, CRGB (*)[32])'

当我在 Arduino IDE 中运行此代码时会发生此错误：

#include <LedsHorloge.h>
#include "FastLED.h"

#define LED_PIN     6
#define NUMBER_LEDS    32
#define BRIGHTNESS  100
#define LED_TYPE    WS2812B
#define COLOR_ORDER GRB
#define VITESSE_JAUGE 150 // Delay milliseconds

CRGB leds[NUMBER_LEDS];

#define UPDATES_PER_SECOND 100

int tour = 0 ; // Compte le nombre de tour dans le loop
int pinButton = 8; // Pin qui déclenche la fonction "Jauge"
boolean flag = false ;

LedsJauge jauge(LED_PIN); // This is the object I create 

void setup() {

    delay( 3000 ); // power-up safety delay
    FastLED.addLeds<LED_TYPE, LED_PIN, COLOR_ORDER>(leds, NUMBER_LEDS).setCorrection( TypicalLEDStrip ); // Initialisation de la bande de leds

    Serial.begin(9600);
    FastLED.clear(); // Fonction d'initialisation, encore mal connue

    pinMode(pinButton, INPUT_PULLUP) ;
    InitBandeLeds(); // Eteint toutes les leds si elles sont allumées

    FastLED.show();  // Applique la valeur HSV définie dans la variable "leds"
}

void loop() { 

  // tant que le bouton n'est pas activé, le drapeau reste false
  if ( digitalRead(pinButton) == LOW ){
    flag = true ;
  }


  // lorsque le drapeau devient true on rentre dans la condition
  if (flag){
      if ( tour < NUMBER_LEDS ){  tour += 1;  } // A chaque loop la variable est incrémenté de 1

      jauge.Jauge(tour, NUMBER_LEDS, BRIGHTNESS, &leds); // ERROR COMES FROM THIS LINE
      FastLED.show(); 
      FastLED.delay(1000 / UPDATES_PER_SECOND);
      delay(VITESSE_JAUGE); // régle la vitesse d'allumage des leds
  }

}


// Fonction qui éteint le bandeau de leds
void InitBandeLeds(){
    for( int i = 0; i < NUMBER_LEDS; i++) {
        if ( tour - i >0 ){
          leds[i] = CHSV( 0, 0, 0) ;
        }
    }  
}

这是我的标题 LedsHorloge.h

#ifndef LedsHorloge_h
#define LedsHorloge_h

#include <Arduino.h>
#include "FastLED.h"

class LedsJauge
{
 public:
 LedsJauge(int pin);
 // A chaque tour une led supplémentaire de la jauge est allumée
 void Jauge(int tour, int numberLeds, int brightness, CRGB* ledTable);
 private:
 int _pin;
};


#endif

这是我的名为 LedsHorloge.cpp 的源代码

#include <Arduino.h>
#include "FastLED.h"
#include "LedsHorloge.h"

LedsJauge::LedsJauge(int pin)
{
 _pin = pin;
}

void LedsJauge::Jauge(int tour, int numberLeds, int brightness, CRGB* ledTable)
{
    for( int i = 0; i < numberLeds; i++) {
        if ( tour - i >0 ){
          ledTable[i] = CHSV( 100, 187, brightness) ;
        }
    }

 return;
}

我不知道如何在 object 上创建一个指针CRGB leds[NUMBER_LEDS];。

4

2 回答 2

0

我从另一个论坛得到答案，解决方案是替换：

jauge.Jauge(tour, NUMBER_LEDS, BRIGHTNESS, &leds);

经过

jauge.Jauge(tour, NUMBER_LEDS, BRIGHTNESS, leds);

但是，我真的不明白为什么我不能使用变量的内存值，而我在函数 Jauge 的声明中使用指针，让我们看看：

void LedsJauge::Jauge(int tour, int numberLeds, int brightness, CRGB* ledTable)
于 2018-07-17T06:50:31.763 回答
0

那是因为

    CRGB leds[NUMBER_LEDS];

leds已经是一个指针；只是它是一个常量指针。即不能改变变量的地址。

于 2021-04-18T11:54:42.327 回答