1

我想创建一个类型泛型STRUCT和一个接受和返回泛型类型变量的配对Function Block（假设ANY_NUM）。

这是希望使用可能属于该类型的泛型数字类型以相同格式将许多现有STRUCT和对压缩为单个泛型对。FBANY_NUM

在 C++ 中，通用结构将通过 a 来完成Template Class，但我在结构化文本中找不到类似的结构。

我在 Beckhoff 的 ANY/ANY_(TYPE) 页面上尝试了通用功能块，但很快就失败了convert type 'LREAL' to type '__SYSTEM.AnyType'。

问题：

在结构化文本中我能在多大程度上实现这一目标？

编辑：

我错误地认为这ANY是唯一相关的 ST 泛型。我被指示输入 T_Arg作为潜在可行的候选人。

尝试的示例格式：

结构：

TYPE Bounded_Value:
STRUCT
    Value   : ANY_NUM;
    Min_    : ANY_NUM;
    Max_    : ANY_NUM;
END_STRUCT
END_TYPE

功能块：

FUNCTION_BLOCK Bind_Value
VAR_IN_OUT
    value_struct: Bounded_Value;
END_VAR

（实现将绑定value_struct.Value到value_struct.min_and之间value_struct.max_）

4

3 回答 3

3

我最近在 TwinCAT 中研究了这个（任何类型）。您基本上需要做的是将 ANY 指针指向的每个字节转换为 LREAL（根据 IEC61131-3，您知道它始终是 8 个字节）。ANY 类型保存有关它指向的类型的信息，因此您将通过解析 ANY 指针指向的数据结构来知道它何时是 LREAL。请在我的博客上阅读我的完整调查：ANY 的奇迹

于 2018-04-27T18:25:04.933 回答
2

（我从Stefan Henneken 在 T_Arg 上的博客文章中收集了我的问题的解决方案。）

目标可以实现，但不是特别干净。有两种适用的通用类型（到目前为止我已经找到）：ANY_NUM和T_Arg.

（我使用ANY_NUM它是因为它与这个例子最相关。ANY, ANY_REAL, 或者ANY_INT也是合理的选择）

这两个选项具有相似的结构和相似的功能。每个都是一个包含存储变量信息的结构：它的类型、指向它的指针和它的大小。

然而，各有利弊。为了最准确地解决这个问题，我们将使用T_Arg.

这是区别：

ANY / ANY_NUM / ETC

优点：变量转换为在分配变量时隐式ANY_NUM完成。输入变量在输入到函数之前不需要进行预转换，从而减少了代码的大小。

此外，它只接受属于其域的变量，因此不会意外使用字符串。

缺点： ANY_NUM不能在VAR_INPUT块之外声明，事实上，在尝试时会提供此错误消息：

Variables of type 'ANY_NUM' only allowed as input of functions.

因此ANY_NUM不能用作STRUCT变量，即使它STRUCT被声明为函数的输入。这就是为什么它不能用来解决这个特定问题的原因。

T_Arg

优点： T_Arg可以在任何地方声明和使用。

缺点： T_Arg需要任何预期变量类型的转换函数，例如： F_INT()、、、F_REAL()等F_DINT()。

因此需要在输入前后进行类型检查。

示例解决方案

T_Arg不幸的是，不能直接操作存储在其中的变量。必须将存储的变量移动到临时变量中才能使用它。所以Value,Min_和Max_都需要从 type 转换T_Arg为 type REAL/ INT/etc。

由于我们试图只使用 one STRUCT，因此一旦完成操作，Value就需要再次将其转换为 T_Arg 。Bind_Value

总共Value将在实例化时转换三次，之后每次调用转换两次。

结构：

TYPE Bounded_Value:
STRUCT
    Value   : T_Arg;
    Min_    : T_Arg;
    Max_    : T_Arg;
END_STRUCT
END_TYPE

功能块：

FUNCTION_BLOCK Bind_Value
VAR_IN_OUT
    value_struct: Bounded_Value;
    // Other variable type declarations
END_VAR
VAR
    val_int     :   INT;
    max_int     :   INT;
    min_int     :   INT;
END_VAR  

CASE (value_struct.Value.eType) OF
    E_ArgType.ARGTYPE_INT: // If the struct's Value's type is INT
        // Copy generic pointer information into typed pointer 
        MEMCPY(ADR(val_int), value_struct.Value.pData, value_struct.Value.cbLen);
        MEMCPY(ADR(max_int), value_struct.Max_.pData,  value_struct.Max_.cbLen);
        MEMCPY(ADR(min_int), value_struct.Min_.pData,  value_struct.Min_.cbLen);

        IF val_int > max_int THEN
            value_struct.Value.pData := value_struct.Max_.pData;
        ELSIF val_int < min_int THEN
            value_struct.Value.pData := value_struct.Min_.pData;
        END_IF
    // Other variable type handlings
