11

我们正在从 ColdFusion 9 升级到 ColdFusion 2016，我们注意到性能总体下降。我们进行了多次模拟以提供更多洞察力。下面是一个脚本，它给出了性能下降的一个很好的例子。该脚本构建一个查询，然后根据该查询创建一个结构。

<!--- Machine info --->
<cfset runtime = createObject("java", "java.lang.System")>
<cfset props = runtime.getProperties()> 
<cfset env = runtime.getenv()> 

<Cfoutput>

coldfusion: #SERVER.ColdFusion.ProductVersion# #SERVER.ColdFusion.ProductLevel#<br>

java.version: #props["java.version"]#<br>
java.vm.name: #props["java.vm.name"]#<br>
os.name: #props["os.name"]#<br>

PROCESSOR_IDENTIFIER: #env["PROCESSOR_IDENTIFIER"]#<br>
PROCESSOR_ARCHITECTURE: #env["PROCESSOR_ARCHITECTURE"]#<br>
NUMBER_OF_PROCESSORS: #env["NUMBER_OF_PROCESSORS"]#<br><Br>
</Cfoutput>

<!--- Create a query --->
<cfset myQuery = QueryNew("Name, Time, Advanced", "VarChar, Time, Bit")> 
<cfset testQuery = QueryNew("ColumnA,ColumnB,ColumnC,ColumnD,ColumnE,ColumnF,ColumnG,ColumnH,ColumnI,ColumnJ,ColumnK,ColumnL,ColumnM,ColumnN","VarChar,VarChar,VarChar,VarChar,VarChar,VarChar,VarChar,VarChar,VarChar,VarChar,VarChar,VarChar,VarChar,VarChar")>

<!--- Populate the query --->
<Cfloop from=1 to=300 index="x">
    <cfset QueryAddRow(testQuery, 1)> 
    <cfloop index="intLetter" from="#Asc('A')#" to="#Asc('N')#" step="1">
        <cfset temp = QuerySetCell(testQuery, "Column#chr(intLetter)#", "Row #x# column #intLetter#", x)> 
    </cfloop>
</cfloop>

<Cfset init = GetTickCount()>
<!--- Query to structure --->
<Cfset queryToStruct = structNEw()>
<cfloop query="testQuery">
<Cfset init2 = GetTickCount()>
    <cfset queryToStruct[testQuery.currentrow] = structNew()>
    <cfset queryToStruct[testQuery.currentrow]['ColumnA'] = structNew()>
    <cfloop list="#testQuery.columnList#" index="key">
        <cfset queryToStruct[testQuery.currentrow]['ColumnA'][testQuery[key][testQuery.currentrow]] = testQuery[key][testQuery.currentrow]>
    </cfloop>
    <cfoutput>#x#:#GetTickCount()-init2#<br></cfoutput>
</cfloop>

<cfoutput>-----------<br><b>#GetTickCount()-init#</b><br><br><Br></cfoutput>

<!---Cfdump var=#queryToStruct# --->

我们有两台具有完全相同硬件配置的服务器。一台服务器在 Windows 2008 / ColdFusion Server 9 Enterprise（Java 版本 1.6.0_14）上运行，另一台在 Windows 2016 / ColdFusion 2016 Standard（Java 版本 1.8.0_112）上运行。两个 ColdFusion 服务器具有相同的最小 JVM 堆大小 (5024 MB) 和最大 JVM 堆大小 (5048 MB)。

ColdFusion 9 服务器的性能要快 4 倍以上。有人可以解释为什么会发生这种情况以及如何解决这个问题吗？

更新

为了排除任何其他会减慢 ColdFusion 的进程，我将 ColdFusion 9、ColdFusion 11 和 ColdFusion 2016 都安装在同一台虚拟机上，并且都使用内置的 Web 服务器。默认安装设置。结果：ColdFusion 9 最快，紧随其后的是 ColdFusion 11。ColdFusion 2016 慢得多。

更新 2 对脚本进行了一些更改，因此更清楚该脚本在做什么。

更新 3 结果可以在这里查看：http: //136.144.177.152/test2.asp或 http://136.144.177.152/test-toma.asp或 http://136.144.177.152/test-ag.asp 注意代码实际上是经过处理的，因此每次加载页面时结果都会略有不同。

另外我想指出我并没有尝试优化这段代码。我试图制作一个非常简单的可重现示例。唯一的目的是指出性能上的差异并找到原因和解决方案。

更新 4 做了一些额外的测试，发现了潜在的问题。出于某种原因，coldfusion 2016 / Windows 2016 上的以下代码非常慢：

<cfset tmp = testQuery['ColumnA'][testQuery.currentrow]>

我发现很奇怪的是更新查询值并不慢。例如

<cfset testQuery['ColumnA'][testQuery.currentrow] = key>

所有结果都可以在这里找到：http: //136.144.177.152/test5.asp或http://136.144.177.152/test6.asp。我还在笔记本电脑上安装了coldfusion 2016，没有发现性能问题。我还尝试在 Windows 2012 机器上安装 Coldfusion 2016。在这里，我发现了相同的性能问题。

更新 5 根据 Tomalak 的建议，我删除了索引访问表示法。这显然是 Coldfusion 2016 的性能问题。实际结果可以在这里找到http://136.144.177.152/bug-adobe.asp。我在 adobe 上针对此问题打开了一个错误https://tracker.adobe.com/#/view/CF-4201966。

4

2 回答 2

3

我无法重现这个问题，真的。这在我的 ColdFusion 2016 上运行得非常快。我创建了QueryToStruct代码的优化版本，但除此之外几乎没有什么区别。

