-1

在 macOS 的邮件应用程序中，我使用了许多智能文件夹（一个显示预定义搜索条件结果的特定邮箱）。因此，这些智能邮箱显示来自不同帐户和文件夹的邮件。

通常，我需要跳转到结果列表中选择的消息所在的实际邮箱/文件夹。我也有很多文件夹。

新邮件应用程序的一个改进（烦恼）是我找不到这样做的方法。在过去的 macOS 版本中（至少到 Mavericks），这很容易。我可以像在许多其他应用程序中一样做同样的事情。看图片。

在此处输入图像描述

以前的技巧在邮件应用程序的消息窗口中不再起作用。

有什么方法可以跳转或打开我在搜索结果或智能邮箱中选择的邮件所在的邮箱/文件夹？

4

1 回答 1

0

使用 Automator + AppleScript 的解决方案

我找到的解决方案是创建一个 Automator 服务，并可选择将其与快捷方式相关联。

  1. 打开自动机。
  2. 新文件。
  3. 选择Service文档类型。
  4. 在窗口顶部，设置此服务的输入类型：
    Service receives selected选择no input
    in选择Mail.app
  5. 在 Actions 库（左窗格）中找到 action Run AppleScript。
  6. 将其拖放到工作流区域中。
  7. 复制此答案末尾的代码并将其粘贴到操作Run AppleScript中。
  8. 保存您的服务（例如“跳转到文件夹”）。

测试服务

在测试服务时，Automator 和 Mail App 可以保持打开状态。

  1. 打开邮件应用程序。
  2. 进行搜索并选择一条消息，最好是位于自定义文件夹中的消息。
  3. 在菜单栏中转到Mail> Services。您应该看到您的新服务。
  4. 选择服务。

选定和活动的邮箱/文件夹应该是先前选择的邮件的邮箱。

选修的。为您的服务分配快捷方式：

  1. 打开系统偏好设置。
  2. 前往Keyboard>Shortcuts
  3. 在左侧窗格中选择Services
  4. 在右窗格的末尾，General您应该找到您的服务
  5. 为其分配快捷方式（例如CMD- OPTION- J）

编码

set theDialogTitle to "Go to Folder Script"

tell application "Mail"

    -- Get the selected messages and the count of them
    set theMessageList to selected messages of message viewer 1
    set theCount to length of theMessageList

    -- Error if no messages
    if theCount is 0 then
        display dialog ¬
            "No message selected." with title theDialogTitle buttons {"OK"} with icon caution
        return
    end if

    -- Error if more than one message
    if theCount is greater than 1 then
        display dialog ¬
            "Must select only one message." with title theDialogTitle buttons {"OK"} with icon caution
        return
    end if

    -- Get the message
    set theMessage to item 1 of theMessageList

    -- Get the mailbox object
    set theMailbox to mailbox of theMessage

    -- Select the mailbox
    set selected mailboxes of message viewer 1 to theMailbox

end tell
于 2018-07-11T02:47:52.640 回答