21

我一直在查看 ANTLR v3 文档（以及我可信赖的“The Definitive ANTLR reference”副本），但我似乎找不到在字符串文字中实现转义序列的干净方法（我目前正在使用 Java目标）。我曾希望能够做类似的事情：

fragment 
ESCAPE_SEQUENCE
    : '\\' '\'' { setText("'"); }
    ;

STRING  
    : '\'' (ESCAPE_SEQUENCE | ~('\'' | '\\'))* '\''
      { 
        // strip the quotes from the resulting token
        setText(getText().substring(1, getText().length() - 1));
      } 
    ;

例如，我希望输入标记“ 'Foo\'s House'”成为字符串“ Foo's House”。

不幸的是，片段setText(...)中的调用ESCAPE_SEQUENCE设置了整个STRING令牌的文本，这显然不是我想要的。

有没有一种方法可以在不添加返回结果字符串并手动替换转义序列的方法的情况下实现此语法（例如，使用类似规则setText(escapeString(getText()))中的内容STRING）？

4

4 回答 4

16

以下是我在我编写的 JSON 解析器中完成此操作的方法。

STRING      
@init{StringBuilder lBuf = new StringBuilder();}
    :   
           '"' 
           ( escaped=ESC {lBuf.append(getText());} | 
             normal=~('"'|'\\'|'\n'|'\r')     {lBuf.appendCodePoint(normal);} )* 
           '"'     
           {setText(lBuf.toString());}
    ;

fragment
ESC
    :   '\\'
        (   'n'    {setText("\n");}
        |   'r'    {setText("\r");}
        |   't'    {setText("\t");}
        |   'b'    {setText("\b");}
        |   'f'    {setText("\f");}
        |   '"'    {setText("\"");}
        |   '\''   {setText("\'");}
        |   '/'    {setText("/");}
        |   '\\'   {setText("\\");}
        |   ('u')+ i=HEX_DIGIT j=HEX_DIGIT k=HEX_DIGIT l=HEX_DIGIT
                   {setText(ParserUtil.hexToChar(i.getText(),j.getText(),
                                                 k.getText(),l.getText()));}

        )
    ;
于 2009-02-16T10:58:24.983 回答
6

对于 ANTLR4、Java 目标和标准转义字符串语法，我使用了一个专用的单例类：CharSupport 来翻译字符串。它在 antlr API 中可用：

STRING          :   '"' 
                (   ESC  
                |   ~('"'|'\\'|'\n'|'\r') 
                )* 
                    '"' { 
                        setText( 
                            org.antlr.v4.misc.CharSupport.getStringFromGrammarStringLiteral(
                                getText()
                            )
                        ); 
                    }
                ;

正如我在 V4 文档和实验中看到的那样，词法分析器部分不再支持 @init！

于 2013-07-27T09:57:59.270 回答
4

另一种（可能更有效）的替代方法是使用规则参数：

STRING
@init { final StringBuilder buf = new StringBuilder(); }
:
    '"'
    (
    ESCAPE[buf]
    | i = ~( '\\' | '"' ) { buf.appendCodePoint(i); }
    )*
    '"'
    { setText(buf.toString()); };

fragment ESCAPE[StringBuilder buf] :
    '\\'
    ( 't' { buf.append('\t'); }
    | 'n' { buf.append('\n'); }
    | 'r' { buf.append('\r'); }
    | '"' { buf.append('\"'); }
    | '\\' { buf.append('\\'); }
    | 'u' a = HEX_DIGIT b = HEX_DIGIT c = HEX_DIGIT d = HEX_DIGIT { buf.append(ParserUtil.hexChar(a, b, c, d)); }
    );
于 2012-04-28T07:00:34.597 回答
3

我需要这样做，但我的目标是 C 而不是 Java。这是我根据答案#1（和评论）做的，以防有人需要类似的东西：

QUOTE   :      '\'';
STR
@init{ pANTLR3_STRING unesc = GETTEXT()->factory->newRaw(GETTEXT()->factory); }
        :       QUOTE ( reg = ~('\\' | '\'') { unesc->addc(unesc, reg); }
                        | esc = ESCAPED { unesc->appendS(unesc, GETTEXT()); } )+ QUOTE { SETTEXT(unesc); };

fragment
ESCAPED :       '\\'
                ( '\\' { SETTEXT(GETTEXT()->factory->newStr8(GETTEXT()->factory, (pANTLR3_UINT8)"\\")); }
                | '\'' { SETTEXT(GETTEXT()->factory->newStr8(GETTEXT()->factory, (pANTLR3_UINT8)"\'")); }
                )
        ;

HTH。

于 2009-06-02T16:46:25.267 回答