regex - 如何在perl中匹配包含精确3次出现特殊字符的字符串

Question

我尝试了几种方法来匹配包含精确 3 倍斜线但无法工作的单词。下面是例子

@array = qw( abc/ab1/abc/abc a2/b1/c3/d4/ee w/5/a  s/t )
foreach my $string (@array){
    if ( $string =~ /^\/{3}/ ){
          print " yes, word with 3 / found !\n";
          print "$string\n";
    }
    else {
          print " no word contain 3 / found\n";
    }

我尝试了很少的东西，但它们都不起作用

$string =~ /^\/{3}/;
$string =~ /^(\w+\/\w+\/\w+\/\w+)/;
$string =~ /^(.*\/.*\/.*\/.*)/;

还有其他方法可以匹配这种类型的字符串并打印字符串吗？

Answer 1

全局匹配 a/并将匹配数与3

if ( ( () = m{/}g ) == 3 ) { say "Matched 3 times" }

其中=()=运算符是上下文的游戏，强制列表上下文在其右侧，但在其左侧提供标量上下文时返回该列表的元素数。

如果您对这样的语法延伸感到不舒服，那么分配给一个数组

if ( ( my @m = m{/}g ) == 3 ) { say "Matched 3 times" }

随后的比较在标量上下文中对其进行评估。

您正在尝试匹配三个连续 /的并且您的字符串没有。

Answer 2

The pattern you need (with whitespace added) is

^ [^/]* / [^/]* / [^/]* / [^/]* \z

or

^ [^/]* (?: / [^/]* ){3} \z

Your second attempt was close, but using ^ without \z made it so you checked for string starting with your pattern.

---

Solutions:

say for grep { m{^ [^/]* (?: / [^/]* ){3} \z}x } @array;

or

say for grep { ( () = m{/}g ) == 3 } @array;

or

say for grep { tr{/}{} == 3 } @array;

Answer 3

你需要匹配

• 斜线
• 被一些非斜线 ( ^(?:[^\/]*)包围
• 准确地重复比赛三遍
• 并将整个三元组包含在行首和行锚的开头：

$string =~ /^(?:[^\/]*\/[^\/]*){3}$/;

Answer 4

if ( $string =~ /\/.*\/.*\// and $string !~ /\/.*\/.*\/.*\// )