1

如何在 VESA 图形模式下绘制像素？

我正在尝试中断10h功能0ch，但它不起作用。怎么了？

（注：我用 NASM 语法写了这段代码，并用 qemu 测试过）

; Code:
Mov ax, 4F02h
Mov bx, 0105h ; 1024x768 pixels
Int 10h

Mov ah, 0ch ; Draw pixel function
Mov cx, 2           ; column
Mov dx, 3           ; row
Mov bh, 0    
Mov bl, 00000101b   ; colour
Int 10h

Jmp $            ; jump forever
Times 510-($-$$) db 0
Dw 0xaa55
4

1 回答 1

9

即使在使用 VESA VBE 模式时 ，功能Int 10h/AH=0Ch也应该起作用。

确保正确使用它，像素的颜色进入al.

;Set video mode
mov ax, 4f02h
mov bx, 105h
int 10h

;Draw pixel
mov ax, 0c09h    ;09h = Blue
mov cx, 2 
mov dx, 3     
xor bx, bx   
int 10h

从技术上讲，您应该使用Int 10h/AX=4F01h来检索视频模式信息，包括模式属性字段的第 2 位（支持 2 个 BIOS 输出），以检查 BIOS 功能是否可以工作。

使用 BIOS 功能写入高分辨率图像可能太慢，可能值得投资直接写入线性或窗口帧缓冲区。
写入线性帧缓冲区可能需要使用虚幻模式，可以通过使用窗口帧缓冲区来避免这种情况。
这除了更慢之外，也更麻烦。

这是一个非常简单的程序，它用可怕的灰色阴影填充 30 行。
请注意，为了紧凑和清晰，我剥离了所有检查，我做了很多假设以避免做一些数学运算。
这是一个不好的做法，我只将它用于原型设计。
我强烈建议您阅读由返回的完整信息Int 10h/AX=4F01h并使用该信息来选择正确的窗口，进行正确的填充和计算。

BITS 16

ORG 100h

mov ax, ds
mov es, ax 

;Set video mode
mov ax, 4f02h
mov bx, 105h
int 10h

;Get video mode info
mov ax, 4f01h
mov cx, 105h
mov di, modeInfo 
int 10h

;Assume first window is valid 
mov ax, WORD [es:modeInfo + 08h]
mov es, ax

;Example of how to change the window 
mov ax, 4f05h
xor bx, bx
mov dx, 5       ;This is granularity units
int 10h

xor di, di 
mov al, 0f1h
mov cx, 3*1024*20

rep stosb

;Wait for key
xor ax, ax
int 16h

;Restore DOS text mode
mov ax, 0003h
int 10h

;Exit
mov ax, 4c00h
int 21h

modeInfo    TIMES 256 db 0

这是 NASM 语法，我通常对 DOS 程序使用 TASM（出于感情），但这次我很着急。
结果是

黑屏中间或多或少的灰色带

请记住，通常可以填充每条扫描线（扫描线的大小在视频模式信息中返回）。
对于 1024 像素宽的扫描线，对于 3x8bpp，我们有 3072 字节/扫描线，因为它可以被 4 整除，所以不会发生填充。
窗口起始地址以粒度单位给出（也可在视频模式信息中找到），总帧缓冲区为 1024x768x3 字节 = 2.25 MiB，假设没有填充。
窗口大小也可以在视频模式信息中找到。

所有这些都足以写入帧缓冲区。
一旦设置了虚幻模式，线性帧缓冲区就更容易处理（填充仍然是一个需要考虑的方面）。

于 2018-05-26T10:45:38.423 回答