xslt - XSLT 分组半小时

Question

鉴于此 XML：

<root>
  <row>
    <time>08:00</time>
    <sales>800</sales>
  </row>
  <row>
    <time>08:15</time>
    <sales>815</sales>
  </row>
  <row>
    <time>08:30</time>
    <sales>830</sales>
  </row>
  <row>
    <time>08:45</time>
    <sales>845</sales>
  </row>
  <row>
    <time>11:00</time>
    <sales>1100</sales>
  </row>
  <row>
    <time>11:45</time>
    <sales>1145</sales>
  </row>
  <row>
    <time>14:15</time>
    <sales>1415</sales>
  </row>
  <row>
    <time>14:30</time>
    <sales>1430</sales>
  </row>
</root>

我试图通过按 30 分钟间隔汇总销售额来找到一种 XSLT 转换的方法。我可以使用 MUENCHIAN 方法按每小时间隔 60 分钟进行汇总，但我不能使用 30 分钟，因为我需要一个自定义函数来执行此操作（但我不能使用 XSLT 2.0，也不能使用 .Net 的自定义函数）。请帮忙！

预期的输出是这样的：

30 minute
08:00 $1600  
08:30 $1675 
11:00 $1100 
11:30 $1145 
14:00 $1415 
14:30 $1430

score 6 · Accepted Answer

解决方案 1。

这种转变：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:key name="krowsInHalfHour" match=
  "row[not((substring-after(time,':')+30) mod 30 = 0)]"
  use="generate-id(
        preceding-sibling::row
          [60*substring-before(time,':')
          +
           substring-after(time,':')
          >=
           60*substring-before(current()/time,':')
          +
           substring-after(current()/time,':')

          -
           substring-after(current()/time,':') mod 30

          ]
             [1]
                   )
  "/>

 <xsl:template match=
  "row[(substring-after(time,':')+30) mod 30 = 0
     or
      not(
       60*substring-before(preceding-sibling::row[1]/time,':')
          +
           substring-after(preceding-sibling::row[1]/time,':')
       >=
          60*substring-before(time,':')
          +
           substring-after(time,':')

          -
           substring-after(time,':') mod 30
          )
      ]
  ">
  <xsl:variable name="vPrevStartMins" select=
  "60*substring-before(time,':')
  +
   substring-after(time,':')

  -
   substring-after(time,':') mod 30
  "/>
  <xsl:value-of select=
   "concat('&#xA;',floor($vPrevStartMins div 60),
           ':', concat(substring('0',($vPrevStartMins mod 60 >0)+1),
                       $vPrevStartMins mod 60
                       )
           )
   "/>
  <xsl:text> $</xsl:text>
  <xsl:value-of select=
  "sum(sales
      |
       key('krowsInHalfHour',generate-id())/sales)"/>
 </xsl:template>

 <xsl:template match="text()"/>
</xsl:stylesheet>

应用于提供的 XML 文档时：

<root>
    <row>
        <time>08:00</time>
        <sales>800</sales>
    </row>
    <row>
        <time>08:15</time>
        <sales>815</sales>
    </row>
    <row>
        <time>08:30</time>
        <sales>830</sales>
    </row>
    <row>
        <time>08:45</time>
        <sales>845</sales>
    </row>
    <row>
        <time>11:00</time>
        <sales>1100</sales>
    </row>
    <row>
        <time>11:45</time>
        <sales>1145</sales>
    </row>
    <row>
        <time>14:15</time>
        <sales>1415</sales>
    </row>
    <row>
        <time>14:30</time>
        <sales>1430</sales>
    </row>
</root>

产生想要的正确结果：

8:00 $1615
8:30 $1675
11:00 $1100
11:30 $1145
14:00 $1415
14:30 $1430

