apache-flex - Flex 3 - 如何支持 HTTP Authentication URLRequest？

Question

我有一个使用 URLRequest 将文件上传到服务器的 Flex 文件上传脚本。我想添加对 http 身份验证（服务器上受密码保护的目录）的支持，但我不知道如何实现这一点 - 我假设我需要以某种方式扩展类，但我有点迷失了。

我尝试修改以下内容（用 URLRequest 替换 HTTPService），但这没有用。

private function authAndSend(service:HTTPService):void{        
   var encoder:Base64Encoder = new Base64Encoder();        
   encoder.encode("someusername:somepassword");        
   service.headers = {Authorization:"Basic " + encoder.toString()};
   service.send();
}

我应该指出，我对 ActionScript / Flex 并不了解，尽管我已经成功地修改了上传脚本。

[编辑] - 这是我的进度更新，基于下面的答案，虽然我仍然无法让它工作：

谢谢您的帮助。我试图实现你的代码，但我没有任何运气。

我在处理经过 HTTP 身份验证的位置时遇到的一般行为是，使用 IE7 一切都很好，但在 Firefox 中，当我尝试将文件上传到服务器时，它会显示 HTTP 身份验证提示 - 即使给出正确的详细信息，也会停止上传过程。

我相信 IE7 正常的原因是浏览器和 Flash 组件共享的会话/身份验证信息 - 但是，在 Firefox 中情况并非如此，我遇到了上述行为。

这是我更新的上传功能，包含您的更改：

private function pergress():void 
{
if (fileCollection.length == 0) 
  {
  var urlString:String = "upload_process.php?folder="+folderId+"&type="+uploadType+"&feid="+formElementId+"&filetotal="+fileTotal;
  if (ExternalInterface.available) 
    {
    ExternalInterface.call("uploadComplete", urlString);
    }
  }
if (fileCollection.length > 0) 
  {
  fileTotal++;
  var urlRequest:URLRequest = new URLRequest("upload_file.php?folder="+folderId+"&type="+uploadType+"&feid="+formElementId+"&obfuscate="+obfuscateHash+"&sessidpass="+sessionPass);
  urlRequest.method = URLRequestMethod.POST;
  urlRequest.data = new URLVariables("name=Bryn+Jones");
  var encoder:Base64Encoder = new Base64Encoder();
  encoder.encode("testuser:testpass");
  var credsHeader:URLRequestHeader = new URLRequestHeader("Authorization", "Basic " + encoder.toString());
  urlRequest.requestHeaders.push(credsHeader);

  file = FileReference(fileCollection.getItemAt(0));
  file.addEventListener(Event.COMPLETE, completeHandler);
  file.addEventListener(HTTPStatusEvent.HTTP_STATUS, onHTTPStatus);
  file.addEventListener(ProgressEvent.PROGRESS, onUploadProgress);
  file.upload(urlRequest);
  }
}

如上所述，无论是否修改我的功能，我似乎都遇到了相同的结果。

我还可以问一下 crossdomain.xml 应该放在哪里 - 因为我目前没有，并且不确定将它放在哪里。

score 19 · Accepted Answer

URLRequest 的语法有点不同，但思路是一样的：

private function doWork():void
{
    var req:URLRequest = new URLRequest("http://yoursite.com/yourservice.ext");
    req.method = URLRequestMethod.POST;
    req.data = new URLVariables("name=John+Doe");

    var encoder:Base64Encoder = new Base64Encoder();        
    encoder.encode("yourusername:yourpassword");

    var credsHeader:URLRequestHeader = new URLRequestHeader("Authorization", "Basic " + encoder.toString());
    req.requestHeaders.push(credsHeader);

    var loader:URLLoader = new URLLoader();
    loader.load(req);
}

要记住几件事：

最好的我可以说，出于某种原因，这仅适用于请求方法为 POST 的情况；标头没有使用 GET 请求设置。
有趣的是，除非至少一个 URLVariables 名称-值对与请求一起打包，否则它也会失败，如上所述。这就是为什么您看到的许多示例（包括我的示例）都附加了“name=John+Doe”——它只是 URLRequest 在设置任何自定义 HTTP 标头时似乎需要的一些数据的占位符。没有它，即使是经过适当身份验证的 POST 请求也会失败。
显然，Flash 播放器版本9.0.115.0完全阻止了所有 Authorization 标头（有关此处的更多信息），因此您可能也需要记住这一点。
您几乎肯定必须修改您的 crossdomain.xml 文件以适应您将要发送的标头。就我而言，我正在使用它，这是一个相当广泛的策略文件，因为它可以从任何域接受，所以在你的情况下，你可能想要更多地限制一些事情，这取决于你的安全意识如何.

跨域.xml：

<?xml version="1.0"?>
<cross-domain-policy>
    <allow-access-from domain="*" />
    <allow-http-request-headers-from domain="*" headers="Authorization" />
</cross-domain-policy>

……这似乎行得通；Adobe 可在此处获得有关此信息的更多信息）。

上面的代码是用 Flash player 10（带有调试和发布 SWF）测试的，所以它应该适合你，但我想更新我的原始帖子以包含所有这些额外的信息，以防你遇到任何问题，因为机会似乎（遗憾地）你可能会。

希望能帮助到你！祝你好运。我会留意评论。

score 3 · Accepted Answer

FileReference.upload() 和 FileReference.download() 方法不支持 URLRequest.requestHeaders 参数。

http://livedocs.adobe.com/flex/2/langref/flash/net/URLRequest.html

score 2 · Accepted Answer

