2

我有一个功能可以动态地将文本添加到预先指定位置的图像中。最初我是用 jpegs 做的，它正在工作。我切换到PNG，因此图像质量会更好，因为原始的jpeg有点像素化。无论如何，这是我的代码。它执行到oBitmap.Save()，然后死于“GDI+ 中发生一般错误”。

Public Sub ProcessRequest(ByVal context As HttpContext) Implements IHttpHandler.ProcessRequest
    context.Response.ContentType = "image/png"
    context.Response.Clear()
    context.Response.BufferOutput = True

    Try
        Dim oText As String = context.Server.HtmlDecode(context.Request.QueryString("t"))
        If String.IsNullOrEmpty(oText) Then oText = "Placeholder"
        Dim oPType As String = context.Server.HtmlDecode(context.Request.QueryString("p"))
        If String.IsNullOrEmpty(oPType) Then oPType = "none"

        Dim imgPath As String = ""
        Select Case oPType
            Case "c"
                imgPath = "img/banner_green.png"
            Case "m"
                imgPath = "img/banner_blue.png"
            Case Else
                Throw New Exception("no ptype")
        End Select

        Dim oBitmap As Bitmap = New Bitmap(context.Server.MapPath(imgPath))
        Dim oGraphic As Graphics = Graphics.FromImage(oBitmap)
        Dim frontColorBrush As New SolidBrush(Color.White)
        Dim oFont As New Font(FONT_NAME, 30)


        Dim oInfo() As ImageCodecInfo = ImageCodecInfo.GetImageEncoders
        Dim oEncoderParams As New EncoderParameters(2)
        Dim xOffset As Single = Math.Round((oBitmap.Height - oFont.Height) / 2, MidpointRounding.ToEven)
        Dim oPoint As New PointF(275.0F, xOffset + 10)

        oEncoderParams.Param(0) = New EncoderParameter(Encoder.Quality, 100L)
        oEncoderParams.Param(1) = New EncoderParameter(Encoder.ColorDepth,8L)

        oGraphic.TextRenderingHint = Drawing.Text.TextRenderingHint.AntiAlias
        oGraphic.DrawString(oText, oFont, frontColorBrush, oPoint)
        oBitmap.Save(context.Response.OutputStream, oInfo(4), oEncoderParams)
        context.Response.Output.Write(oBitmap)

        oFont.Dispose()
        oGraphic.Dispose()
        oBitmap.Dispose()  
        context.Response.Flush()
    Catch ex As Exception

    End Try
End Sub

我从 jpeg 版本对此所做的唯一更改是：

  • context.Response.ContentType = "image/jpeg"变成"image/png"
  • 将基础图像 ( img/banner_green.jpg, img/banner_blue.jpg) 更改为.png
  • 添加了指定颜色深度的第二个编码参数
  • 将oInfo(1)(jpeg) 更改为oInfo(4)(png)

我是否需要调整更多的东西才能让这个例程正确生成 PNG？

4

2 回答 2

5

根据这篇文章，Bitmap.Save 需要一个可搜索的流来保存为 PNG，而 HttpResponse.OutputStream 不是。您必须先将图像保存到 MemoryStream 中，然后将其内容复制到 Response.OutputStream，例如：

Dim tempStream as New MemoryStream
oBitmap.Save(tempStream, ImageFormat.Png, oEncoderParams)
Response.OutputStream.Write(tempStream.ToArray(), 0, tempStream.Length)

另请注意，该行

context.Response.Output.Write(oBitmap)

做一些与您可能期望的不同的事情。HttpResponse.Output是一个 TextWriter，您在此处使用的重载TextWriter.Write(object)只会在对象上调用 ToString 并将结果写入流中，在这种情况下会导致将“System.Drawing.Bitmap”写入输出。

于 2009-02-04T15:17:59.663 回答
0

您在刷新响应之前处理位图？尝试翻转它。此外，看起来您正在将位图写入流两次。我不确定你为什么要这样做。将位图保存到输出流或使用 Response 对象的 Write 方法，但不能同时使用两者。

于 2009-02-04T14:31:38.167 回答