6

多年来，Delphi 一直支持应用程序设置选项卡上的启用运行时主题开关。但是，这仅适用于可执行文件。假定 DLL 会从其父应用程序中接管主题（和其他）设置。

不幸的是，Microsoft Office 在那里表现不佳。它们的“主题”外观是使用自定义控件实现的，而不是通过 Windows 自己的通用控件。

在 MSDN 文章830033 - 如何将 Windows XP 主题应用于 Office COM 加载项中， Microsoft 解释了如何将清单应用于 DLL，使其具有隔离意识，从而忽略来自父进程的设置。

基本上，它归结为两个步骤：

  1. 在您的进程中包含默认清单资源，使用 2 的 int-resource id（而不是您通常使用的 1）。
  2. 使用 ISOLATION_AWARE_ENABLED 定义进行编译。**这在 Delphi 中不可用。**

我想我已经确定了 (1)，尽管我不太确定 brcc32 是否将资源 ID 作为整数或文字字符串来获取。真正的问题在于（2）。据说，这个定义改变了几个 DLL 函数绑定。

有没有人在Delphi中解决过这个问题？我应该进一步调查这条路线，我应该尝试手动创建激活上下文，还是有其他优雅的解决方案来解决这个问题？

4

1 回答 1

9

我已经为我的 COM 加载项完成了此操作。我使用了激活上下文。COM 插件非常容易，因为插件界面的表面积非常小。我可以发布代码，但直到明天我才会在机器上。希望这可以帮助！

更新

正如所承诺的，这是我使用的代码：

type
  (* TActivationContext is a loose wrapper around the Windows Activation Context API and can be used
     to ensure that comctl32 v6 and visual styles are available for UI elements created from a DLL .*)
  TActivationContext = class
  private
    FCookie: LongWord;
    FSucceeded: Boolean;
  public
    constructor Create;
    destructor Destroy; override;
  end;

var
  ActCtxHandle: THandle=INVALID_HANDLE_VALUE;
  CreateActCtx: function(var pActCtx: TActCtx): THandle; stdcall;
  ActivateActCtx: function(hActCtx: THandle; var lpCookie: LongWord): BOOL; stdcall;
  DeactivateActCtx: function(dwFlags: DWORD; ulCookie: LongWord): BOOL; stdcall;
  ReleaseActCtx: procedure(hActCtx: THandle); stdcall;

constructor TActivationContext.Create;
begin
  inherited;
  FSucceeded := (ActCtxHandle<>INVALID_HANDLE_VALUE) and ActivateActCtx(ActCtxHandle, FCookie);
end;

destructor TActivationContext.Destroy;
begin
  if FSucceeded then begin
    DeactivateActCtx(0, FCookie);
  end;
  inherited;
end;

procedure InitialiseActivationContext;
var
  ActCtx: TActCtx;
  hKernel32: HMODULE;
begin
  if IsLibrary then begin
    hKernel32 := GetModuleHandle(kernel32);
    CreateActCtx := GetProcAddress(hKernel32, 'CreateActCtxW');
    if Assigned(CreateActCtx) then begin
      ReleaseActCtx := GetProcAddress(hKernel32, 'ReleaseActCtx');
      ActivateActCtx := GetProcAddress(hKernel32, 'ActivateActCtx');
      DeactivateActCtx := GetProcAddress(hKernel32, 'DeactivateActCtx');
      ZeroMemory(@ActCtx, SizeOf(ActCtx));
      ActCtx.cbSize := SizeOf(ActCtx);
      ActCtx.dwFlags := ACTCTX_FLAG_RESOURCE_NAME_VALID or ACTCTX_FLAG_HMODULE_VALID;
      ActCtx.lpResourceName := MakeIntResource(2);//ID of manifest resource in isolation aware DLL
      ActCtx.hModule := HInstance;
      ActCtxHandle := CreateActCtx(ActCtx);
    end;
  end;
end;

procedure FinaliseActivationContext;
begin
  if ActCtxHandle<>INVALID_HANDLE_VALUE then begin
    ReleaseActCtx(ActCtxHandle);
  end;
end;

initialization
  InitialiseActivationContext;

finalization
  FinaliseActivationContext;

当您想使用它时，您只需编写如下代码：

var
  ActivationContext: TActivationContext;
....
ActivationContext := TActivationContext.Create;
try
  //GUI code in here will support XP themes
finally
  ActivationContext.Free;
end;

您需要将执行 GUI 工作的每个入口点包装在此类代码中。

请注意，在我的 COM 加载项 DLL 中，我采取了特殊措施来DLLMain避免InitialiseActivationContext在FinaliseActivationContext. 但是，我认为没有理由将这段代码放在那里不安全。

于 2011-02-27T12:32:54.017 回答