5

我正在努力在 Haskell 中创建一个 AST。我想添加不同的注释，例如类型和位置信息，所以我最终使用了fixplate。但是，我在网上找不到任何示例并且遇到了一些困难。

我已经按照 fixplate 的建议设置了我的 AST（有些被删除了）：

data ProgramF a
  = Unary a
          Operator
  | Number Int
  | Let { bindings :: [(Identifier, a)]
        , body :: a }

type Program = Mu ProgramF

接下来添加一个标签，我创建了另一种类型，以及一个基于树遍历添加标签的函数。

type LabelProgram = Attr ProgramF PLabel

labelProgram :: Program -> LabelProgram
labelProgram =
  annMap (PLabel . show . fst) . (snd . synthAccumL (\i x -> (i + 1, (i, x))) 0)

但是，除此之外，我遇到了一些问题。例如，我正在尝试编写一个对 AST 进行一些转换的函数。因为它需要一个标签才能运行，所以我制作了 type LabelProgram -> Program，但我认为我在这里做错了。下面是部分函数的片段（其中一个更简单的部分）：

toANF :: LabelProgram -> Program
toANF (Fix (Ann label (Let {bindings, body}))) = Fix $ Let bindingANF nbody
  where
    bindingANF = map (\(i, e) -> (i, toANF e)) bindings
    nbody = toANF body

我觉得我在这里工作的抽象级别错误。我应该像这样显式匹配Fix Ann ...并返回Fix ...，还是我使用了错误的固定板？

此外，我担心如何泛化函数。如何使我的函数一般适用于Programs、LabelPrograms 和TypePrograms？

4

1 回答 1

3

编辑：ProgramF为s 添加一个带有通用注释的函数示例。

是的，至少在 的情况下toANF，你用错了。

在toANF中，请注意您的Let bindingANF nbody和伴随定义的bindingANFandnbody只是fmap toANF特定构造函数的重新实现Let。

也就是说，如果您Functor为您的 派生一个实例ProgramF，那么您可以将您的代码段重写toANF为：

toANF :: LabelProgram -> Program
toANF (Fix (Ann label l@(Let _ _))) = Fix (fmap toANF l)

如果toANF只是剥离标签，则此定义适用于所有构造函数，而不仅仅是，Let因此您可以删除该模式：

toANF :: LabelProgram -> Program
toANF (Fix (Ann label l)) = Fix (fmap toANF l)

现在，根据@Regis_Kuckaertz 的评论，您刚刚重新实现forget了定义为：

forget = Fix . fmap forget . unAnn . unFix

关于编写在Program,LabelProgram等上通用的函数，我认为在（单个）注释中编写通用函数更有意义：

foo :: Attr ProgramF a -> Attr ProgramF a

并且，如果您确实需要将它们应用于未注释的程序，请定义：

type ProgramU = Attr ProgramF ()

其中“U”ProgramU代表“单位”。显然，如果真的需要，您可以轻松编写翻译器以使用Programs as s：ProgramU

toU :: Functor f => Mu f -> Attr f ()
toU = synthetise (const ())

fromU :: Functor f => Attr f () -> Mu f
fromU = forget

mapU :: (Functor f) => (Attr f () -> Attr f ()) -> Mu f -> Mu f
mapU f = fromU . f . toU

foo' :: Mu ProgramF -> Mu ProgramF
foo' = mapU foo

作为一个具体的（如果愚蠢的话）示例，这里有一个函数，它将Let具有多个绑定的 s 分隔为Let具有单例绑定的嵌套 s（因此破坏了Program语言中的相互递归绑定）。它假定多重绑定上的注释Let将被复制到每个生成的单例中Let：

splitBindings :: Attr ProgramF a -> Attr ProgramF a
splitBindings (Fix (Ann a (Let (x:y:xs) e)))
  = Fix (Ann a (Let [x] (splitBindings (Fix (Ann a (Let (y:xs) e))))))
splitBindings (Fix e) = Fix (fmap splitBindings e)

它可以应用于一个例子Program：

testprog :: Program
testprog = Fix $ Unary (Fix $ Let [(Identifier "x", Fix $ Number 1), 
                                   (Identifier "y", Fix $ Number 2)] 
                                  (Fix $ Unary (Fix $ Number 3) NegOp))
                       NegOp

像这样：

> mapU splitBindings testprog
Fix (Unary (Fix (Let {bindings = [(Identifier "x",Fix (Number 1))],
body = Fix (Let {bindings = [(Identifier "y",Fix (Number 2))], 
body = Fix (Unary (Fix (Number 3)) NegOp)})})) NegOp)
>

这是我的完整工作示例：

{-# LANGUAGE DeriveFunctor #-}
{-# OPTIONS_GHC -Wall #-}

import Data.Generics.Fixplate

data Identifier = Identifier String deriving (Show)
data PLabel = PLabel deriving (Show)
data Operator = NegOp deriving (Show)

data ProgramF a
  = Unary a
          Operator
  | Number Int
  | Let { bindings :: [(Identifier, a)]
        , body :: a }
  deriving (Show, Functor)
instance ShowF ProgramF where showsPrecF = showsPrec

type Program = Mu ProgramF
type LabelProgram = Attr ProgramF PLabel

splitBindings :: Attr ProgramF a -> Attr ProgramF a
splitBindings (Fix (Ann a (Let (x:y:xs) e)))
  = Fix (Ann a (Let [x] (splitBindings (Fix (Ann a (Let (y:xs) e))))))
splitBindings (Fix e) = Fix (fmap splitBindings e)

toU :: Functor f => Mu f -> Attr f ()
toU = synthetise (const ())

fromU :: Functor f => Attr f () -> Mu f
fromU = forget

mapU :: (Functor f) => (Attr f () -> Attr f ()) -> Mu f -> Mu f
mapU f = fromU . f . toU

testprog :: Program
testprog = Fix $ Unary (Fix $ Let [(Identifier "x", Fix $ Number 1), 
                                   (Identifier "y", Fix $ Number 2)] 
                                  (Fix $ Unary (Fix $ Number 3) NegOp))
                       NegOp

main :: IO ()
main = print $ mapU splitBindings testprog
于 2018-04-23T14:09:32.847 回答