1

我正在尝试使用四个点光源来实现Cook-Torrance 照明模式。虽然我只使用一个点光源就得到了很好的结果，但我不明白哪种方法是在我的光循环中总结镜面反射项的正确方法。

我将材料定义如下：

struct material {
    vec3 ambient; /* ambient color */
    vec3 diffuse; /* diffuse color */
    vec3 specular; /* speculr color */
    float metallic;
    float roughness;
};

...因此我的灯只有一种颜色/强度属性，

struct light {
    vec3 position;
    vec3 color;
    bool enabled;
};

这是我的片段着色器中带有片段颜色计算的函数：

vec3 lighting() {
    vec3 color = vec3(0.0,0.0,0.0);
    float r0 = pow(material.metallic - 1.0,2.0)/pow(material.metallic + 1.0,2.0);
    vec3 V = normalize(-v_viewpos);
    vec3 N = normalize(v_normal);
    for (int i = 0; i < 4; i++) {
        if (light[i].enabled) {
            vec3 L = normalize(light[i].position - v_viewpos);
            // Half-way vector 
            vec3 halfVector = normalize(L + V);
            float NdotL = max(dot(N, L),0.0);
            float NdotV = max(dot(N, V),0.0);
            if (NdotL > 0.001 && NdotV > 0.001) {
                float NdotH = max(0.0, dot(N, halfVector));
                float HdotV = max(0.0, dot(halfVector, V));
                // Beckmann 
                float tanAlpha = sqrt(1.0-NdotH*NdotH)/NdotH;
                float D = exp(-pow(tanAlpha/material.roughness,2.0))/(4.0*pow(material.roughness,2.0)*pow(NdotH,4.0));
                // Shadowing-masking term 
                float G1 = (2.0 * NdotH * NdotV) / HdotV;
                float G2 = (2.0 * NdotH * NdotL) / HdotV;
                float G = min(1.0, min(G1, G2));
                // Fresnel reflection, Schlick approximation 
                float F = r0 + (1.0 - r0) * pow(1.0 - NdotL, 5.0);
                float R = (F*G*D) / (3.14159 * NdotL * NdotV);
                color += light[i].color * R * NdotL;
            }
            color += material.diffuse * light[i].color;
        }
    }
    return color;
}

我相信这里的关键是我在光循环中的错误计算：

color += light[i].color * R * NdotL;

这是我的意思的一个例子，产生的片段颜色要么太暗，要么太亮。我无法总结每个光的贡献，以获得镜面反射项和材质颜色之间的平滑颜色渐变。

在此处输入图像描述

我在这里阅读有关伽马校正的信息，但我不明白这是否适用于我的问题。

我应该如何将每个 light.color 与材质的漫反射、环境和镜面反射颜色相加，以计算最终的片段颜色，正确地包括每个灯光的镜面反射高光贡献总量？

4

2 回答 2

1
  • vec3 V应该是从片段位置到相机位置的归一化向量。
  • vec3 L应该是从片段位置到光照位置的归一化向量。

这些向量之一在您的着色器中是错误的，具体取决于v_viewpos.

菲涅耳应该基于 HoV 而不是 NoL： pow(1.0 - HoV, 5.0)

对于漫反射部分，您将您的光视为环境光而不是点光。

color += material.diffuse * light[i].color;

应该是（对于简单的朗伯）

color += material.diffuse * light[i].color * NoL;

于 2018-07-12T18:16:56.943 回答
1

您的大多数计算看起来都不错（包括 和 的方向V以及L菲涅耳项）。唯一的问题是您可能混淆了如何组合各个照明组件。对于镜面反射和漫反射，您有

color += light[i].color * R * NdotL;

R对应于镜面反射部分和NdotL漫反射部分。然而，两者都是相加的。因此，方程应该是（加上考虑材料参数）：

color += light[i].color * (material.specular * R + material.diffuse * NdotL);

对于您拥有的环境术语

color += material.diffuse * light[i].color;

替换material.diffuse为material.ambient，这应该是正确的。

并确保你的灯不太亮。屏幕不能显示比白色（或完全饱和的红色）更亮的东西。

于 2018-07-13T06:38:22.670 回答