解决方案 2：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my:my" >
 <xsl:output method="text"/>
 <xsl:strip-space elements="*"/>

 <my:halfHours>
  <t>00:00</t><t>00:30</t><t>01:00</t><t>01:30</t>
  <t>02:00</t><t>02:30</t><t>03:00</t><t>03:30</t>
  <t>04:00</t><t>04:30</t><t>05:00</t><t>05:30</t>
  <t>06:00</t><t>06:30</t><t>07:00</t><t>07:30</t>
  <t>08:00</t><t>08:30</t><t>09:00</t><t>09:30</t>
  <t>10:00</t><t>10:30</t><t>11:00</t><t>11:30</t>
  <t>12:00</t><t>12:30</t><t>13:00</t><t>13:30</t>
  <t>14:00</t><t>14:30</t><t>15:00</t><t>15:30</t>
  <t>16:00</t><t>16:30</t><t>17:00</t><t>17:30</t>
  <t>18:00</t><t>18:30</t><t>19:00</t><t>19:30</t>
  <t>20:00</t><t>20:30</t><t>21:00</t><t>21:30</t>
  <t>22:00</t><t>22:30</t><t>23:00</t><t>23:30</t>
  <t>24:00</t>
 </my:halfHours>

 <xsl:variable name="vhalfHrs" select=
  "document('')/*/my:halfHours/*"/>

 <xsl:template match="row">
  <xsl:variable name="vStart" select=
  "$vhalfHrs[translate(.,':','')
            >
             translate(current()/time,':','')
             ][1]
                 /preceding-sibling::*[1]
  "/>

  <xsl:variable name="vprecRow" select=
   "preceding-sibling::*[1]"/>

  <xsl:if test=
   "not(translate($vprecRow/time,':','')
       >=
       translate($vStart,':','')
       )">
   <xsl:value-of select="concat('&#xA;',$vStart, ' $')"/>
   <xsl:value-of select=
   "sum(sales|following-sibling::*
          [not(translate(time,':','')
              >=
               translate($vStart/following-sibling::*,':','')
               )
          ]
            /sales
        )
   "/>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于同一个 XML 文档时，再次产生所需的正确结果：

08:00 $1615
08:30 $1675
11:00 $1100
11:30 $1145
14:00 $1415
14:30 $1430

说明：

在变量$vhalfHrs中，我们的元素的值是一天中每半小时的开始时间。
在匹配 every 的模板中row，$vStart变量被设置为这个半小时的开始时间，time当前节点 ( row) 所在的时间。
该变量$vprecRow设置为当前的前一个兄弟 ( row) row。
如果前面的时间row不晚于 start-half-hour-time （在 $vStart ), then the currentrow` 中是这个半小时内的第一个。
我们输出开始的半小时时间段。
我们计算并输出在同一半小时时间段内的所有row元素的总和。time他们正在关注当前的兄弟姐妹，row并且他们time不大于或等于下一个半小时时段的开始。

解决方案 3 (XSLT 2.0)：

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema">
 <xsl:output method="text"/>

 <xsl:template match="/*">
  <xsl:for-each-group select="row" group-adjacent=
  "(xs:integer(substring-before(time,':'))*60
   +
    xs:integer(substring-after(time,':'))
    )
    idiv 30
  ">
   <xsl:variable name="vStartMinutes"
        select="current-grouping-key()*30"/>
   <xsl:value-of separator="" select=
   "'&#xA;',
     format-number($vStartMinutes idiv 60, '00'), ':',
     format-number($vStartMinutes mod 60,'00'),
     ' $',
     sum(current-group()/sales/xs:integer(.))
   "/>
  </xsl:for-each-group>
 </xsl:template>
</xsl:stylesheet>

当将此转换应用于与上述相同的 XML 文档时，会产生相同的想要的正确结果：

08:00 $1615
08:30 $1675
11:00 $1100
11:30 $1145
14:00 $1415
14:30 $1430

说明：

我们使用<xsl:for-each-group>属性group-adjacent集作为表达式来计算 a 所在的 1/2 小时周期的位置row/time。
大量使用标准功能 current-group()和current-grouping-key().

score 3 · Accepted Answer

没有前面的轴，这个样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:key name="kRowByHalfHour"
             match="row"
             use="floor((substring(time,1,2)*60+substring(time,4))div 30)"/>
    <xsl:template match="row[count(.|key('kRowByHalfHour',
                                         floor((substring(time,1,2) * 60
                                                 + substring(time,4)) div 30)
                                     )[1]
                             )=1
                         ]">
        <xsl:variable name="vKey"
             select="floor((substring(time,1,2)*60+substring(time,4))div 30)"/>
        <xsl:value-of
             select="concat(format-number(floor($vKey * 30 div 60),'00'),':',
                            format-number(($vKey * 30) mod 60,'00'),' $',
                            sum(key('kRowByHalfHour',$vKey)/sales),'&#xA;'
                     )"/>
    </xsl:template>
    <xsl:template match="text()"/>
</xsl:stylesheet>

输出：

08:00 $1615
08:30 $1675
11:00 $1100
11:30 $1145
14:00 $1415
14:30 $1430

编辑 2：更好的键值，标准化时间允许参数化（通过document()函数或两相变换）：如果我们将键计算作为复杂度度量，这将是 O(N)

xslt - XSLT 分组半小时

2 回答 2

Related

Reference