0

我有一个看起来像的列表：

list1 = {a.b.c.d a.bb.ccd\[0\] a.bb.ccd\[1\] ....}

当我使用 foreach 循环一一操作列表的元素时：

`foreach ele $list1 {
puts "$ele
}`

我得到以下输出：

a.b.c.d a.bb.ccd[0] a.bb.ccd[1]

请注意，反斜杠丢失了（由于 tcl 语言流程）。

为了保持相同，我想为 list1 具有现有反斜杠的所有元素添加一个额外的反斜杠。

我试过了 ：

regsub -all {\} $list1 {\\} list1 （还尝试了双引号而不是大括号和其他可能的试验）。

似乎没有任何效果。

有没有办法确保 $ele 在 foreach 循环中保留反斜杠字符，因为我需要具有完全相同字符的元素进行进一步处理。

PS 初学者使用 regexp/regsub

4

2 回答 2

1

如果您的输入数据中包含您希望保留的反斜杠，则在将该数据转换为 Tcl 列表时需要使用一些额外的工作，否则 Tcl 将简单地假定您将反斜杠用作传统的 Tcl 元字符。有几种方法可以做到；这是我个人最喜欢的，因为它在逻辑上准确地选择了我们想要的字符（非空白的非空序列）：

set input {a.b.c.d a.bb.ccd\[0\] a.bb.ccd\[1\] ....}
set items [regexp -all -inline {\S+} $input]
foreach item $items {
    puts $item
}

从输出中可以看出：

A B C D
a.bb.ccd\[0\]
a.bb.ccd\[1\]
……

这会准确地保留反斜杠。（另外，是的，我非常喜欢正则表达式。尤其是像这样非常简单的表达式。）

于 2018-05-16T13:42:04.867 回答
0

正如您所定义list1的，它是一个字符串。当list1与foreach命令一起使用时，字符串将转换为列表。请记住，Tcl 中的列表实际上只是特殊格式化的字符串，当从字符串转换为列表时会被解析。在解析列表元素时，根据正常的 Tcl 解析规则删除反斜杠。有几种方法可以构建包含对 Tcl 解析器很重要的字符的列表。下面的代码显示了与您的代码形成对比的两个示例：

set list1 {a.b.c.d a.bb.ccd\[0\] a.bb.ccd\[1\]}
puts "list1 as a string"
puts $list1

puts "converting the list1 string to a proper list"
foreach ele $list1 {
    puts $ele
}

set list2 [list a.b.c.d {a.bb.ccd\[0\]} {a.bb.ccd\[1\]}]
puts "list2 build by the list command"
puts $list2

puts "list2, element by element"
foreach ele $list2 {
    puts $ele
}

set list3 {a.b.c.d {a.bb.ccd\[0\]} {a.bb.ccd\[1\]}}
puts "list3 build properly quoting each element"
puts $list3

puts "list3, element by element"
foreach ele $list3 {
    puts $ele
}

运行此产生：

list1 as a string
a.b.c.d a.bb.ccd\[0\] a.bb.ccd\[1\]
converting the list1 string to a proper list
a.b.c.d
a.bb.ccd[0]
a.bb.ccd[1]
list2 build by the list command
a.b.c.d {a.bb.ccd\[0\]} {a.bb.ccd\[1\]}
list2, element by element
a.b.c.d
a.bb.ccd\[0\]
a.bb.ccd\[1\]
list3 build properly quoting each element
a.b.c.d {a.bb.ccd\[0\]} {a.bb.ccd\[1\]}
list3, element by element
a.b.c.d
a.bb.ccd\[0\]
a.bb.ccd\[1\]

如果您将每个反斜杠替换为两个反斜杠，您的regsub尝试将起作用，但正确构建列表会更加清晰。

于 2018-05-16T01:34:35.393 回答