3

给定以下仆人服务器：

{-# LANGUAGE DataKinds #-}
{-# LANGUAGE TemplateHaskell #-}
{-# LANGUAGE TypeOperators #-}

module ServantSample (main) where

import Data.Aeson
import Data.Aeson.TH
import Network.Wai
import Network.Wai.Handler.Warp
import Servant

data Spec = Spec
  { schema :: Object
  } deriving (Eq, Show)
$(deriveJSON defaultOptions ''Spec)

type Api = ReqBody '[JSON] Spec :> Post '[JSON] NoContent

server :: Server Api
server = postDoc

postDoc :: Spec -> Handler NoContent
postDoc _ = return NoContent

api :: Proxy Api
api = Proxy

app :: Application
app = serve api server

main :: IO ()
main = run 8080 app

...以及以下 curl 到上述服务器的运行实例：

curl localhost:8080 -H 'Content-Type: application/json' --data '{"schema": "I am not an object but I should be!"}'

我回来了：

Error in $.schema: expected HashMap ~Text v, encountered String

有没有办法拦截 Aeson 错误并将其替换为不会将实现细节泄漏给客户端的东西？据我所知，这一切都发生在 Servant 机器的幕后，我找不到任何关于如何连接它的文档。

例如，我很想返回类似的东西：

Expected a JSON Object under the key "schema", but got the String "I am not an object but I should be!"

谢谢！

4

1 回答 1

2

手动编写 FromJSON 实例可以解决至少一半的问题。

instance FromJSON Spec where
  parseJSON (Object o) = do
    schema <- o .: "schema"
    case schema of
      (Object s) -> pure $ Spec s
      (String s) -> fail $ "Expected a JSON Object under the key \"schema\", but got the String \"" ++ unpack s ++ "\"\n"
      _          -> fail $ "Expected a JSON Object under the key \"schema\", but got the other type"
  parseJSON wat = typeMismatch "Spec" wat

然后您的 curl 命令返回：

Error in $: Expected a JSON Object under the key "schema", but got the String "I am not an object but I should be!"

您显然可以检查Value来自 Aeson 的不同类型构造函数并将其分解为一个单独的函数。

通过查看Data.Aeson.Types.typeMismatch的实现得到代码

于 2018-05-31T13:56:05.913 回答