我没有可用的 CF 9 服务器，当您测试它时，此代码在 CF 9 上的速度是否也快 4 倍？

<!--- Machine info --->
<cfset runtime = createObject("java", "java.lang.System")>
<cfset props = runtime.getProperties()>
<cfset env = runtime.getenv()>
<cfoutput>
ColdFusion: #SERVER.ColdFusion.ProductVersion# #SERVER.ColdFusion.ProductLevel#<br>
java.version: #props["java.version"]#<br>
java.vm.name: #props["java.vm.name"]#<br>
os.name: #props["os.name"]#<br>
PROCESSOR_IDENTIFIER: #env["PROCESSOR_IDENTIFIER"]#<br>
PROCESSOR_ARCHITECTURE: #env["PROCESSOR_ARCHITECTURE"]#<br>
NUMBER_OF_PROCESSORS: #env["NUMBER_OF_PROCESSORS"]#<br>
<br>
</cfoutput>

<!--- Create a query --->
<cfset ROWNUM = 2000>
<cfset testColumns = "ColumnA,ColumnB,ColumnC,ColumnD,ColumnE,ColumnF,ColumnG,ColumnH,ColumnI,ColumnJ,ColumnK,ColumnL,ColumnM,ColumnN">
<cfset testTypes = "VarChar,VarChar,VarChar,VarChar,VarChar,VarChar,VarChar ,VarChar,VarChar,VarChar,VarChar,VarChar,VarChar,VarChar">
<cfset testQuery = QueryNew(testColumns, testTypes)>

<!--- Populate the query --->
<cfloop from="1" to="#ROWNUM#" index="x">
    <cfset QueryAddRow(testQuery, 1)>
    <cfloop from="#Asc('A')#" to="#Asc('N')#" index="intLetter">
        <cfset QuerySetCell(testQuery, "Column#chr(intLetter)#", "#x#-#intLetter#", x)>
    </cfloop>
</cfloop>

<!--- Convert the query to a struct --->
<cfset init = GetTickCount()>
<cfset converted = QueryToStruct(testQuery, "ColumnA")>

<cfoutput>
<b>My version:</b> #StructCount(converted)# rows, #GetTickCount()-init# ms<br>
</cfoutput>

<!--- Convert the query to a struct --->
<cfset init = GetTickCount()>
<cfset converted = QueryToStructOP(testQuery)>

<cfoutput>
<b>OP version:</b> #StructCount(converted)# rows, #GetTickCount()-init# ms<br>
</cfoutput>

<!--- +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ --->
<cffunction name="QueryToStruct">
  <cfargument name="Query" type="query" required="yes">
  <cfargument name="IndexColumn" type="string" required="yes">

  <cfset var result = StructNew()>
  <cfset var rowTemplate = StructNew()>
  <cfset var key = "">
  <cfset var thisRow = "">

  <cfloop list="#Query.ColumnList#" index="key">
    <cfset rowTemplate[key] = "">
  </cfloop>

  <cfloop query="Query">
    <cfset thisRow = Duplicate(rowTemplate)>
    <cfset result[Query[IndexColumn][Query.CurrentRow]] = thisRow>
    <cfloop collection="#thisRow#" item="key">
      <cfset thisRow[key] = Query[key][Query.CurrentRow]>
    </cfloop>
  </cfloop>

  <cfreturn result>
</cffunction>

<cffunction name="QueryToStructOP">
  <cfargument name="Query" type="query" required="yes">

  <cfset var queryToStruct = StructNew()>
  <cfset var key = "">
  <cfset var index = "">

  <cfloop query="Query">
    <cfset index = Query['ColumnA'][Query.CurrentRow]>
    <cfset queryToStruct[index] = StructNew()>
    <cfloop list="#Query.ColumnList#" index="key">
      <cfset queryToStruct[index][Query[key][Query.CurrentRow]] = Query[key][Query.CurrentRow]>
    </cfloop>
  </cfloop>

  <cfreturn queryToStruct>
</cffunction>

结果（这甚至不是服务器硬件，而且它是一个旧 CPU）：

java.version: 1.8.0_162
java.vm.name：Java HotSpot(TM) 64 位服务器虚拟机
操作系统名称：Windows 7
ColdFusion：2016,0,05,308055 开发者
PROCESSOR_IDENTIFIER: Intel64 Family 6 Model 42 Stepping 7, GenuineIntel
PROCESSOR_ARCHITECTURE：AMD64
NUMBER_OF_PROCESSORS：4

我的版本：2000 行，78 毫秒
OP 版本：2000 行，229 毫秒
于 2018-04-11T14:12:01.313 回答
2

首先，您将 CF 9 Enterprise 与 CF 2016 Standard 进行比较。对于这个例子来说应该没什么大不了的，但是如果你在 Standard 上对整个应用程序进行回归测试，你会发现问题。我以前的公司从 9 Ent 迁移到 2016 Ent，我们看到的只是全面的绩效改进。当您看到瓶颈时，您应该始终考虑重构。这是您升级的原因之一。

最大的问题是如何将 a 转换query为struct. CF 2016 具有更高级的功能。将您的旧流程与利用查询对象中的成员函数的流程进行比较。

public array function arrayOfStructs(required query data) {
    var results = [];
    arguments.data.each(function(row) {
        arrayAppend(results, arguments.row);
    });
    return results;
}

query成员函数将each()每个内容row作为struct. 无需遍历每一列，输入一个新键并分配一个值。繁荣！完毕。快得要命。

做你的升级。:)

于 2018-04-11T17:15:29.233 回答