END_CASE

主要的：

PROGRAM MAIN
VAR
    val     : INT := -1; //Change this to test
    minim   : INT :=  0;
    maxim   : INT :=  5;
    newVal  : INT;
    bv      : Bounded_Value;
    bind    : Bind_Value;
END_VAR

// Convert INT variables to T_Arg in structure
bv.Value:= F_INT(val);
bv.Max_ := F_INT(maxim);
bv.Min_ := F_INT(minim);
// Bind_Value.value_struct := bv;
bind(value_struct := bv);
// Copy result to newVal
MEMCPY(ADR(newVal), bv.Value.pData, bv.Value.cbLen);
于 2018-04-30T20:46:21.953 回答
0

您还可以在功能块和联合的帮助下创建泛型类型。假设您定义了一个包含所有 DUT 和 POU 的 Union：

TYPE GenericType :
UNION
    generic : PVOID;
    bBool   : REFERENCE TO BOOL;
    nInt    : REFERENCE TO INT;
    nUint   : REFERENCE TO UINT;
    nUdint  : REFERENCE TO UDINT;
    fReal   : REFERENCE TO REAL;
    fLreal  : REFERENCE TO LREAL;
    fbTest  : REFERENCE TO FB_Test;
END_UNION
END_TYPE

然后创建一个特殊的功能块：

FUNCTION_BLOCK Generic
VAR_INPUT
END_VAR
VAR_OUTPUT
END_VAR
VAR
    uGenericType : GenericType;
END_VAR

还有一个获取和设置 PVOID 的属性：

PROPERTY PUBLIC generic : PVOID

吸气剂：

generic := uGenericType.generic;

二传手：

uGenericType.generic := generic;

您还需要 Properties 以便稍后检索您的类型：

FB的图像

getBool 设置器的一个示例可能是：

IF uGenericType.generic = 0 
THEN
    RETURN;
ELSE
    getBool := uGenericType.bBool;
END_IF

现在您创建将使用泛型类型的 FB：

FUNCTION_BLOCK FB_Container
VAR_INPUT

    myGenericType       : Generic;
    nContainerOption    : INT;

END_VAR
VAR_OUTPUT
END_VAR
VAR

    testInt             : INT;
    testBool            : BOOL;
    testFB              : FB_Test;

END_VAR

CASE nContainerOption OF

    1:
        testInt := myGenericType.getInt;

    2:
        testFB := myGenericType.getFbTest;

    3:
        testBool := myGenericType.getBool;

END_CASE

调用可能是这样的：

fbContainer.myGenericType.generic := ADR(testInteger);
...
fbContainer(nContainerOption := 1);

另一种方法是使用通用 FB 扩展我们的 FB。我们需要对 Generic FB 和 GenericType Union 做一些修改：

FUNCTION_BLOCK Generic
VAR_INPUT
END_VAR
VAR_OUTPUT
END_VAR
VAR
    uGenericType    : GenericType;
    bInit           : BOOL;
END_VAR

IF NOT bInit THEN
 uGenericType.generic := ADR(THIS^);
 bInit := TRUE;
END_IF

TYPE GenericType :
UNION
    generic : PVOID;

    //Add the pointer of the FB you want to extend
    pAxis   : POINTER TO FB_Axis;

    bBool   : REFERENCE TO BOOL;
    nInt    : REFERENCE TO INT;
    nUint   : REFERENCE TO UINT;
    nUdint  : REFERENCE TO UDINT;
    fReal   : REFERENCE TO REAL;
    fLreal  : REFERENCE TO LREAL;
    fbTest  : REFERENCE TO FB_Test;

END_UNION
END_TYPE

扩展FB：

FUNCTION_BLOCK FB_Axis EXTENDS Generic
VAR_INPUT
END_VAR
VAR_OUTPUT
END_VAR
VAR
    fPosition : LREAL;
END_VAR

现在像以前一样调用我们的容器：

fbContainer.myGenericType := fbAxis;

在 FB_Container 中，您可以按如下方式调用轴：

IF myGenericType.getPointerFbAxis <> 0 
THEN
    position := myGenericType.getPointerFbAxis^.fPosition;
END_IF
于 2019-07-05T10:57:41.150 回答