如果要上传文件，只需通过 UploadPostHelper 类使用 URLRequest 发送正确的标题和文件内容。这 100% 有效，我正在使用此类上传生成的图像和 CSV 文件，但您可以上传任何类型的文件。

此类仅准备带有标头和内容的请求，就好像您要从 html 表单上传文件一样。

http://code.google.com/p/as3asclublib/source/browse/trunk/net/UploadPostHelper.as?r=118

_urlRequest = new URLRequest(url);
        _urlRequest.data = "LoG";
        _urlRequest.method = URLRequestMethod.POST; 

        _urlRequest.requestHeaders.push(new URLRequestHeader("X-HTTP-Code-Override", "true"));
        _urlRequest.requestHeaders.push(new URLRequestHeader("pragma", "no-cache"));

        initCredentials();
_loader.dataFormat = URLLoaderDataFormat.BINARY;
            //this creates a security problem, putting the content type in the headers bypasses this problem
            //_urlRequest.contentType = 'multipart/form-data; boundary=' + UploadPostHelper.getBoundary();
            _urlRequest.requestHeaders.push( new URLRequestHeader( 'Cache-Control', 'no-cache' ) );
            _urlRequest.requestHeaders.push(new URLRequestHeader('Content-Type', 'multipart/form-data; boundary=' + UploadPostHelper.getBoundary()));
            _urlRequest.data = UploadPostHelper.getPostData("file.csv", param[1]);

        _loader.load(_urlRequest);

score 1 · Accepted Answer

我不确定这一点，但您是否尝试将 username:password@ 添加到您的网址的开头？

" http://用户名:password@yoursite.com/yourservice.ext "

score 1 · Accepted Answer

var service : HTTPService  = new HTTPService ();
var encoder:Base64Encoder = new Base64Encoder();
encoder.insertNewLines = false;
encoder.encode("user:password");

service.headers = {Authorization:"Basic " + encoder.toString()};
service.method = HTTPRequestMessage.POST_METHOD;
service.request = new URLVariables("name=John+Doe");
service.addEventListener(FaultEvent.FAULT,error_handler );
service.addEventListener(ResultEvent.RESULT,result_handler);
service.url = 'http://blah.blah.xml?'+UIDUtil.createUID();
service.send();

score 0 · Accepted Answer

看似相似的问题在这里得到了解决。我敦促您也检查第一篇文章中链接到的Flexcoders帖子。

问题在于 FireFox 使用单独的浏览器窗口实例来发送文件上传请求。解决方案是将会话 ID 手动附加到请求 url。会话 ID 不是作为常规 GET 变量附加的，而是带有分号（我不知道这种语法的原因）。

score 0 · Accepted Answer

Flash 在您可以通过 http 请求传递什么样的标头方面非常有限（并且它在浏览器和操作系统之间发生变化）。如果您让它在一个浏览器/操作系统上运行，请确保在其他浏览器/操作系统上进行测试。

最好的办法是不要弄乱 HTTP 标头。

我们有同样的问题（从 Flash 上传到 Picasa 网络相册）并通过我们服务器上的代理发布。我们将额外的标头作为 post 参数传递，我们的代理做正确的事情。

score 0 · Accepted Answer

" http://用户名:password@yoursite.com/yourservice.ext "

这在 IE ( http://www.theregister.co.uk/2004/01/30/ms_drop_authentication_technique/ ) 中不起作用，并且在 Chrome 中似乎也不起作用。

可能无法在 Flash 中使用

score 0 · Accepted Answer

这是使用 ASP.Net 时的变通方法，部分基于此处的工作。

我构建了一个将 Flex 对象动态写入页面的组件，以便它们可以在 UpdatePanels 中使用。如果您想要他们的代码，请给我留言。为了解决需要通过 URLRequest 发送身份验证 cookie 的页面中的上述问题，我将值添加为 flashVars。

此代码仅适用于我的对象，但您明白了

Dictionary<string, string> flashVars = new Dictionary<string, string>();     
flashVars.Add("auth", Request.Cookies["LOOKINGGLASSFORMSAUTH"].Value);
flashVars.Add("sess", Request.Cookies["ASP.NET_SessionId"].Value);
myFlexObject.SetFlashVars(flashVars);

然后在 Flex 对象中，检查参数

if (Application.application.parameters.sess != null)
    sendVars.sess= Application.application.parameters.sess;
if (Application.application.parameters.auth != null)
    sendVars.au= Application.application.parameters.auth;

request.data = sendVars;
request.url = url;
request.method = URLRequestMethod.POST;

最后将 cookie 填入 global.asax BeginRequest

if (Request.RequestType=="POST" && Request.Path.EndsWith("upload.aspx"))
{
    try
    {
        string session_param_name = "sess";
        string session_cookie_name = "ASP.NET_SESSIONID";
        string session_value = Request.Form[session_param_name]; // ?? Request.QueryString[session_param_name];
        if (session_value != null) { UpdateCookie(session_cookie_name, session_value); }
    }
    catch (Exception) { }

    try
    {
        string auth_param_name = "au";
        string auth_cookie_name = FormsAuthentication.FormsCookieName;
        string auth_value = Request.Form[auth_param_name];// ?? Request.QueryString[auth_param_name];

        if (auth_value != null) { UpdateCookie(auth_cookie_name, auth_value); }
    }
    catch (Exception) { }   

}

希望这可以帮助某人避免我刚刚花费了 6 个小时来解决这个问题。Adobe 已将该问题视为无法解决，因此这是我最后的手段。

apache-flex - Flex 3 - 如何支持 HTTP Authentication URLRequest？

9 回答 9

Related

Reference