6

我正在使用Delphi 2007 (Pre generics)，并且我定义了许多可用于所有TObject后代数组的函数，例如：

function IndexOf(AArray : array of TObject; AItem : TObject) : integer;
begin
  //...
end;

为了传递他们TObject的后代动态数组，我定义了一个数组类型TObjectArray = array of TObject。通过这种方式，我可以转换动态数组并将它们传递给我的函数，而不会出现任何问题：

type
  TChild = class(TObject);

...

procedure Test();
var
  Items : array of TChild;
  Item : TChild;
begin
  //...
  IndexOf(TObjectArray(Items), Item);
end;

当我尝试向它们传递开放数组参数时，问题就来了：

procedure  Test(AItems : array of TChild);
var
  Item : TChild;
begin
  //...
  IndexOf(TObjectArray(AItems), Item);
end;

在这些情况下，编译器会引发以下错误消息：

E2089 无效类型转换

为什么会发生这种情况，我该如何避免这种情况？

4

1 回答 1

8

将任何类型的数组传递给开放数组参数时，您不需要进行类型转换，前提是元素类型相同。您可以按原样传递数组，打开的数组会很好地接受它。这就是开放数组的全部意义所在。

type
  TChild = class(TObject);

...

function IndexOf(AArray : array of TObject; AItem : TObject) : integer;
begin
  //...
end;

procedure Test();
var
  Items : array of TObject;
  Item : TChild;
begin
  //...
  IndexOf(Items, Item);
end;

procedure Test2();
var
  Items : array[0..N] of TObject;
  Item : TChild;
begin
  //...
  IndexOf(Items, Item);
end;

procedure Test3(AItems : array of TObject);
var
  Item : TChild;
begin
  //...
  IndexOf(AItems, Item);
end;

但是，您不能传递期望数组的TChild位置的数组。TObject编译器会以“不兼容的类型”错误拒绝它。输入数组必须使用与开放数组相同的元素类型。

在传递动态数组或固定数组时，一个简单的类型转换可以解决这个问题：

procedure Test();
type
  TObjectArray = array of TObject;
var
  Items : array of TChild;
  Item : TChild;
begin
  //...
  IndexOf(TObjectArray(Items), Item);
end;

procedure Test2();
type
  TObjectFixedArray = array[0..N] of TObject;
  PObjectFixedArray = ^TObjectFixedArray;
var
  Items : array[0..N] of TChild;
  Item : TChild;
begin
  //...
  IndexOf(PObjectFixedArray(@Items)^, Item);
end;

但是，您根本无法将开放数组类型转换为任何其他数组类型。不同类型的数组具有不同的内存布局（将一个动态数组类型转换为另一个动态数组，或将一个固定数组类型转换为另一个固定数组，不会改变被类型转换的数组的内存布局）。

在开放数组的情况下，它实际上根本就不是一个数组，它只是一个指向传入数组的第一个元素的指针，还有一个数组长度的第二个隐藏参数。换句话说，这种声明：

procedure Test3(AItems : array of TChild);

实际上是由编译器在幕后实现的，如下所示：

procedure Test3(AItems : ^TChild; AItems_High: Integer);

因此，您必须将打开的数组元素复制到另一个数组，然后将该数组传递给另一个数组：

procedure Test3(AItems : array of TChild);
var
  Items: array of TObject;
  Item : TChild;
  I: Integer;
begin
  //...
  SetLength(Items, Length(AItems));
  For I := Low(AItems) to High(AItems) do
    Items[I] := AItems[I];
  IndexOf(Items, Item);
end;
于 2018-05-18T15:18:39.233 回答